使用 Cp5 库在处理中启用和禁用文本字段

Question

使用 Cp5，我正在尝试创建一个文本字段。 我希望用户只能在单击按钮后编辑文本字段。 如果未按下按钮，用户将无法编辑文本字段。 Textfield 是否有方法可以帮助我处理这个 function？ 我问是因为我没有找到库中方法的任何文档。

Answer 1

setLock() 应该做你想做的事：

import controlP5.*;

ControlP5 cp5;

String textValue = "";

public void lock() {
  cp5.get(Textfield.class, "textField").setLock(true);
}

public void unlock() {
  cp5.get(Textfield.class, "textField").setLock(false);
}

void setup() {
  size(700, 400);
  background(0);
  fill(255);
  PFont font = createFont("arial", 20);
  cp5 = new ControlP5(this);

  cp5.addTextfield("textField")
    .setPosition(60, 100)
    .setSize(150, 30)
    .setFont(createFont("arial", 18))
    .setAutoClear(false)
    .setLock(false);
  ;

  cp5.addBang("lock")
    .setPosition(240, 100)
    .setSize(60, 30)
    .getCaptionLabel().align(ControlP5.CENTER, ControlP5.CENTER)
    ;

  cp5.addBang("unlock")
    .setPosition(330, 100)
    .setSize(60, 30)
    .getCaptionLabel().align(ControlP5.CENTER, ControlP5.CENTER)
    ;
  textFont(font);
}

void draw() {
  
}