尝试自动创建分析中使用的年份 Label

Question

假设我有 5 年的数据，用于计算这些汇总年份的某些指标。 有时这些是连续 5 年，而其他时候某一年的数据不可用，因此必须跳过。 例如 2016-2020 与 2015-2017 和 2019-2020。 在这种情况下，2018 年的数据不可用。我得到了一套关于如何呈现这些年份的规则。

连续年份应为 ex: 2016-2020

非连续年份会根据缺失年份的发生位置而略有不同。

• 2015-2017 & 2019-2020
• 2010, 2012, 2014, 2016 & 2017
• 2015-2018 & 2020

虽然仅仅生成一个逗号分隔的所有使用年份列表是微不足道的，但这就是他们想要呈现年份的方式。 这些标签用于一系列不同的度量，因此我试图在宏中自动创建这些标签。 数据的年数也不总是5，可能是3年，甚至10年。

显而易见的第一个想法是从最小年份开始并逐步与分析中使用的下一年进行比较以查看这些年份是否连续的过程。 考虑到年数并不总是 5，这是迄今为止最有意义的，但我并没有经常使用 do until 循环。 因此，我无法完全弄清楚如何在 do until 循环的迭代中逐步构建 label，同时还遵守这些规则。

对于此示例，我们使用 2015、2016、2017、2019、2020 年。

任何帮助将不胜感激。

Answer 1

这应该让你开始。

data test;
    infile cards dsd;
    input x @@;
    d = dif(x); /*used to create RUN when dif > 1 increment run*/
    if d eq . or d > 1 then run+1;
    cards;
2015,2016,2017,2019,2020,2022,2024,2025,2026
;;;;
    run;
proc print;
    run;
proc summary data=test nway; /*count the number of years in each run*/
    class run;
    output out=runlen(drop=_type_);
    run;
data test; /* merge TEST and RUNLEN*/
    length list $128;
    do until(last.run); /*loop until last.run*/
        merge test runlen;
        by run;
        if first.run then list = cats(x); /*start of list*/
        end;    
     select(_freq_); /*based on run-length create LIST */
        when(1);
        when(2)   list = catx(' & ',list,x);
        otherwise list = catx('-',list,x);
        end;
    run;
 proc print;
    run;

Answer 2

这可能是一张图片值一千字的案例。

例子：

/* simulate raw results of a survey of 10 questions over 16 years */
data surveyresults;
  call streaminit(20230125);
  do qid = 1 to 10;
    do year = 2007 to 2022;
      if year = 2021 then continue;
      if rand('uniform') > 0.85 then continue;
      do _n_ = 1 to rand('integer', 30);
        pid + 1;
        if rand('uniform') > 0.85 then continue;
        answercode = rand('integer', 20);
        output;
      end;
    end;
  end;
run;

proc sql noprint;
  create table stage1 as
  select distinct qid, year, 1 as flag
  from surveyresults
  order by qid, year
  ;
  
  select catx(' ', min(year), 'to', max(year))
  into :year_range
  from stage1 ;

ods html file='plot.html';

proc sgplot data=stage1;
  scatter x=year y=qid / markerattrs=(symbol=squarefilled size=8.2%);
  xaxis values=(&year_range);
  yaxis type=discrete;
run;

ods html close;

Answer 3

可能比这更简单，但这适用于您的场景。

data years;
input year;
cards;
2015
2016
2017
2019
2020
;
run;

/* data years; */
/* input year; */
/* cards; */
/* 2010 */
/* 2012 */
/* 2014 */
/* 2016 */
/* 2017 */
/* ; */
/* run; */

/* data years; */
/* input year; */
/* cards; */
/* 2015 */
/* 2016 */
/* 2017 */
/* 2018 */
/* 2020 */
/* ; */
/* run; */



data want;
merge years end=eof years(firstobs=2 rename=year=next_year);
length year_list $200. interval $20.;;
retain year_list start_year;

_dif= next_year - year;
if _n_=1 then start_year=year; 

if _dif > 1 or eof  then do;


if start_year ne year then interval = catx('-', start_year, year);
else interval = put(start_year, 8. -l);



 if eof then year_list=catx(" & ", year_list, interval); 
 else year_list = catx(", ", year_list, interval); 

start_year = next_year;
end;

if eof then call symputx('year_list', year_list);
run;

%put &year_list;

Answer 4

此版本创建组合列表。 我认为它具有您描述的功能。

data test;
    infile cards dsd;
    input x @@;
    d = dif(x); /*used to create RUN when dif > 1 increment run*/
    if d eq . or d > 1 then run+1;
    cards;
2015,2016,2017,2019,2020,2022,2024,2025,2026
;;;;
    run;
proc print;
    run;

data list(keep=combinedlist);
    length list $128 combinedList $256;
    do while(not eof);
        list=' ';
        do runlength=1 by 1 until(last.run); /*loop until last.run*/
            set test end=eof;
            by run;
            if first.run then list = cats(x); /*start of list*/
            end;    
         select(runlength); /*based on run-length create LIST */
            when(1);
            when(2)   list = catx(' & ',list,x);
            otherwise list = catx('-',list,x);
            end;
        combinedList = catx(', ',combinedList,list);
        end;
    output;
    stop;
    run;
 proc print;
    run;