如何在批处理中使用字符串的长度 TOUPPER 字符串？

Question

在一些帮助下，我创建了一个 function 来获取字符串的长度。 现在使用该长度，我想通过大写字符串的内容来清除从快捷方式收到的输入。 但是，我似乎无法找到一种方法来指定要在字符串中将字符大写的位置。 我有 rest 的代码，我想，我只是找不到一种方法来告诉我要在字符串中的哪个位置进行更改。 这是我到目前为止所拥有的：

@ECHO on
TITLE Navigator
SETLOCAL enabledelayedexpansion

REM | ...file comments...

REM | variable setting, grabbing & cleaning
SET _box=%1
SET _system=%_box:~1,-1%
CALL :STRLEN _system _len
CALL :CLEANER _system _len _cSystem

REM | Results
ECHO Cleaned output: %_cSystem%

PAUSE
ENDLOCAL
EXIT /B %ERRORLEVEL%

REM | ***** Functions *****
REM | String length function (last working @ 09/26/22 TIME)
:STRLEN
  SET $str=!%1!
  SET $len=0
:_STRLEN
  IF NOT DEFINED $str ( goto :END_STRLEN )
  IF NOT "!$str:~%$len%!"=="" (
    SET /A $len+=1
    goto :_STRLEN
  )
:END_STRLEN
  SET "%2=!$len!"
  SET $str=
  SET $len=
  EXIT /B 0

REM | String cleaner (currently in progress)
:CLEANER
  SET $str=!%1!
  SET $len=!%2!
:_CLEANER
  IF NOT DEFINED $str ( goto :END_CLEANER )
  IF "$len">=0 (
    SET $str:[POSITION @ $len]=$str:[POSITION @ $len]
    SET /A %$len%-=1
    GOTO :_CLEANER
  )
:END_CLEANER
  SET "%3=!$str!"
  SET $str=
  SET $len=
  EXIT /B 0

问题在第二个IF语句中的:_CLEANER底部附近，它尝试将$str字符串中的一个字符设置为自身，以便批处理自己进行大写。 对此的任何帮助将不胜感激。

Answer 1

@ECHO OFF
SETLOCAL
set "ucalphas=A B C D E F G H I J K L M N O P Q R S T U V W X Y Z"
set "lcalphas=a b c d e f g h i j k l m n o p q r s t u v w x y z"
set "mystring=abcddcbajqz123HELLO teSt"
echo start         %mystring%
call :toupper mystring
echo after toupper %mystring%
call :tolower mystring
echo after tolower %mystring%

GOTO :EOF

:toupper
setlocal enabledelayedexpansion
set "result=!%1!"
for %%s in (%ucalphas%) do set "result=!result:%%s=%%s!"
endlocal&set "%1=%result%"
goto :eof

:tolower
setlocal enabledelayedexpansion
set "result=!%1!"
for %%s in (%lcalphas%) do set "result=!result:%%s=%%s!"
endlocal&set "%1=%result%"
goto :eof

这是一个启动器，使用字符串替换，它用相同的字符（字面意思）替换第一个“字符串”（好的，它是一个字符）不区分大小写。

IF "$len">=0 (

不管用。 比较是逐个字符的。 一侧引用，另一侧未引用。 您想要$len的内容，而不是文字$len ，因此%$len%和比较运算符是 ==、equ neq、gtr、geq、lss、leq。 除==之外的所有内容都必须用空格包围。 >是一个重定向器。

注意set "var=value"的使用。 此语法确保行上的尾随空格不包含在值set 。

Answer 2

尽管您的问题专门针对纯batch-file ，但我只是将其放在那里以供参考。

对于这些类型的任务，我宁愿 go 和Powershell

例如，我们可以将字符串中每个单词的首字母大写：

$str = 'john m smith'
$result = (Get-Culture).TextInfo
$result.ToTitleCase($str)

这将导致John M Smith

显然，这可以从batch-file中调用为：

@echo off
for /f "delims=" %%i in ('powershell "$str = 'john m smith';$result = (Get-Culture).TextInfo;$result.ToTitleCase($str)"') do echo %%i

要将整行推到较低或较高，我们只需使用string.toUpper()或 `"string".toLower()。 所以在批处理文件中我们可以运行：

上：

for /f "delims=" %%i in ('powershell "$str = 'john m smith';"$str".ToUpper()"') do echo %%i

降低：

for /f "delims=" %%i in ('powershell "$str = 'john m smith';"$str".ToLower()"') do echo %%i

然后，作为旁注，可以使用"sting".length轻松检索字符串长度，再次可用作batch-file中的 function

for /f "delims=" %%i in ('powershell "$str = 'john m smith';$str.length"') do echo %%i

PS！！ 这些最好用作独立的ps1脚本，但我已经包含了batch-file ，如果您需要将其合并到现有的大型batch-file