我的引导脚本中需要哪些内容才能将节点加入我的 EKS 集群？

Question

我正在为我的节点组使用启动模板，并且收到一条错误消息， NodeCreationFailure: Instances failed to join the kubernetes cluster看来我的问题是我需要一个引导脚本才能将节点加入集群。 这是我的用户数据脚本，这是我从这个文档中找到的一个示例

linux_user_data.tpl脚本尝试 #1

#!/bin/bash
set -e
${pre_bootstrap_user_data ~}
export SERVICE_IPV4_CIDR=${cluster_service_ipv4_cidr}
B64_CLUSTER_CA=${cluster_auth_base64}
API_SERVER_URL=${cluster_endpoint}
/etc/eks/bootstrap.sh ${cluster_name} ${bootstrap_extra_args} --b64-cluster-ca $B64_CLUSTER_CA --apiserver-endpoint $API_SERVER_URL
${post_bootstrap_user_data ~}

脚本尝试 #2

#!/bin/bash
set -o xtrace
/etc/eks/bootstrap.sh mtc-cluster

脚本尝试 #3

#!/bin/bash
set -o xtrace
/etc/eks/bootstrap.sh --apiserver-endpoint ${aws_eks_cluster.eks.endpoint} --b64-cluster-ca ${aws_eks_cluster.eks.certificate_authority}

这是我在 Terraform 中的启动模板，它应该使用这个用户数据脚本

resource "aws_launch_template" "node" {
  image_id                             = var.image_id
  instance_type                        = var.instance_type
  key_name                             = var.key_name
  name                                 = var.name
  user_data                            = base64encode("linux_user_data.tpl")

    block_device_mappings {
        device_name = "/dev/sda1"

    ebs {
      volume_size = 20
    }
  }
}

这也是我的节点组资源块

resource "aws_eks_node_group" "nodes_eks" {

  cluster_name    = aws_eks_cluster.eks.name
  node_group_name = "eks-node-group"
  node_role_arn   = aws_iam_role.eks_nodes.arn
  subnet_ids      = module.vpc.private_subnets

  scaling_config {
    desired_size = 3
    max_size     = 6
    min_size     = 3
  }

  ami_type             = "CUSTOM"
  capacity_type        = "ON_DEMAND"

  force_update_version = false

  launch_template {
    id      = aws_launch_template.node.id
    version = aws_launch_template.node.default_version
  }

  depends_on = [
    aws_iam_role_policy_attachment.amazon_eks_worker_node_policy,
    aws_iam_role_policy_attachment.amazon_eks_cni_policy,
    aws_iam_role_policy_attachment.amazon_ec2_container_registry_read_only,
  ]
}

Answer 1

根据问题和文档中发布的代码，第二个示例应该可以工作。 但是，我认为文件扩展名可能会绊倒加入集群的节点。 在第一次和第三次尝试中定义的脚本需要使用templatefile函数 [1]，因为否则无法将值提供给脚本，即使插值定义正确，如

/etc/eks/bootstrap.sh --apiserver-endpoint ${aws_eks_cluster.eks.endpoint} --b64-cluster-ca ${aws_eks_cluster.eks.certificate_authority}

文档 [2] 说在向节点提供配置时有几种可能性。 由于您使用的是 Amazon Linux 2，因此您应该按照 [3] 中的说明进行操作。 在这种情况下，您可以将templatefile函数与以下模板一起使用（让我们使用您已有的名称linux_user_data.tpl ）：

MIME-Version: 1.0
Content-Type: multipart/mixed; boundary="==MYBOUNDARY=="

--==MYBOUNDARY==
Content-Type: text/x-shellscript; charset="us-ascii"

#!/bin/bash
set -ex
/etc/eks/bootstrap.sh ${cluster_name} \
  --container-runtime containerd

--==MYBOUNDARY==--

由于 K8s 1.24版放弃了 Docker 作为容器运行时， --container-runtime设置为containerd 。 关于功能，没有区别，但这种方式（如果您不部署 1.24）将简化过渡。 在aws_launch_template资源中，您必须更改以下内容：

resource "aws_launch_template" "node" {
  image_id       = var.image_id
  instance_type  = var.instance_type
  key_name       = var.key_name
  name           = var.name
  user_data      = base64encode(templatefile("${path.root}/linux_user_data.tpl", {
                   cluster_name = aws_eks_cluster.eks.name
  }))

    block_device_mappings {
        device_name = "/dev/sda1"

    ebs {
      volume_size = 20
    }
  }
}

文档说唯一需要的参数是集群名称，因此请尝试使用此参数并在需要时进行相应更新。 还要注意path.root的用法，这意味着templatefile文件将在模块根目录所在的同一目录中查找文件。 如果要模块化代码，则可以切换到path.module 。 有关path的更多信息可以在 [4] 中找到。

编辑：为了使引导脚本按预期工作，必须使用 EKS 优化的 AMI。 每个区域的 AMI ID 可以在 [5] 中找到。

---

[1] https://www.terraform.io/language/functions/templatefile

[2] https://docs.aws.amazon.com/eks/latest/userguide/launch-templates.html#launch-template-user-data

[3] https://docs.aws.amazon.com/eks/latest/userguide/launch-templates.html#launch-template-custom-ami

[4] https://www.terraform.io/language/expressions/references#filesystem-and-workspace-info

[5] https://docs.aws.amazon.com/eks/latest/userguide/eks-optimized-ami.html