如果我依赖它们，是否可以 eta （或以其他方式）减少参数？

Question

我正在解决一个超级简单的问题，并得出了这段代码。 我觉得应该有一种方法可以消除areaOrPerimeter中的参数x和y 。 但我找不到办法做到这一点。 有可能以某种方式摆脱它们吗？ 我有一种强烈的感觉，这应该是可能的。

areaOrPerimeter :: Double -> Double -> Double
areaOrPerimeter x y
  | x == y = area x y 
  | otherwise = perimeter x y
  

area :: Num a => a -> a -> a
area = (*)

perimeter :: Num a => a -> a -> a
perimeter x y = 2 * (x + y)

Answer 1

如果您想有机会以一种不令人讨厌的方式这样做，您应该首先将参数有意义地组合在一起，以避免不得不处理多个参数：

data RectangleSize a = RectangleSize {width, height :: a}

然后我们可以使函数和x==y检查也更有意义：

area :: Num a => RectangleSize a -> a
area (RectangleSize w h) = w*h

perimeter :: Num a => RectangleSize a -> a
perimeter (RectangleSize w h) = 2*(w+h)

isSquare :: Eq a => RectangleSize a -> Bool
isSquare (RectangleSize w h) = w==h

这给我们留下了已经更有希望的

areaOrPerimeter :: RectangleSize Double -> Double
areaOrPerimeter r
  | isSquare r  = area r 
  | otherwise   = perimeter r

为了使这一点变得无意义，您仍然需要在r周围复制三遍。 这可以通过函数的Applicative实例来完成（是否应该是另一回事），即\x -> fx (gx)可以写为f<*>g 。 在这种情况下，您要做出决定，因此您需要一流的if ； 通常是这样写的

if' :: Bool -> a -> a -> a
if' True x _ = x
if' False _ y = y

现在您可以通过组合if'将isSquare升级为切换功能：

    if' . isSquare :: Eq a => RectangleSize a -> b -> b -> b

现在我们可以使用应用实例将矩形分配给所有组件：

areaOrPerimeter = if'.isSquare <*> area <*> perimeter

实际上并不太寒酸IMO。

Answer 2

链接两个单参数函数f和g , . 很前卫。 要链接g :: c -> d和f :: a -> b -> c ，请使用(g .) . f (g .) . f . 这样，您可以将perimeter写为

perimeter = ((2*) .) . (+)

可以使用<*>删除一个参数，对两个参数执行两次：

import Control.Applicative(liftA2)
import Data.Bool(bool)

areaOrPerimeter :: Double -> Double -> Double
areaOrPerimeter = bool <<$>> (*) <<*>> ((2*) .) . (+) <<*>> (==)
   where infixl 4 <<*>>
         (<<*>>) = liftA2 (<*>)
         infixl 5 <<$>>
         (<<$>>) = fmap . fmap

无点写作是一个很好的练习，但不要指望在 6 个月后理解这一点。