我能做些什么来减少这个程序的运行时间吗？

Question

uses sysutils;
var
stringlength,querynum,i,start,tail,j,cnt:int64;
input,temp:ansistring;
querychar:char;
begin
readln(stringlength,querynum);
readln(input);
for i:=1 to querynum do begin
   readln(querychar,start,tail);
   temp:=copy(input,start,tail-start+1);
   writeln(temp.CountChar(querychar));
end;
end.

这是一个程序，用于查找某个字符在字符串的特定段中出现了多少次。 输入格式是第一行输入字符串的长度和查询次数（n），然后接下来的n行输入要搜索的字符，以及字符串的部分（例如从3到8）。 有时程序的运行时间非常高，我认为这是由于 for 循环。 有什么办法可以减少运行时间吗？

Answer 1

速度通常以 memory 为代价。 如果您想提高速度，可以将数据转换为比输入处理速度更快的表单/布局。 特别是套装适合实现您的目标。

现在，这是一个实现细节。 Pascal——编程语言——没有规定任何 memory 布局。 理论上，您的处理器在使用一组时可能会产生更糟糕的结果，这可能不太可能。 因此，我通常建议使用最易于维护的算法。 您的算法已经很好地满足了这个标准。

program characterSubstringOccurrences(input, output);
    type
        { `integer`-prefix to facilitate sorting in documentation tools. }
        integerNonNegative = 0..maxInt;
    
    {
        Performs specified number of character queries on sample.
        
        \param sample the sample to inspect for a certain character
        \param queryCount the total number of queries to prompt
    }
    procedure processQueries(
            protected sample: string;
            queryCount: integerNonNegative
        );
        type
            sampleIndex = 1..sample.capacity;
            sampleIndices = set of sampleIndex;
        var
            c: char;
            i, j: sampleIndex;
            characterIndex: array[char] of sampleIndices value [otherwise []];

这是一个子例程，因为它简化了具有非常量边界（这里是给定sample的容量）的集合的创建。 我们只需要相应地声明我们的数据类型； 没有必要调用new的。

        begin
            { --- analyze `sample` step --- }
            for i := 1 to length(sample) do
            begin
                characterIndex[sample[i]] := characterIndex[sample[i]] + [i];
            end;
            
            { --- draw conclusions from analysis step --- }
            for queryCount := 1 to queryCount do
            begin
                readLn(c, i, j);
                writeLn(card(characterIndex[c] * [i..j]));
            end;
        end;

显然，这避免了一遍又一遍地重新检查样本。 您需要做的就是获取 [start, tail] 与指定字符出现的索引集的交集的基数。

    { === MAIN ================================================== }
    var
        sample: ^string;
        sampleLength: integerNonNegative;
        queryCount: integerNonNegative;
    begin
        if EOF then
        begin
            writeLn('Error: Program needs input.');
            halt;
        end;
        
        read(sampleLength);
        if sampleLength = 0 then
        begin
            writeLn('Error: Sample length must be positive.');
            halt;
        end;
        
        new(sample, sampleLength);
        
        readLn(queryCount);
        readLn(sample^);
        
        if queryCount > 0 then
        begin
            processQueries(sample^, queryCount);
        end;
    end.

现在这是一个符合 ISO 标准 10206“Extended Pascal”的program 。 从您的代码的非标准偏差中，我了解到您使用的是某种方言，但是将数据提取/转换为处理速度更快的形式的一般想法仍然存在。