如何正确更改自定义文本框（形状）内的文本？

Question

我有一个自动将文本框形状插入图表并为该文本框提供正确文本和字体的宏。 虽然它目前按原样工作，但我想更好地了解如何在不在文本框形状上使用 .Select 的情况下执行此操作。 .Select方法允许我包含.ColorIndex 、 .Strikethrough 、 .Superscript等，但我不得不将.Textframe2.TextRange.Font.Fill.Forecolor.RGB放在 With Selection 块之外以更改颜色。 （我当前“更新”文本框的方法会删除图表中所有现有的文本框并添加一个新文本框）。

我已经尝试摆脱.Select并使用“With txt1.Character(Start:=1, Length:=216).Font”并将所有意外事件放入此 With 块中，但某些行会出现错误（我已阅读最好避免使用 .Select 引用）。

真的只是想更好地了解如何正确有效地使用宏来更新图表中的文本框。

Sub UpdateChart()
Dim chrtobj As ChartObject
Dim txt1 As Shape
Dim cht1 As Chart
Dim wkbk As Workbook

Set wkbk = ActiveWorkbook
Set cht1 = Sheets("Profit & Loss").ChartObjects(1).Chart

On Error Resume Next
For Each chrtobj In Sheets("Profit & Loss").ChartObjects
    chrtobj.Chart.TextBoxes.Delete
Next chrtobj
On Error GoTo 0

Set txt1 = cht1.Shapes.AddTextbox(msoTextOrientationHorizontal, 790, 30, 190, 30)
txt1.Line.Visible = msoFalse
txt1.TextFrame.Characters.Text = "Total Rev: $" & Format(Cells(n, "B").Value, "#,###")
txt1.Select
With Selection.Characters(Start:=1, Length:=216).Font
    .Size = 18
    .ColorIndex = xlAutomatic
    .Strikethrough = False
    .Superscript = False
    .Subscript = False
    .OutlineFont = False
    .Shadow = False
    .Bold = True
    .Italic = True
End With
txt1.TextFrame2.TextRange.Font.Fill.ForeColor.RGB = RGB(84, 130, 53)
End Sub

Answer 1

这行得通。
我已经从代码中删除了False和xlAutomatic值，因为它们是默认值 - 无需专门设置它们。 当您使用更改ForeColor时，还会设置字体颜色 -

还用7替换了n ，因为n没有在Format(Cells(n, "B").Value中定义

Sub UpdateChart()
    Dim chrtobj As ChartObject
    Dim txt1 As Shape
    Dim cht1 As Chart
    Dim wkbk As Workbook
    
    Set wkbk = ActiveWorkbook
    Set cht1 = Sheets("Profit & Loss").ChartObjects(1).Chart
    
    On Error Resume Next
    For Each chrtobj In Sheets("Profit & Loss").ChartObjects
        chrtobj.Chart.TextBoxes.Delete
    Next chrtobj
    On Error GoTo 0
    
    Set txt1 = cht1.Shapes.AddTextbox(msoTextOrientationHorizontal, 790, 30, 190, 30)
    txt1.Line.Visible = msoFalse
    txt1.TextFrame.Characters.Text = "Total Rev: $" & Format(Cells(7, "B").Value, "#,###")
    'txt1.Select
        With txt1.TextFrame2.TextRange.Characters.Font
            .Size = 18
            .Bold = True
            .Italic = True
            .Fill.ForeColor.RGB = RGB(84, 130, 53)
        End With
    'txt1.TextFrame2.TextRange.Font.Fill.ForeColor.RGB = RGB(84, 130, 53)
End Sub