用两列相除的平均和填充一列的空值 SAS

Question

我需要用两列相除的平均总和来填充一列的空值一个例子是

A B C ... B_01 C_01
5 . .
5 2 3
7 3 1,2
9 3 0,3
4 . .

好吧，我希望 B 列的缺失值为 (2/5 + 3/7 + 3/9) / 3 * 其对应的 A 列 For column new_c (3/5 + 1,2/7 + 0,3 /9)/3 * 其对应的A列

我考虑过这样做，但事实证明我有 60 根柱子可以用来做这件事，我想到的唯一方法就是这样做 60 次。

Proc sql;
  create table new as
  Select *
  , sum(B/A)/sum(case when B is missimg then . else 1) end as new_B
  , sum(C/A)/sum(case when C is missimg then . else 1) end as new_C_01
  from table_one
  ;

谢谢

Answer 1

PROC SQL 应该能够轻松做到这一点。

首先让我们将您的数据列表转换为实际数据集。

data have;
  input A B C ;
cards;
5 . .
5 2 3
7 3 1.2
9 3 0.3
4 . .
;

现在让我们用它来创建一个遵循您的规则的新版本 B。

proc sql;
create table want as 
  select *,coalesce(b,a*mean(b/a)) as new_b
  from have
;
quit;

结果：

OBS    A    B     C      new_b

 1     5    .     .     1.93651
 2     5    2    3.0    2.00000
 3     7    3    1.2    3.00000
 4     9    3    0.3    3.00000
 5     4    .     .     1.54921

Answer 2

您可以使用 Proc MEANS 计算 60 列中每一列的平均分数，并在 DATA 步中应用插补规则。

例子：

data have;
  call streaminit(20230129);
  do row = 1 to 100;
    a = rand('integer', 30);
    array x x1-x60;
    do over x;
      x = ifn(rand('uniform') > 0.30, rand('integer', a-1), .);
    end;
    output;
  end;
run;

data fractions;
  set have;
  array f x1-x60;
  do over f;
    if not missing(f) then f = f / a;
  end;
  rename x1-x60 = f1-f60;
run;

proc means noprint data=fractions;
  output out=means mean(f1-f60)=mean1-mean60;
  var f1-f60;
run;

data want;
  set have;

  one = 1;
  set means point=one;

  array means mean1-mean60;
  array x x1-x60;

  do over x;
    if missing (x) then means = means * a; else means = x;
  end;

  rename mean1-mean60=new_x1-new_x60;
run;