导出到 CSV 文件时缺少最后几列名称

Question

我正在尝试导出我的图书馆/作品中的数据集。 它在 SAS 中显示正常。但是，当我将数据导出为 CSV 或 txt 文件时（通过右键单击 -> 导出，或使用 SAS 代码），最后几个列名丢失（在 CSV 中显示为空），而值是保存。 缺少的列名都是“Log_xxx”格式，但一些相同格式的列已正确导出。 我的数据集中大约有 4000 多列。

我试过的代码是这样的：

proc export data=logdata
    outfile="path.csv"
    dbms=csv
    replace;
run;

我以前导出过很多数据集，但我还是第一次遇到这种问题。 我试过重启 SAS 还是不行。

我只是想完全导出包含所有列名和值的整个数据集。

你有什么想法？

Answer 1

我不认为问题出在 PROC EXPORT 上。 您必须告诉 SAS 您想要写入超过 32,767 字节的行（LRECL 选项的默认设置）。

此代码有效：

data test;
 array longname [3500] ;
run;

filename csv temp lrecl=1000000 ;
proc export data=test dbms=csv file=csv ; 
run;

因此，请更改您的代码，为所有变量名称设置足够长的 LRECL。

filename csv "path.csv" lrecl=1000000 ;
proc export data=logdata
    outfile=csv
    dbms=csv
    replace
;
run;

Answer 2

根据这篇文章，您的 header 可能超过 32k 个字符，这导致了问题。

解决方案是在没有 proc 导出的情况下手动创建文件，或者 proc 导出到 XLSX 似乎没有问题。

*Create demo data;
data class;
    set sashelp.class;
    label age='Age, Years' weight = 'Weight(lbs)' height='Height, inches';
run;

proc sql noprint;
create table temp as
select name as _name_, label as _label_
from dictionary.columns
where libname="WORK" and upcase(memname)="CLASS";
select nliteral(name) into :varList separated by ' '
from dictionary.columns
where libname="WORK" and upcase(memname)="CLASS";
quit;

data _null_;
file "&sasforum.\datasets\TwoLinesHeader.csv" dsd lrecl = 40000;
set class;
if _n_ = 1 then do;
do until(eof);
    set temp end=eof;
    put _name_ @;
    end;
put;
end;
put (&varList) (:);
run;