Visual basic 2019 中两个图片框之间的碰撞

Question

我正在尝试创建一个简单的游戏，其中我的角色处理迷宫，在 Visual Basic 2019 中，我无法阻止我的角色（图片框）穿过墙壁（图片框）。 不得不说，我离专家还差得很远，只是学校的一个重要项目。

我试过这个

Dim colliding As Boolean = False
For Each PictureBox In Me.Controls
    If PictureBox1.Bounds.IntersectsWith(PictureBox.Bounds) Then
        colliding = True
    Else
        colliding = False
    End If
Next

和这个

Dim colliding As Boolean = False
For Each PictureBox In Me.Controls 
    If PictureBox IsNot PictureBox1 AndAlso PictureBox21.Bounds.IntersectsWith(PictureBox.Bounds) Then
        colliding = True
    Else
        colliding = False
    End If 
Next

在两次参加中我都失败了，我的角色（picturebox1）仍然可以穿墙

Answer 1

代码假定所有 PictureBoxes 都直接包含在 Form 本身中（它们不在另一个容器内，如 Panel），并且除了 PictureBox1 之外的任何东西都是一堵墙：

Dim colliding As Boolean = False
For Each PB As PictureBox In Me.Controls.OfType(Of PictureBox)
    If PB IsNot PictureBox1 Then
        If PB.Bounds.IntersectsWith(PictureBox1.Bounds) Then
            colliding = True
            Exit For
        End If
    End If
Next

使用 LINQ 位的替代方法：

Public Class Form1

    Private Walls As New List(Of PictureBox)

    Private Sub Form1_Load(sender As Object, e As EventArgs) Handles MyBase.Load
        Walls = Me.Controls.OfType(Of PictureBox).Where(Function(pb) pb IsNot PictureBox1).ToList
    End Sub

    Private Sub Button1_Click(sender As Object, e As EventArgs) Handles Button1.Click
        Dim colliding As Boolean = Walls.Any(Function(pb) pb.Bounds.IntersectsWith(PictureBox1.Bounds))
    End Sub


End Class

Answer 2

这是处理碰撞的另一种选择。 这假设有 4 个按钮来移动“角色”

   Private Enum MoveDirection
        Left
        Down
        Right
        Up
    End Enum

    Private Sub RightButton_Click(sender As Object, e As EventArgs) Handles RightButton.Click
        MovePicBox(CharacterPicBox, MoveDirection.Right)
    End Sub

    Private Sub LeftButton_Click(sender As Object, e As EventArgs) Handles LeftButton.Click
        MovePicBox(CharacterPicBox, MoveDirection.Left)
    End Sub

    Private Sub UpButton_Click(sender As Object, e As EventArgs) Handles UpButton.Click
        MovePicBox(CharacterPicBox, MoveDirection.Up)
    End Sub

    Private Sub DownButton_Click(sender As Object, e As EventArgs) Handles DownButton.Click
        MovePicBox(CharacterPicBox, MoveDirection.Down)
    End Sub

    Private Sub MovePicBox(PicBox As PictureBox, movement As MoveDirection)

        'save the old location to move the pic box back if a clash occurs
        Dim oldLocation As Point = PicBox.Location
        Dim newLocation As Point
        Dim stepSize As Integer = 50

        'calculate new position
        Select Case movement
            Case MoveDirection.Down
                newLocation.X = oldLocation.X
                newLocation.Y = oldLocation.Y + stepSize
            Case MoveDirection.Left
                newLocation.X = oldLocation.X - stepSize
                newLocation.Y = oldLocation.Y
            Case MoveDirection.Up
                newLocation.X = oldLocation.X
                newLocation.Y = oldLocation.Y - stepSize
            Case MoveDirection.Right
                newLocation.X = oldLocation.X + stepSize
                newLocation.Y = oldLocation.Y
        End Select

        'move the picture box
        PicBox.Location = newLocation

        'check if it has collided
        For Each wallPicBox As PictureBox In Me.Controls.OfType(Of PictureBox)
            If wallPicBox Is PicBox Then
                Continue For
            End If
            If PicBox.Bounds.IntersectsWith(wallPicBox.Bounds) Then
                'move it back
                PicBox.Location = oldLocation
            End If
        Next

    End Sub