使用 Regex 公式（和内部数组）使其同时检查三个单元格上的模式（使用 OR）

Question

我在单元格 (K3) =RegexMatch(C3,"\b[Mm]od(?.erate).*\b[hH]\b")上使用了这个表达式。
然后在数组中使用它分别用列 (C) 的值评估目标范围。
我需要调整下面的代码和公式，使其同时检查三个单元格（使用 OR）。
我的意思是检查单元格上的模式，例如("C3" or "F3" or "G3" ) 如果在任何一个引用的单元格中匹配，则公式的结果为真，反之亦然。
我尝试=RegexMatch((C3,F3,G3),"\b[Mm]od(?.erate).*\b[hH]\b")但它对单元格 (F3,G3) 没有影响。

Sub Regex_with_three_cells()

    Dim ws As Worksheet, lr As Long, x As Long, r_in As Variant, r_out()
    
     Set ws = ActiveSheet
     lr = ws.Cells(ws.Rows.Count, 1).End(xlUp).Row
     r_in = ws.Range("C3:C" & lr).Value
     
     ReDim r_out(1 To UBound(r_in), 1 To 1)
    
    For x = LBound(r_in) To UBound(r_in)
        r_out(x, 1) = RegexMatch(r_in(x, 1), "\b[Mm]od(?!erate).*\b[hH]\b")
    Next
    
    ws.Range("K3:K" & lr).Value = Application.Index(r_out, 0, 1)

End Sub

Public Function RegexMatch(str, pat) As Boolean
    Static RE As Object
     If RE Is Nothing Then Set RE = CreateObject("vbscript.regexp")
      RE.Pattern = pat
       RegexMatch = RE.Test(str)
End Function

Answer 1

请尝试下一个适应的解决方案：

Sub Regex_with_three_cells()

    Dim ws As Worksheet, lr As Long, x As Long, r_in As Variant, r_out()
    
     Set ws = ActiveSheet
     lr = ws.cells(ws.rows.count, 1).End(xlUp).Row
     r_in = ws.Range("C3:G" & lr).Value2
     
     ReDim r_out(1 To UBound(r_in), 1 To 1)
    
    For x = LBound(r_in) To UBound(r_in)
        If RegexMatch(r_in(x, 1)) Or RegexMatch(r_in(x, 4)) _
                                   Or RegexMatch(r_in(x, 5)) Then
            r_out(x, 1) = True
        End If
    Next
    
    ws.Range("K3:K" & lr).Value2 = r_out

End Sub

Public Function RegexMatch(str) As Boolean
    Static RE As Object
     If RE Is Nothing Then Set RE = CreateObject("vbscript.regexp")
      RE.Pattern = "\b[Mm]od(?!erate).*\b[hH]\b" 'place the pattern here to make 
                                                 'the call more compact
       RegexMatch = RE.Test(str)
End Function

如果您还需要在不匹配的情况下编写False ，则可以使用Else: r_out(x, 1) = False ...

编辑：

要使用能够处理三列（当然，在同一行）的值的公式，您应该使用上面的 function和下一个公式：

=IF(OR(RegexMatch(C31),RegexMatch(F3),RegexMatch(G3)),TRUE,FALSE)

每个RegMatch function 将被评估为 Boolean return 并且IF将相应返回......

也可以使 function 能够接受多个单元格（范围）并处理它们中的每一个，返回True并在单元格处理返回时退出RE.Test(CStr(cell.value))) = True ...它的作为 UDF 的调用可以转换为：

  =RegexMatch(C3,F3,G3)