从 function 收集值到 Julia

Question

我的问题是关于 Julia 广播运营商的使用。

假设我有以下对象

M = [0.7 0.3; 0.4 0.6];
x0 = [100 100];
N=5;
y = zeros(N, size(x0)[2]);

function Markov_bling_bling(;Trans_mat, initial_states, n_ahead)
    # Define useful names
    M = Trans_mat; x0 = initial_states; N = n_ahead;
    # Compute the N-th state 
    xn = x0 * M^N
    return(x_n = xn)
end

（对不起这个愚蠢的名字）

所以这个 function 返回一个 1x2 向量。

所以我想将每个xn作为一行存储在y中。

在 R 中，我会这样做：

y <- list()
for(t in 1:(N+1)){
  y[t] = Markov_bling_bling(Trans_mat = M, initial_states = x0, n_ahead=(t-1))
}

y <- Reduce(rbind,x)

我如何在 Julia 中完成此操作？ 我知道我必须使用广播运算符以避免for loop 。

但我仍然不知道如何存储结果，我应该定义y = []吗？ Julia 存储结果的方式是什么？

提前致谢！

Answer 1

它可以用与 R 几乎相同的方式编写：

julia> reduce(vcat, [Markov_bling_bling(Trans_mat = M, initial_states = x0, n_ahead=(t-1)) for t in 1:N])
5×2 Matrix{Float64}:
 100.0   100.0
 110.0    90.0
 113.0    87.0
 113.9    86.1
 114.17   85.83

Answer 2

Bogumił 的回答是更好的直接翻译，但我可以建议一个更有效的版本：

julia> function blingblings(x0, M, N)
           ys = similar(x0, size(x0, 2), N)
           ys[:, 1] = x0
           for i = 2:N
               ys[:, i] = ys[:, i-1]' * M
           end
           return ys
       end
blingblings (generic function with 1 method)

julia> blingblings(x0, M, 5)
2×5 Matrix{Float64}:
 100.0  110.0  113.0  113.9  114.17
 100.0   90.0   87.0   86.1   85.83

最重要的是，这避免了每次求幂的二次复杂性，并且更好地尊重 Julia arrays 的列优先性质。 for 循环没有错。

（我想发布一个使用accumulate的解决方案，但不幸的是，它的init参数并没有像我预期的那样以结果结尾，这使得该解决方案不符合您的要求：

julia> ys = accumulate(1:5; init=x0) do y, _
           (y * M)::Matrix{Float64}
       end
5-element Vector{Matrix{Float64}}:
 [110.0 90.0]
 [113.0 87.0]
 [113.89999999999999 86.1]
 [114.16999999999999 85.82999999999998]
 [114.25099999999998 85.74899999999998]

)