在 Raku 中，如何编写等效于 Haskell 的 span 函数？

Question

---

在 Raku 中，如何编写等效于 Haskell 的span函数？

在 Haskell 中，给定一个谓词和一个列表，可以将列表分成两部分：

• 满足谓词的元素的最长前缀
• 列表的其余部分

例如，Haskell 表达式……

span (< 10) [2, 2, 2, 5, 5, 7, 13, 9, 6, 2, 20, 4]

……评估为……

([2,2,2,5,5,7],[13,9,6,2,20,4])

如何编写与 Haskell 的span函数等效的 Raku？

---

更新 1

根据@chenyf 的回答，我开发了以下span子例程（稍后的附加更新反映了span内的否定谓词需要保持忠实于Haskell 的span函数的正逻辑）......

sub span( &predicate, @numberList )
  {
  my &negatedPredicate = { ! &predicate($^x) } ;
  my $idx = @numberList.first(&negatedPredicate):k ;
  my @lst is Array[List] = @numberList[0..$idx-1], @numberList[$idx..*] ;
  @lst ;
  } # end sub span

sub MAIN()
  {
  my &myPredicate = { $_ <= 10 } ;
  my @myNumberList is Array[Int] = [2, 2, 2, 5, 5, 7, 13, 9, 6, 2, 20, 4] ;
  my @result is Array[List] = span( &myPredicate, @myNumberList ) ;

  say '@result is ...' ;
  say @result ;
  say '@result[0] is ...' ;
  say @result[0] ;
  say @result[0].WHAT ;
  say '@result[1] is ...' ;
  say @result[1] ;
  say @result[1].WHAT ;
  } # end sub MAIN

程序输出是……

@result is ...
[(2 2 2 5 5 7) (13 9 6 2 20 4)]
@result[0] is ...
(2 2 2 5 5 7)
(List)
@result[1] is ...
(13 9 6 2 20 4)
(List)

---

更新 2

利用发布到StackOverflow上的有关 Raku 的Nil的信息，以下子例程span的更新草案是……

sub span( &predicate, @numberList )
  {
  my &negatedPredicate = { ! &predicate($^x) } ;
  my $idx = @numberList.first( &negatedPredicate ):k ;
  if Nil ~~ any($idx) { $idx = @numberList.elems ; }
  my List $returnList = (@numberList[0..$idx-1], @numberList[$idx..*]) ;
  $returnList ;
  } # end sub span

sub MAIN()
  {
  say span( { $_ == 0 }, [2, 2, 5, 7, 4, 0] ) ;  #  (() (2 2 5 7 4 0))
  say span( { $_ <  6 }, (2, 2, 5, 7, 4, 0) ) ;  #  ((2 2 5) (7 4 0))
  say span( { $_ != 9 }, [2, 2, 5, 7, 4, 0] ) ;  #  ((2 2 5 7 4 0) ())
  } # end sub MAIN

---

Answer 1

我使用first一种方法和:k副词，如下所示：

my @num  = [2, 2, 2, 5, 5, 7, 13, 9, 6, 2, 20, 4];
my $idx = @num.first(* > 10):k;

@num[0..$idx-1], @num[$idx..*];

Answer 2

一个完全天真的看法：

sub split_on(@arr, &pred) {
  my @arr1;
  my @arr2 = @arr;

  loop {
    if not &pred(@arr2.first) {
      last;
    } 

    push @arr1: @arr2.shift
  }

  (@arr1, @arr2);
}

创建一个新的@arr1并将数组复制到@arr2中。 循环，如果数组中的第一个元素不满足谓词，则为最后一次。 否则，将第一个元素从@arr2移出并将其推送到@arr1上。

测试时：

my @a = [2, 2, 2, 5, 5, 7, 13, 9, 6, 2, 20, 4];
my @b = split_on @a, -> $x { $x < 10 };

say @b;

输出是：

[[2 2 2 5 5 7] [13 9 6 2 20 4]]

这里唯一的问题是......如果不满足谓词怎么办？ 好吧，让我们检查列表是否为空或不满足谓词来终止循环。

sub split_on(@arr, &pred) {
  my @arr1;
  my @arr2 = @arr;

  loop {
    if !@arr2 || not &pred(@arr2.first) {
      last;
    } 

    push @arr1: @arr2.shift;
  }

  (@arr1, @arr2);
}

Answer 3

在Raku (*each) 的 1 行* 中的 105 个 C++ 算法的演讲中，Daniel Sockwell 讨论了一个几乎可以回答您的问题的函数。 我已经对其进行了一些重构以适应您的问题，但变化很小。

#| Return the index at which the list splits given a predicate.
sub partition-point(&p, @xs) {
    my \zt = @xs.&{ $_ Z .skip };
    my \mm = zt.map({ &p(.[0]) and !&p(.[1]) });
    my \nn = mm <<&&>> @xs.keys;
    return nn.first(?*)
}

#| Given a predicate p and a list xs, returns a tuple where first element is
#| longest prefix (possibly empty) of xs of elements that satisfy p and second
#| element is the remainder of the list.
sub span(&p, @xs) {
    my \idx = partition-point &p, @xs;
    idx.defined ?? (@xs[0..idx], @xs[idx^..*]) !! ([], @xs)
}

my @a = 2, 2, 2, 5, 5, 7, 13, 9, 6, 2, 20, 4;
say span { $_ < 10 }, @a;                #=> ((2 2 2 5 5 7) (13 9 6 2 20 4))
say span { $_ < 5 }, [6, 7, 8, 1, 2, 3]; #=> ([] [6 7 8 1 2 3])

Answer 4

所以我想我会把我的版本扔进去，因为我认为classify可能会有所帮助：

sub span( &predicate, @list ) { 
    @list
    .classify({
        state $f = True; 
        $f &&= &predicate($_); 
        $f.Int; 
    }){1,0}
    .map( {$_ // []} )
}

最后的map用于处理谓词永远不为真或总是为真的情况。

Answer 5

版本 6.e 的 raku 将采用新的“snip”功能：

use v6.e; 
dd (^10).snip( < 5 );
#«((0, 1, 2, 3, 4), (5, 6, 7, 8, 9)).Seq␤»