gnuplot: plot 输入数据通过pipe得到

Question

这是一个有点奇怪的查询，可能比简单的求助更能证明我对 bash 的无知。 再一次，有人可能会给出完美的答案——这会让我省去很多头疼的事情。

我想创建一个简单的 gnuplot 命令来生成 plot，重复不同的数据。 虽然目前我可能不得不将数据保存到 /dev/shm 中的临时文件中，但我真的不想这样做。 这感觉像是不必要的复杂性，当我本能地做的是通过 pipe 传递数据时。然而，就在我认为我怀疑它时（感谢theozh ），实验证明我错了。

我从文件 stack.gp 开始，如下所示：

### bar chart with conditional color
data = '/dev/stdin'
lhb = ARG1
myColor(col) = (_s=strcol(col), _s eq lhb ? 0xff3333 : 0x3333ff)

set style fill solid 0.5
set key noautotitle

stats data using 0:2 nooutput
set label 1 at STATS_max_x, STATS_mean_y sprintf("mean=%.1f",STATS_mean_y) offset 0,0.7 right

plot data using 0:2:(myColor(1)):xtic(1) w boxes lc rgb var, \
     STATS_mean_y w l lw 2 lc "web-green"

据我了解，这里重要的是：

1. 第一行，存储传入的数据； 和
2. 事实上，这些数据被处理了不止一次（因为我可以轻松地做我想做的事，只要我没有 stats 命令）。

数据是一个非常简单的两列表：

A 8
B 6
C 4
D 3

我可以使用以下命令生成我的 output：

< test.dat gnuplot --persist -c stack.gp 'C' 

完美，但事实并非如此。 因为这使用了一个临时文件 (test.dat)。 我实际上打算做的是pipe中的数据，类似这种做法：

cat otherfile.txt | awk ... | gnuplot -c stack.gp 'C'

这不适用于原始脚本（没有有效的数据点），但如果我删除我的统计命令以便数据只处理一次，它就会起作用。 因此，让我们尝试其他几种方法：

1. 数据 = '<猫'
2. 数据='-'

(1) 再次适用于单次通过，但否则会给出“x 范围无效” (2) 根据 1 次或 2 次通过处理给出“x 范围无效”或“在文件中找不到有效数据点” 。 啊！

那么，还有另一种方法吗？ 曾经可能是我首先开始使用 gnuplot 的原因，它是 perl 帮助程序脚本feedgnuplot 。 但是，到目前为止，我也没有设法使它正常工作。

帖子https://unix.stackexchange.com/questions/671446进行了更详细的介绍。 类似的讨论：如何从 gnuplot 中的相同标准输入数据制作多个图？

顽固，逻辑表明这是可能的，因为我可以创建随机测试数据（使用set table $Data ）然后分析它。 如果我能做到这一点，那么我肯定可以用管道数据的内容填充 $Data 吗？ 使用标准输入时我显然没有正确填充它......

有解决办法吗？ 或者这对于当前版本的 gnuplot 来说是不可能的吗？

Answer 1

我可以想到至少两种方法。 可能还有其他人。

方法一：

您可以将管道数据包装在开始和结束行中，以告诉 gnuplot 将其存储为此处文档以供以后使用。 gnuplot 想要看到的是：

$DATA << EOD
 ... data ...
 ... data ...
 ...
EOD

包装（附加的第一行和最后一行）可以由生成数据的程序完成，也可以通过管道通过 awk 或其他一些命令行位来添加。 这是一个模型：

cat part2.gp
   print $DATA
   stats $DATA
   plot $DATA

echo '$DATA << EOD\n 2 1 \n 3 0 \n 4 4 \nEOD' | gnuplot '-' part2.gp

方法二：

您可以告诉 gnuplot 从其他 fd 读取，而不是通过 stdin 进行管道传输。 这是手册中的相关文本（“帮助管道数据”）：

 On systems with an fdopen() function, data can be read from an arbitrary file
 descriptor attached to either a file or pipe.  To read from file descriptor
 `n` use `'<&n'`.  This allows you to easily pipe in several data files in a
 single call from a POSIX shell:

       $ gnuplot -p -e "plot '<&3', '<&4'" 3<data-3 4<data-4
       $ ./gnuplot 5< <(myprogram -with -options)
       gnuplot> plot '<&5'

Answer 2

这是对数据进行单次传递的建议。 您可以计算第一个 plot 命令期间的平均值和 plot 第二个和第三个 plot 命令中的平均值， with lines和with labels 。 通过单次传递，您应该能够让它与 pipe 一起运行，您只有一次数据，并且您可以从参数ARG1获取变量lhb 。

脚本：

### bar chart with mean value in a single pass
reset session

$Data <<EOD
A 8
B 6
C 4
D 3
EOD

# lhb = ARG1
lhb = "C"
myColor(col) = (strcol(col) eq lhb ? 0xff3333 : 0x3333ff)

set style fill solid 0.5
set key noautotitle
set yrange[0:]
set offsets 0.75,0.75,1,0

plot c=s=0 $Data u (c=c+1):(s=s+$2,$2):(myColor(1)):xtic(1) w boxes lc rgb var, \
     '+' u 1:(s/c) w l lw 2 lc "web-green", \
     '+' u (c):(s/c):(sprintf("mean=%.2f",s/c)) every ::::0 w labels offset 0,0.5 right
### end of script

结果：