如何重定向 echo text=1>script.conf

Question

如果我启动以下命令，则在 DOS 提示符下

echo text=1>script.conf

在 script.conf 中将写入text=而不是text=1我该如何解决这个问题？

谢谢。

Answer 1

>之前的数字是一种特殊语法，其中数字是 C 库意义上的文件描述符（ 1 是 stdout，2 是 stderr ）。

当 cmd.exe 看到>它实际上会删除>之前的数字（如果有的话）和它之后的文件名，然后将剩余的文本作为命令执行。 因此，您实际上是在说； 获取echo text=的标准输出结果并将其写入文件script.conf 。

始终有效的解决方案是对其重新排序，以便重定向优先：

>script.conf echo text=1

如果您不介意文件行尾的额外空格，您可以执行以下操作：

echo text=1 >script.conf

Answer 2

感谢 Stephan，我还根据他的解决方案编写了一个宏：

@echo on

:: Define LF as a Line Feed (newline) string
set LF=^


::Above 2 blank lines are required - do not remove

::define a newline with line continuation
:: set ^"\n=^^^%LF%%LF%^%LF%%LF%^^" this is an old style and more complex \n definition
:: Next is the modern style \n definition
(set \n=^^^
%=EMPTY=%
)

set @{CreaPPosEth-Log.properties}=for %%. in (1 2) do if %%.==2 (for %%L in ("!LF!") DO ( %\n%
    set /a "I=1" %\n%
    for /f "tokens=* delims=" %%1 in ("!args: =%%~L!") do (%\n%
        set "par.!I!=!%%~1!" %\n%
        set /a "I+=1" %\n%
      )%\n%
      %= Inizio della vera macro =% %\n%
      ^>!par.1! echo BillPayment=0%\n%
      ^>^>!par.1! echo GTType=1%\n%
      %= Fine macro =% %\n%
      endlocal %\n%
)) else setlocal EnableDelayedExpansion ^& set args=

set "conf1=.\PPosEth.properties"
%@{CreaPPosEth-Log.properties}% conf1

:ESCI
exit /b 1000