如何使用批处理编辑txt文件中的随机数

Question

大家好，我需要一些帮助

我正在尝试编辑一个 txt 文件，但它前面没有数据，所以我很难找到编辑 txt 文件的方法

这是我的脚本

@ECHO Off
setlocal ENABLEDELAYEDEXPANSION
cd /d "%~dp0"

set "Mfind=    %Random%"

@For %%G In ("%~dp03Ready\NSB") Do Set "sourcedir=%%~fG"
@For %%G In ("%~dp03Ready\NSBEdited") Do Set "destdir=%%~fG"

Set /p "FPats=Enter Your Amount: 

FOR /f "delims=" %%q IN ('dir /b /s /a-d "%sourcedir%\(09)Fus.txt"') DO (
 rem calculate new destination directory
 SET "newdest=%%~dpq"
 SET "newdest=!newdest:%sourcedir%=%destdir%!"
 SET "newdest=!newdest:~0,-1!"
 MD "!newdest!" 2>nul

(
  for /F "tokens=1* delims=:" %%a in ('findstr /N "^" "%%q"') do (
   set "line=%%b"
   if defined line IF "%%b" neq "!line:%Random%=!" CALL :nidC1
      echo(!line!
 )
)>"!newdest!\%%~nxq" 

)
GOTO :NSBEditing

:nidC1
SET "line=%line:-=%"
SET "original=%line%"
FOR /L %%s IN (0,1,9) DO set "line=!line:%Mfind%%%s=%Mfind%!"
IF "%original%" neq "%line%" goto nidC1
set "line=!line:%Mfind%=%Mfind%%FPats%!"
GOTO :eof

这是我的 txt 文件文本文件 cna 达到 100K 行甚至更多，这只是其中的一小部分

(09)福斯.txt

    "cpup": [
    {
      "upma": "id",
      "upnn": 0,
      "upfb": true,
      "upcu": {
        "adid": "Dge_ChngerSTemon_2018_nit2",
        "ulid": "TT_UPADE_NROU03",
        "upty": "NOUS",
        "isnc": false,
        "erpm": 0
      }
    },
    58, < ---------------- Trying to edit these numbers
    {
      "upma": "id",
      "upnn": 0,
      "upfb": true,
      "upcu": {
        "adid": "lphaSixoSSCrewcycled_016_tur1",
        "ulid": "TT_RADE_TUO02",
        "upty": "BO",
        "uplv": 1,
        "erpm": 0,
        "adtc": [
          {
            "kfti": 1000.0,
            "kfva": 0.321
          }
        ]
      }
    },
    70 < ---------------- Trying to edit these numbers
  ],

Answer 1

下面的 function 可以用来修改只包含空白数字和 ',' 的行，表示必填参数，参数位置是固定的。

它使用一个标志将行标记为仅数字 - 如果在删除这些 delims 后该行不为空，则带有 delims 的 For /f 循环会覆盖该标志。

@Echo off

:ReplaceNum <inputfilepath.ext> <outputfilepath.ext>
    Set "ScriptName=%~0"
    For /f "tokens=1,2* Delims=:" %%G in (":.%ScriptName%")Do If "%%G"=="." Set "ScriptName=Call :%%H"
    If "%~1"=="" (
        Echo(%ScriptName% ^<inputfilepath.ext^> ^<outputfilepath.ext^>
        Exit /B 0
    )

    %= Error 1; No Source =%            If not Exist "%~1" Exit /B 1
    %= Error 2; Filepaths Same =%       If "%~1"=="%~2" Exit /B 2

    Set "Class="
    1>"%~2" (
        For /f "usebackq delims=" %%G in ("%~1")Do (
            Set "Line=%%G"
            Setlocal EnableDelayedExpansion
            Set "isnum=true"
            For /f "delims=0123456789, " %%i in ("!Line!")Do Set "isnum=false"
            If "!isnum!"=="true" (
                Set "nLine=!Line: =!"
                Set "nLine=!nLine:,=!"
                Mode 120,40
                1> Con Call :GetNum Replace number:'!nLine!' for Class: !Class!
                For /f "tokens=1,2" %%i in ("!nLine! !Num!")Do Echo(!Line:%%i=%%j!
                Set "Class="
            )Else (
                Set ^"cLine=!Line:"=!"
                For /f "tokens=1,2 delims=:," %%u in ("!Line!")Do If not "%%~b"=="" Set "Class=!Class! %%u"
                For %%c in ("{" "}" "[" "]") Do Set "Class=!Class:%%~c=!"
                For /L %%i in (1 1 4)Do Set "Class=!Class:  = !"
                Echo(!Line!
            )
            For /F "Delims=" %%c in ("!Class!")Do Endlocal & Set "Class=%%c"
        )
    )

Exit /B 0

:GetNum
(   Set LF=^


%= Linefeed Definition - Do not modify =%)
    Set "Num="
    Set /P "Num=%*!LF!>:"
    2> nul Set /A "Num+=0","1/Num" || Goto:GetNum
Exit /B 0

Answer 2

行。 在这里，我们 go（再次）...

第一步：（试图）识别要编辑的行：

@echo off
setlocal EnableDelayedExpansion

set "last=1"
set "lines=:"
for /F "delims=:" %%a in ('findstr /N "{ } ]" (09)Fus.txt') do (
   set /A "prev=%%a-2, line=%%a-1"
   if !prev! equ !last! set "lines=!lines!!line!:"
   set "last=%%a"
)

for /F "tokens=1* delims=:" %%a in ('findstr /N "^" (09)Fus.txt') do (
   if "!lines::%%a:=!" neq "%lines%" (
      echo %%b   ^< - This line will be edited
   ) else (
      echo %%b
   )
)

Output 示例：

    "cpup": [
    {
      "upma": "id",
      "upnn": 0,
      "upfb": true,
      "upcu": {
        "adid": "Dge_ChngerSTemon_2018_nit2",
        "ulid": "TT_UPADE_NROU03",
        "upty": "NOUS",
        "isnc": false,
        "erpm": 0
      }
    },
    58,   < - This line will be edited
    {
      "upma": "id",
      "upnn": 0,
      "upfb": true,
      "upcu": {
        "adid": "lphaSixoSSCrewcycled_016_tur1",
        "ulid": "TT_RADE_TUO02",
        "upty": "BO",
        "uplv": 1,
        "erpm": 0,
        "adtc": [
          {
            "kfti": 1000.0,
            "kfva": 0.321
          }
        ]
      }
    },
    70   < - This line will be edited
  ],

Answer 3

非常感谢您帮助我解决我的问题，我 100% 确定您的脚本工作得很好，但我仍然有点难以理解它们，但好消息是我找到了解决它的方法，这并不是最好的方法你们提供的东西，但它完成了工作

我所做的是将 3 个脚本组合在一起来查找和更改找到的数字
这里是58,它现在执行XXXXX,8,
这样做现在给了我一个代码来查找我set的时间
接下来我有一个清洁器，它会找到,8并将其删除
接下来我有一个编辑器来查找XXXXX并使用键入的输入进行编辑

这是我最后更新的脚本

:EditingData
@ECHO Off
setlocal ENABLEDELAYEDEXPANSION
cd /d "%~dp0"

set "FindA1=    "

SET "LETTER=XXXXX,"


@For %%G In ("%~dp0Folder1") Do Set "sourcedir=%%~fG"
@For %%G In ("%~dp0Folder2") Do Set "destdir=%%~fG"

FOR /f "delims=" %%q IN ('dir /b /s /a-d "%sourcedir%\TXTFilename.txt"') DO (
 rem calculate new destination directory
 SET "newdest=%%~dpq"
 SET "newdest=!newdest:%sourcedir%=%destdir%!"
 SET "newdest=!newdest:~0,-1!"
 MD "!newdest!" 2>nul

(
  for /F "tokens=1* delims=:" %%a in ('findstr /N "^" "%%q"') do (
   set "line=%%b"
   if defined line IF "%%b" neq "!line:=!" CALL :Gas1
   echo(!line!
 )
)>"!newdest!\%%~nxq" 

)
GOTO :FusCleaner1

:Gas1
SET "line=%line:-=%"
SET "original=%line%"
FOR /L %%s IN (0,1,9) DO set "line=!line:%FindA1%%%s=%FindA1%1!"
IF "%original%" neq "%line%" goto Gas1
set "line=!line:%FindA1%1=%FindA1%%LETTER%!"
GOTO :eof

:FusCleaner1
@echo off

set "source=Folder2"
set "target=Folder2"
set "file=TXTFilename.txt"

setlocal enableDelayedExpansion
(
   for /F "tokens=1* delims=:" %%a in ('findstr /N "^" "%source%\%file%"') do (
      set "line=%%b"
rem This part deletes from file
      if defined line set "line=!line:,0=!"
      if defined line set "line=!line:,1=!"
      if defined line set "line=!line:,2=!"
      if defined line set "line=!line:,3=!"
      if defined line set "line=!line:,4=!"
      if defined line set "line=!line:,5=!"
      if defined line set "line=!line:,6=!"
      if defined line set "line=!line:,7=!"
      if defined line set "line=!line:,8=!"
      if defined line set "line=!line:,9=!"
      echo(!line!
   )
) > "%target%\%file%.bak"

del "Folder2\%file%"
ren "Folder2\%file%.bak" "%file%"
goto :FusCleaner2

:FusCleaner2
@ECHO Off
setlocal ENABLEDELAYEDEXPANSION
cd /d "%~dp0"

set "FindA2=   "

@For %%G In ("%~dp0Folder2") Do Set "sourcedir=%%~fG"
@For %%G In ("%~dp0Folder2") Do Set "destdir=%%~fG"

set /P FusPQ=Enter Parts Quantity: 

FOR /f "delims=" %%q IN ('dir /b /s /a-d "%sourcedir%\%file%"') DO (
 SET "newdest=%%~dpq"
 SET "newdest=!newdest:%sourcedir%=%destdir%!"
 SET "newdest=!newdest:~0,-1!"
 MD "!newdest!" 2>nul

(
   for /F "tokens=1* delims=:" %%a in ('findstr /N "^" "%%q"') do (
   set "line=%%b"
   if defined line IF "%%b" gtr "!line:XXX=!" CALL :FPTS4
   echo(!line!
 )
)>"!newdest!\%file%.bak" 
del "Folder2\%file%"
ren "Folder2\%file%.bak" "%file%"
)
GOTO :eof

:FPTS4
SET "original=%line%"
FOR /L %%s IN (0,1,9) DO set "line=!line:%FindA2%%%s=%FindA2%XXXXX!"
IF "%original%" gtr "%line%" goto FPTS4
set "line=!line:%FindA2%XXXXX=%FindA2%%FusPQ%!"
GOTO :eof