将批处理命令的返回值存储到变量中

Question

我可以在 cmd 提示符中运行此行并返回一行：

powershell -NoLogo -NoProfile "Get-Item -Path HKCU:\SOFTWARE\Microsoft\Windows\CurrentVersion\Explorer\FeatureUsage\AppSwitched ^| Select-Object -ExpandProperty Property ^| Where-Object { $_ -Match 'steamapps\\common\\Among Us\\Among Us.exe' }"

但是如何在批处理脚本中使用它？ 我尝试了这个和其他一些东西，但它不起作用：

@echo off 
set psScript=powershell -NoLogo -NoProfile "Get-Item -Path HKCU:\SOFTWARE\Microsoft\Windows\CurrentVersion\Explorer\FeatureUsage\AppSwitched ^| Select-Object -ExpandProperty Property ^| Where-Object { $_ -Match 'steamapps\\common\\Among Us\\Among Us.exe' }"

for /F "delims=" %L in (%psScript%) do (set "VAR=%%L")

echo %VAR%

Answer 1

您可以通过批处理文件中的注册表项确定特定可执行文件的位置，而无需使用 powershell.exe。

显示应用程序路径：

@Echo Off
SetLocal EnableExtensions
PushD "%SystemDrive%\"
For /F "Delims=" %%G In ('%SystemRoot%\System32\reg.exe Query "HKCU\SOFTWARE\Microsoft\Windows\CurrentVersion\Explorer\FeatureUsage\AppSwitched" /F "\Among Us.exe" /V 2^>NUL ^| %SystemRoot%\System32\findstr.exe /IRC:"\\Among Us\.exe\>"') Do For /F "Tokens=1,*" %%H In ("%%~dpG.") Do Echo %%~fI
PopD
Pause

将应用程序路径保存为变量：

@Echo Off
SetLocal EnableExtensions
PushD "%SystemDrive%\"
Set "AppPath="
For /F "Delims=" %%G In ('%SystemRoot%\System32\reg.exe Query "HKCU\SOFTWARE\Microsoft\Windows\CurrentVersion\Explorer\FeatureUsage\AppSwitched" /F "\Among Us.exe" /V 2^>NUL ^| %SystemRoot%\System32\findstr.exe /IRC:"\\Among Us\.exe\>"') Do For /F "Tokens=1,*" %%H In ("%%~dpG.") Do Set "AppPath=%%~fI"
PopD
If Defined AppPath (Echo %AppPath%& Pause)