我需要找到文件夹中最后保存的文件并将其移动（或复制）到另一个文件夹，使用 VBA。有人可以帮我解决这个问题吗？

Question

我需要查看特定文件夹并找到最后保存的文件并使用 VBA 移动（或复制）到其他文件夹。

通过查找我正在使用的文件：

私有 Function fFindLastFile()

'Call GetFolder

Dim fso As Object
Set fso = CreateObject("Scripting.FileSystemObject")
Dim myFolder As Object
Set myFolder = fso.GetFolder("D:\SF\C0T460A220000042\")
'Set myFolder = fso.GetFolder(GetFolder)
Dim myFile As Object
Set myFile = myFolder.Files.Item(myFolder.Files.Count)      '<----- this is where i get a debug nr 5, unknown procedure or argument
MsgBox myFile.Name & " was last modified on " & myFile.DateLastModified

结束 Function

我不知道要查找的文件的名称或类型，但我只是从已知的 URL 下载了它。
你知道我做错了什么吗？

Answer 1

最后修改的文件 ( FileSystemObject )

Option Explicit

Private Sub CopyLastFile()

    Const sFolderPath As String = "D:\SF\C0T460A220000042\"
    Const dFolderPath As String = "C:\Test\" ' adjust!

    Dim fso As Object: Set fso = CreateObject("Scripting.FileSystemObject")
    Dim fsoFolder As Object: Set fsoFolder = fso.GetFolder(sFolderPath)

    Dim fsoFile As Object, fName As String, fDate As Date
    
    For Each fsoFile In fsoFolder.Files
        If fsoFile.DateLastModified > fDate Then
            fName = fsoFile.Name
            fDate = fsoFile.DateLastModified
        End If
    Next fsoFile

    If Len(fName) > 0 Then
        fso.CopyFile sFolderPath & fName, dFolderPath, True
        'fso.MoveFile sFolderPath & fName, dFolderPath, True
        MsgBox "File Name: " & fName & vbLf & "Last modified: " & fDate, _
            vbInformation, "Last Modified File"
    Else
        MsgBox "No file found.", vbExclamation, "Last Modified File"
    End If

End Sub