VBA 多个 if 语句

Question

我有以下代码可以正常工作。 使用多个 if 语句时有没有办法减少行数。 没有一个依赖于任何其他，它们都引用相同的工作表和范围。 滚动代码时它看起来不正确。 认为可能有更简洁的方法？ 我没有使用这些实际的变量名。

    If Not c.Offset(0, 3).Value = "" Then
        var1 = True
        var2 = c.Offset(0, 3).Value
    End If
    
    If Not c.Offset(0, 4).Value = "" Then
        var3 = True
        var4 = c.Offset(0, 4).Value
    End If
    
    If Not c.Offset(0, 5).Value = "" Then
        var5 = True
        var6 = c.Offset(0, 5).Value
    End If
    
    If Not c.Offset(0, 6).Value = "" Then
        var7 = True
        var8 = c.Offset(0, 6).Value
    End If
    
    If Not c.Offset(0, 7).Value = "" Then
        var9 = True
        var10 = c.Offset(0, 7).Value
    End If

Answer 1

您可以使用 switch 语句，或者不是为每个条件使用新的 if 语句，而是创建一个 else if，这使得代码更短且更具可读性。

Answer 2

避免使用大量变量（数组）

• 当您需要使用大量变量时，尤其是相同数据类型的变量，是时候考虑使用数据结构（数组、字典、集合...）了。
• 以下示例探讨了 arrays 的使用。 由于没有足够的信息，使用其他数据结构之一可能更合适。
• 要快速了解 arrays，您可以观看此Excel Macro Mastery playlist中的视频。

编码

Option Explicit

Sub ArraysInsteadOfTonsOfVariables()

    ' Using the Array function, write the column offsets to a variant array.
    ' (Using 'VBA.' in front of 'Array' ensures a zero-based array.)
    Dim ColumnOffsets() As Variant: ColumnOffsets = VBA.Array(3, 4, 5, 6, 7)
    
    ' Reference the initial cell ('iCell').
    ' ('ThisWorkbook' means the workbook containing this code.)
    Dim iCell As Range
    Set iCell = ThisWorkbook.Worksheets("Sheet1").Range("A1")
    
    ' Write the upper limit of the 'ColumnOffsets' array to a variable.
    ' (the lower limit is '0').
    Dim UB As Long: UB = UBound(ColumnOffsets)
    
    ' Define an array of the same size as the 'ColumnOffsets' array
    ' which will hold the booleans ('var1, var3, var5, var7, var9').
    Dim Booleans() As Boolean: ReDim Booleans(0 To UB)
    
    ' Define an array of the same size as the 'ColumnOffsets' array
    ' which will e.g. hold the strings ('var2, var4, var6, var8, var10').
    Dim Strings() As String: ReDim Strings(0 To UB)
    
    ' Print the title and the headers to the Immediate window ('Ctrl+G').
    Debug.Print "For cell '" & iCell.Address(0, 0) & "'"
    Debug.Print "Index", "Offset", "Address", "Boolean", "String"
    
    Dim cCell As Range ' current (offsetted) cell
    Dim cIndex As Long ' current index
    Dim cString As String ' current string
    
    ' Loop through the elements of the arrays (they are all of the same size).
    For cIndex = 0 To UB
        ' Reference the current cell.
        Set cCell = iCell.Offset(, ColumnOffsets(cIndex))
        ' Write the current string (string representation
        ' of the current cell's value) to a variable.
        cString = CStr(cCell.Value)
        If Len(cString) > 0 Then ' is not ""
        ' or 'If cString <> ""' or 'If cString <> vbNullString'
            Booleans(cIndex) = True
            Strings(cIndex) = cString
        'Else ' is "" ' do nothing
            ' Since the 'Booleans' array is declared 'As Boolean',
            ' each of its elements is assigned the default value 'False'.
            ' Since the 'Strings' array is declared 'As String',
            ' each of its elements is assigned the default value '""'.
        End If
        ' Print what was written to the arrays
        ' to the Immediate window ('Ctrl+G').
        Debug.Print cIndex, ColumnOffsets(cIndex), cCell.Address(0, 0), _
            Booleans(cIndex), Strings(cIndex)
    Next cIndex
    
End Sub

结果

For cell 'A1'
Index         Offset        Address       Boolean       String
 0             3            D1            True          Peter
 1             4            E1            False         
 2             5            F1            True          Helen
 3             6            G1            False         
 4             7            H1            True          John