如何防止thrust::copy_if非法memory访问

Question

在 CUDA C++ 代码中，我使用thrust::copy_if copy_if 将那些 integer 值从数组 x 复制到 y：

thrust::copy_if(x_ptr, x_ptr + N, y_ptr, is_not_minus_one());

我将代码放在 try/catch 中，并定期更新数组 x，然后再次将非 -1 的数字推送到 y 的末尾，直到它访问数组外并返回

CUDA Runtime Error: an illegal memory access was encountered

由于我不知道每次迭代中有多少值不是 -1，我应该继续在主数组中生成和复制数字，直到它变满为止。 但是，我希望它在到达数组末尾时停止。 我该如何管理它？

一个天真的想法是使用另一个数组，然后在新值的数量不超过大小的情况下进行复制。 但它可能效率低下。 有更好的主意吗？

Answer 1

这是一种可能的方法：

在x上使用remove_if()代替，（具有相反的条件 - 删除 if -1）。 然后使用（ x start 和）返回的迭代器复制到最终数组（ y ）。 每次对y进行复制时，都会知道y中剩余多少空间，并且可以在复制之前根据需要调整复制数量。

示例（删除 1 个值）：

$ cat t2088.cu
#include <thrust/device_vector.h>
#include <thrust/host_vector.h>
#include <thrust/complex.h>
#include <thrust/transform.h>
#include <thrust/copy.h>
#include <thrust/functional.h>
#include <iostream>

using mt = int;
using namespace thrust::placeholders;
int main(){

  thrust::device_vector<mt> a(5);
  thrust::device_vector<mt> c(25);
  bool done = false;
  int empty_spaces = c.size();
  int copy_start_index = 0;
  while (!done){
    thrust::sequence(a.begin(), a.end());
    int num_to_copy = (thrust::remove_if(a.begin(), a.end(), _1 == 1) - a.begin());
    int actual_num_to_copy = std::min(num_to_copy, empty_spaces);
    if (actual_num_to_copy != num_to_copy) done = true;
    thrust::copy_n(a.begin(), actual_num_to_copy, c.begin()+copy_start_index);
    copy_start_index += actual_num_to_copy;
    empty_spaces -= actual_num_to_copy;
    }
  std::cout << "output array is full!" << std::endl;
  thrust::host_vector<mt> h_c = c;
  thrust::copy(h_c.begin(), h_c.end(), std::ostream_iterator<mt>(std::cout, ","));
  std::cout << std::endl;
}
$ nvcc -o t2088 t2088.cu
$ compute-sanitizer ./t2088
========= COMPUTE-SANITIZER
output array is full!
0,2,3,4,0,2,3,4,0,2,3,4,0,2,3,4,0,2,3,4,0,2,3,4,0,
========= ERROR SUMMARY: 0 errors
$