从工作表范围中提取日期

Question

我正在处理月度报告宏，这需要我从一个范围中提取天数和月数并获得最大天数（例如 1、5、7、9）以继续下一步。 我的代码似乎不是理想的解决方案。

举例来说，我正在从范围 A1:A4 中提取日期，尽管在编写实际代码时它将是从 A1 到最后一行。 所以范围 A1 到 A4 的值如下

A1= 12/10/2022 A2= 14/6/2020 A3=3/3/2020 A4= 1/4/2021

请注意，日期约定在 Excel 范围内采用英国约定 (dd/mm/yyyy)。 同样，我也需要提取月份，但如果我可以获得几天的代码，那么获取月份也不成问题。*

Sub TestR1()
    Dim MonthArray(1 To 4) As Variant
    Dim x As Double
    Dim i As Byte
    Dim Rng As Range
    Dim ExDate As Date
    Dim Mx As Long
   
    Set Rng = Range("A1:A4")
             
         
    For i = 1 To 4
    Set Rng = Range("A" & i)
    ExDate = VBA.CDate(Range("A" & i).Value)
    x = VBA.Day(ExDate)
           
    MonthArray(i) = x
    Next i
   
    Mx = Excel.WorksheetFunction.Max(MonthArray)
   
    End Sub

Answer 1

这段代码和你的解释很混乱。 我认为您正在尝试为每一行获取一系列月份和日期，但您的代码是：

1. 从单个单元格中读取日期，而不是一行中的四个。
2. 提取该日期的日期部分，以及；
3. 将那一天的值插入一个名为 MonthArray 的数组。

如果我对你的理解正确，我会做这样的事情：

Sub ParseDates(src As Range)
    Dim dates() As Variant
    dates = src.Value

    Dim rCount As Long
    rCount = src.Rows.Count

    Dim cCount As Long
    cCount = src.Columns.Count

    Dim days() As Variant
    Dim months() As Variant
    Dim dt As Date

    Dim r As Long, c As Long
    For r = 1 To rCount
        For c = 1 To cCount
            dt = CDate(dates(r, c))
            days(r, c) = Day(dt)
            months(r, c) = Month(dt)
        Next c
    Next r

    ... ' Whatever you want to do with your values.
End Sub

Answer 2

提取日期和月份

Option Explicit

Sub TestR1()
    
    Dim wb As Workbook: Set wb = ThisWorkbook ' workbook containing this code
    
    Dim ws As Worksheet: Set ws = wb.Sheets("Sheet1")
    
    Dim rg As Range
    Set rg = ws.Range("A2", ws.Cells(ws.Rows.Count, "A").End(xlUp))
    Dim rCount As Long: rCount = rg.Rows.Count
    
    Dim Data()
    If rCount = 1 Then
        ReDim Data(1 To 1, 1 To 1): Data(1, 1) = rg.Value
    Else
        Data = rg.Value
    End If
    
    Dim Months() As Long: ReDim Months(1 To rCount)
    Dim Days() As Long: ReDim Days(1 To rCount)
    
    Dim r As Long
    
    For r = 1 To rCount
        Days(r) = Day(Data(r, 1))
        Months(r) = Month(Data(r, 1))
    Next r
    
    Debug.Print "Index", "Day", "Month"
    
    For r = 1 To rCount
        Debug.Print r, Days(r), Months(r)
    Next r
    
    Debug.Print "Max Day", "Max Month"
    Debug.Print Application.Max(Days), Application.Max(Months)

End Sub

即时结果 Window ( Ctrl+G )

Index         Day           Month
 1             20            4 
 2             16            2 
 3             27            2 
 4             15            3 
 5             26            1 
 6             4             12 
 7             3             2 
 8             26            1 
 9             20            4 
Max Day       Max Month
 27            12