在 Haskell 中加倍列表（列表中的数字）

Question

其他人可以在 Haskell 中编写此代码吗：加倍数字数字需要加倍，为此可以定义以下函数：

doubleDigits :: [Integer] -> [Integer]

函数doubleDigits必须从右边开始每隔一个数字加倍。 倒数第二个数字首先加倍，然后是倒数第四个，...，依此类推。

Input: doubleDigits [1,2,3,4,5,6,7]
Output: [1,4,3,8,5,12,7]

toDigitsReverse :: Integer -> [Integer]
toDigitsReverse n = reverse (toDigits n)

-- function to help double every other element of list
doubleDigitsHelper :: [Integer] -> Integer -> [Integer]
doubleDigitsHelper l t
    | l == [] = []
    | t == 0 = [head l] ++ (doubleDigitsHelper (drop 1 l) 1)
    | t == 1 = [2*(head l)] ++ (doubleDigitsHelper (drop 1 l) 0)

-- function to double every other element
doubleDigits :: [Integer] -> [Integer]
doubleDigits l = reverse (doubleDigitsHelper (reverse l) 0)

Answer 1

另一种方法：

让我们用它们的索引zip列表的元素。

[1,2,3,4,5,6,7] `zip` [0..]

我们得到：

[(1,0),(2,1),(3,2),(4,3),(5,4),(6,5),(7,6)]

然后我们可以将其map到所需的结果：

let f (x, i) = if even i then x else x * 2 in map f $ [1,2,3,4,5,6,7] `zip` [0..]

结果是：

[1,4,3,8,5,12,7]

或者写得有点不同：

doubleDigits lst = map f lst'
  where
    lst' = lst `zip` [0..]
    f (x, i)
      | even i = x
      | otherwise = x * 2

因为您想从right开始将所有其他元素加倍，您可以简单地反转列表，用索引压缩它，映射，然后保留输出。

doubleDigits lst = reverse $ map f lst'
  where
    lst' = (reverse lst) `zip` [0..]
    f (x, i)
      | even i = x
      | otherwise = x * 2

Answer 2

我会说首先没有必要reverse列表，确定累加器（ t ）是偶数还是奇数（有内置函数 - 例如even ），然后采取相应的行动。 接下来可以改进代码的内容 - 使用模式匹配而不是==和head / tail调用。 我还更改了辅助函数的顺序：

-- function to help double every other element of list
doubleDigitsHelper :: Integer -> [Integer] -> [Integer]
doubleDigitsHelper _ [] = []
doubleDigitsHelper t (x:xs) | even t  = x : doubleDigitsHelper (t+1) xs 
                            | otherwise = 2*x : doubleDigitsHelper (t+1) xs


-- function to double every other element
doubleDigits :: [Integer] -> [Integer]
doubleDigits = doubleDigitsHelper 0

Answer 3

您可以将要应用的交替函数放在列表中（ cycle [id, (*2)] ）并使用zipWith将它们应用到您的列表中。

doubleDigits :: Num a => [a] -> [a]
doubleDigits = reverse . zipWith ($) (cycle [id, (*2)]) . reverse

如果您想从右侧开始交替，我看不到反转列表的优雅方法。 例如，您可以先查看列表的长度，然后根据该长度更改函数的顺序，但这会使函数稍微复杂化。

doubleDigits xs = zipWith ($) fs xs
    where fs = (if even . length $ xs then tail else id) $ cycle [id, (*2)]