如何提取定界延续（重置/移位）以供将来在 Haskell 中使用？

Question

以下是使用定界延续（重置/移位）的简单示例：

import Control.Monad
import Control.Monad.Trans
import Control.Monad.Trans.Cont

test :: Integer
test = evalCont . reset $ do
    r <- shift $ \k -> do
        return $ k 10
    return $ 1 + r

λ> test1
11

它运作良好。

但是，我想将延续k提取为纯 function 以供将来使用，而不仅仅是在 shift 中调用它。

例如，我希望test2可以返回k ：

test2 :: Integer -> Integer
test2 = evalCont . reset $ do
    r <- shift $ \k -> do
        return $ k
    return $ 1 + r

但 GHC 抱怨：

    ? Couldn't match type 'Integer -> Integer' with 'Integer'
      Expected type: Cont (Integer -> Integer) (Integer -> Integer)
        Actual type: ContT
                       (Integer -> Integer)
                       Data.Functor.Identity.Identity
                       ((Integer -> Integer) -> Integer -> Integer)
    ? In a stmt of a 'do' block: return $ k
      In the expression: do return $ k
      In the second argument of '($)', namely '\ k -> do return $ k'
   |
88 |         return $ k
   |         ^^^^^^^^^^

任何人都可以帮助我解决这个问题吗？

谢谢。

Answer 1

标准Cont不完全通用。 “真实” Cont看起来像这样

newtype Cont    i o a =    Cont { runCont :: (a -> i) -> o }
-- versus the standard
newtype SadCont   r a = SadCont { sadCont :: (a -> r) -> r }
-- SadCont r a = Cont r r a

使用标准的SadCont是因为它支持>>=并以通常的类型return （因此它可以是Monad ）。 但是Cont内部的“真实”分隔延续允许每个shift从一种类型的延续中获取值，并将它们发送到上一个shift /以不同类型reset 。 在这种情况下，您只是将整个延续作为 function 从shift传递到reset 。

{-# LANGUAGE RebindableSyntax #-}
-- ^ placing this at the top of a file or passing -XRebindableSyntax to GHC allows do notation to use custom (>>=) and (>>)

-- not Monad operations!
return :: a -> Cont r r a
return x = Cont ($ x)
(>>=) :: Cont m o a -> (a -> Cont i m b) -> Cont i o b
Cont x >>= f = Cont $ \k -> x (($ k) . runCont . f)
(>>) :: Cont m o a -> Cont i m b -> Cont i o b -- RebindableSyntax also wants this
a >> b = a >>= const b

evalCont :: Cont a o a -> o
evalCont (Cont x) = x id

-- shift/reset are actually just
reset = evalCont
shift = Cont
-- note that the types of reset and shift differ significantly from transformers
-- reset returns a pure value here and shift requires a pure value from its function
-- I think my choices are more correct/standard, e.g. they line up with the old Scala shift/reset http://lampwww.epfl.ch/~hmiller/scaladoc/library/scala/util/continuations/package.html

在你的例子中

test2 :: Integer -> Integer
test2 = reset $ do
    r <- shift $ \k -> k
    return $ 1 + r

TL;DR Cont被故意“破坏”，因此它失去了不同输入和 output 类型的通用性，但获得了Monad icity。 正如您所发现的，您可以通过将输入和 output 类型放入（递归）总和来解决它。 或者（这个答案）您可以定义和使用“真实” Cont 。

Answer 2

受@BenjaminHodgson 评论的启发，这里是临时解决方案：

data Ret a = Fun (Integer -> Ret a) | Val a

instance Show a => Show (Ret a) where
    show (Fun f) = "Jst f"
    show (Val a) = show a

test2 :: Ret Integer
test2 = evalCont . reset $ do
    r <- shift $ \k -> do
         return $ Fun k
    return $ Val (1 + r)

main :: IO ()
main = do
        print $ case test2 of (Fun f) -> f 100
        print $ case test2 of (Fun f) -> f 50

λ> main
101
51

免责声明：我不确定递归类型Ret是否必要。

如果有人可以提供更好的解决方案或解释，我将不胜感激。 谢谢。