可搜索 combobox 不适用于集合

Question

我有一个下拉列表，之前使用以下代码使用我工作簿中第二张表中的值填充该下拉列表：

Private Sub UserForm_Initialize()

Dim cProd As Range
Dim ws As Worksheet
Dim i As Long

Set ws = ThisWorkbook.Worksheets("DO NOT DELETE")

For Each cProd In ws.Range("ProdList")
    With Me.dropProd
        .AddItem cProd.Value
    End With
Next cProd

Me.dropProd.SetFocus

End Sub

然后，我添加了我在此处找到的代码以向其添加可搜索功能，并且它工作得很好。

然后我不得不调整我的代码以添加第二个下拉菜单，该下拉菜单依赖于我之前拥有的第一个下拉菜单。 为此，我删除了 DO NOT DELETE 工作表，并创建了两个 collections 来存储下拉列表的值。

现在，我的第一个下拉列表正在填充此代码：

Sub UpdateAll()

Dim ProdID As String
Dim Prod As String
Dim TF As Boolean
Dim lRow As Long
Dim i, t, s
    
dropProd.Clear
dropPromo.Clear
   
Set ws = ThisWorkbook.Worksheets("Table View")
   
Set cProd = New Collection
    
lRow = ws.Cells(Rows.Count, 1).End(-4162).Row
    
For i = 13 To lRow
    
    ProdID = ws.Cells(i, 2).Value
    Prod = ws.Cells(i, 3).Value

    If ProdID <> "" Then
            
        TF = False
        If cProd.Count <> 0 Then
            For t = 1 To cProd.Count
                If cProd(t) = ProdID & " - " & Prod Then TF = True
            Next
        End If

        If TF = False Then cProd.Add (ProdID & " - " & Prod)
    End If
    Next

For s = 1 To cProd.Count
        dropProd.AddItem (cProd(s))
Next

End Sub

Private Sub UserForm_Initialize()

    Me.dropProd.SetFocus
    UpdateAll 

End Sub

这部分也做得很好，下面是我遇到问题的地方：

Private Sub dropProd_Change()

    Dim ProdInfo As String
    Dim Promo As String
    Dim q, p

    dropPromo.Clear

    lRow = ws.Cells(Rows.Count, 1).End(-4162).Row
    
    If dropProd.Value <> "" Then
        ProdInfo = Mid(dropProd.Value, 1, InStr(1, dropProd.Value, " - ") - 1)
    End If

    'Populates Promo ComboBox
    For q = 13 To lRow

        Promo = ws.Cells(q, 9).Value
        
        If ws.Cells(q, 2).Value = ProdInfo Then dropPromo.AddItem Promo

    Next

End Sub

如果我只是 select 来自下拉列表的值，上面的工作正常，但每次我尝试搜索任何东西时它都会中断，问题出在这一行ProdInfo = Mid(dropProd.Value, 1, InStr(1, dropProd.Value, " - ") - 1)

我试图用另一种方式重写它，但它仍然给我一个错误。 此外，我尝试合并上面链接中的代码以查看它是否有效，但后来我不知道在me.dropProd.List =????上引用什么？ . 我试过让这个等于我拥有的收藏，当然它没有用，现在我被困在如何修复它上。

Answer 1

我无法用您的代码行ProdInfo = Mid(dropProd.Value, 1, InStr(1, dropProd.Value, " - ") - 1)重现问题，它可能与数据相关。 试试这个替代方案ProdInfo = Trim(Split(dropProd.Value, "-")(0))和字典而不是集合。

Option Explicit
Dim ws

Sub UpdateAll()

    Dim ProdID As String, Prod As String
    Dim lastrow As Long, i As Long
      
    dropProd.Clear
    dropPromo.Clear
    
    Dim dictProd As Object, k As String
    Set dictProd = CreateObject("Scripting.DIctionary")
       
    Set ws = ThisWorkbook.Worksheets("Table View")
    With ws
        lastrow = ws.Cells(.Rows.Count, 1).End(xlUp).Row
        For i = 13 To lastrow
            ProdID = Trim(.Cells(i, 2))
            If Len(ProdID) > 0 Then
                Prod = Trim(.Cells(i, 3))
                k = ProdID & " - " & Prod
                If Not dictProd.exists(k) Then
                    dictProd.Add k, 1
                End If
            End If
        Next
        dropProd.List = dictProd.keys
    End With

End Sub

Private Sub dropProd_Change()

    Dim ProdInfo As String, Promo As String
    Dim lastrow As Long, i As Long
    
    dropPromo.Clear
    
    If dropProd.Value <> "" Then
        ProdInfo = Trim(Split(dropProd.Value, "-")(0))
    
        'Populates Promo ComboBox
        With ws
            lastrow = ws.Cells(.Rows.Count, 1).End(xlUp).Row
            For i = 13 To lastrow
                If .Cells(i, 2).Value = ProdInfo Then
                    Promo = ws.Cells(i, 9).Value
                    dropPromo.AddItem Promo
                End If
            Next
        End With
    End If
End Sub

Private Sub UserForm_Initialize()
    Me.dropProd.SetFocus
    UpdateAll
End Sub