如何获取匹配条件的列表的最后一个元素？

Question

所以我有一个从 3 到 10 的数字列表。我想得到最后一个大于 5 且小于 11 的数字。

*Main> greatestIndexInRange [3, 6, 7, 2, 5, 1, 0, 10, 2] 5 11

Answer 1

您可以reverse列表，按谓词filter并在线性时间内选择结果列表的head （这将是原始列表中的最后一个元素）。 或者您可以选择过滤列表中的last元素。

greatestIndexInRange :: Ord a => [a] -> a -> a -> a
greatestIndexInRange xs l h = head . filter (\x -> x > l && x < h) . reverse $ xs

greatestIndexInRange :: Ord a => [a] -> a -> a -> a
greatestIndexInRange xs l h = last $ filter (\x -> x > l && x < h) xs

例如：

greatestIndexInRange [3, 6, 7, 2, 5, 1, 0, 10, 2] 5 11
-- 10

请注意，如果列表中没有元素在给定范围内，这是一个部分函数，​​它将失败，例如：

greatestIndexInRange [1, 2, 3] 5 11
*** Exception: Prelude.head: empty list

正如 Chris 在评论中建议的那样，您还可以在反向列表上使用来自Data.List的find而不是filter + head以获得更优雅的实现：

import Data.List (find)

greatestIndexInRange :: Ord a => [a] -> a -> a -> Maybe a
greatestIndexInRange xs l h = find (\x -> x > l && x < h) . reverse $ xs

该函数现在返回一个Maybe 。 这也将解决上述它是部分功能的问题：

greatestIndexInRange [3, 6, 7, 2, 5, 1, 0, 10, 2] 5 11
-- Just 10
greatestIndexInRange [1, 2, 3] 5 11
-- Nothing

Answer 2

这将让您在 GHC 9.2 或更高版本上执行您想要的操作：

{-# LANGUAGE ImpredicativeTypes #-}

import Control.Monad
import Data.Functor.Identity

lastJust :: forall f a b. Foldable f => (a -> Maybe b) -> f a -> Maybe b
lastJust p xs = foldr go id xs Nothing where
  go :: a -> (forall t. Applicative t => t b -> t b) -> forall t. Applicative t => t b -> t b
  go x acc z = maybe (acc z) (pure . runIdentity . acc . Identity) $ p x

greatestIndexInRange :: (Foldable t, Ord a) => t a -> a -> a -> Maybe a
greatestIndexInRange xs lo hi = lastJust (\x -> x <$ guard (x > lo && x < hi)) xs

Answer 3

您可能希望选择使用filter和last而不是使用reverse和find 。 更好的解决方案取决于以下因素：我们想要的元素在列表中的位置、列表中存在多少与我们的谓词匹配的元素等。您可以根据具体情况决定，但任何一种解决方案都是美好的！

例如，如果我们想要的元素是 one 并且在开头，肯定会反转它并使用find比使用filter和last更糟糕。 同样，如果我们有很多元素与我们的filter的谓词相匹配，并且均匀分布在列表中，那么最好反转列表并使用find 。

如果没有，最好将结果包装在Maybe中。 这个想法是你需要以某种方式到达列表的末尾。 所以无论哪种方式，你都不会得到比线性时间更好的解决方案，除非列表是有序的，在这种情况下你可以进行二进制搜索。

import Data.List    
greatestIndexInRange :: Ord a => [a] -> a -> a -> Maybe a
greatestIndexInRange xs x y = find (\z -> z > x && z < y) (reverse xs)

输出：

*Main Data.List> greatestIndexInRange [3, 6, 7, 2, 5, 1, 0, 10, 2] 5 11
Just 10
*Main Data.List> greatestIndexInRange [1, 2, 3] 5 11
Nothing