Mocking 与 Spock 返回 null 嵌套 mocking 和存根

Question

我正在使用 Spock 为一系列嵌套对象编写单元测试。 我正在为其编写测试的代码非常遗留，不使用依赖注入。 然而，它也是非常关键的任务，所以除非我真的需要，否则我宁愿不碰它。

这是我要测试的 class 的构造函数：

public SqlTable(Connection conn, String query) throws Exception {
    this.statement = conn.createStatement();
    this.resultSet = statement.executeQuery(query);

    meta = resultSet.getMetaData();
    int n = meta.getColumnCount();
    columns = new Column[n];

    for (int c = 0; c < n; c++) {
        columns[c] = new Column(meta.getColumnName(c+1));
        // ...
    }
}

在测试中，我将嵌套模拟存根到.groovy文件中，如下所示：

def "initialising a SQL table"() {
    given:
    def COL_NAME = "someColumnName"
    def mockResSetMeta = Mock(ResultSetMetaData) {
        getColumnCount() >> 1
        getColumnName(_ as int) >> COL_NAME
    }

    and:
    def mockResSet = Mock(ResultSet) {
        getMetaData() >> mockResSetMeta
    }

    and:
    def mockStatement = Mock(Statement) {
        executeQuery(_ as String) >> mockResSet
    }

    and:
    def mockConn = Mock(Connection) {
        createStatement() >> mockStatement
    }

    when: "SqlTable object"
    def table = new SqlTable(mockConn, "some query")

    then: "the table contains the categorical column"
    table.columns[0].getName() == COL_NAME
}

但是测试失败。 通过调试，我发现，在SqlTable构造函数中，当调用getColumnName()时， ResultSetMetaData object 的模拟总是返回null 。

我做了一些挖掘，这似乎是由于 Spock 如何一起处理存根和 mocking。 我在 SO 上找到了两个有希望的答案：

• Spock mock 返回错误值
• 当检查调用时，模拟方法返回 null

然而，对于我的生活，我无法修改测试以使其工作。

Answer 1

问题在于这一行getColumnName(_ as int) >> COL_NAME当您将其更改为getColumnName(_ as Integer) >> COL_NAME或只是getColumnName(_) >> COL_NAME时，它会起作用。

我目前关于为什么会发生这种情况的假设是模拟中的实际 arguments 作为Object[]传递并且不能包含原始类型。

这是一个可运行的复制器

import spock.lang.*;
import java.sql.*;

class ASpec extends Specification {
    def "initialising a SQL table"() {
        given:
            def COL_NAME = "someColumnName"
            def mockResSetMeta = Mock(ResultSetMetaData) {
                getColumnCount() >> 1
                getColumnName(_ as Integer) >> COL_NAME
            }

        and:
            def mockResSet = Mock(ResultSet) {
                getMetaData() >> mockResSetMeta
            }

        and:
            def mockStatement = Mock(Statement) {
                executeQuery(_ as String) >> mockResSet
            }

        and:
            def mockConn = Mock(Connection) {
                createStatement() >> mockStatement
            }

        when: "SqlTable object"
        def table = new SqlTable(mockConn, "some query")

        then: "the table contains the categorical column"
        table.columns[0].getName() == COL_NAME
    }
}

@groovy.transform.Canonical
class Column {
    String name
}

class SqlTable {
    def columns
    public SqlTable(Connection conn, String query) throws Exception {
        def statement = conn.createStatement();
        def resultSet = statement.executeQuery(query);

        def meta = resultSet.getMetaData();
        int n = meta.getColumnCount();
        columns = new Column[n];

        for (int c = 0; c < n; c++) {
            columns[c] = new Column(meta.getColumnName(c+1));
            // ...
        }
    }
}

在Groovy Web 控制台试试

为了将来参考，我通过实际执行 mocking 而不仅仅是存根来轻松检测到问题。

then:
1 * mockResSetMeta.getColumnName(_ as int) >> COL_NAME

将打印

               1 * mockResSetMeta.getColumnName(_ as int) >> COL_NAME   (0 invocations)
            
               Unmatched invocations (ordered by similarity):
            
               1 * mockResSetMeta.getColumnName(1)
               One or more arguments(s) didn't match:
               0: argument instanceof int
                  |        |          |
                  |        false      int
                  1 (java.lang.Integer)