使用Perl hash表删除字符串中的元音，但output始终为空

Question

我试图通过用户提供的字符串数组在 Perl 到 go 中编写一个简短的脚本，检查 hash 表以查看字符串中是否有元音，然后返回减去元音的字符串。 我知道使用正则表达式会更容易完成，但是必须使用 hash 表、 exists()和split()问题 state 的参数。 这是我到目前为止的脚本：

my @vowels = qw(a e i o u A E I O U);
my %vowel;
foreach $v (@vowels) {
   $vowel{$v} = undef;
}
foreach $word (@ARGV) {
   my @letter_array = split(undef,$word);
}
foreach $letter (@letter_array) {
   print($letter) if !exists($vowel{$letter})
}
print "\n"

输入：你好

预计 output：hll

实际 output：无

没有错误消息，所以我知道这不是语法错误。 知道我在搞砸什么吗？ 我对 Python 更舒服，这是我第一次尝试 Perl。

Answer 1

您应该use strict not 来破坏变量的可见性。 如果您需要 perl 版本5.12或更高版本，它将自动使用。

所以你的列表@letter_array只存在于foreach my $word (@ARGV)循环中。 这就是为什么它最后是空的。

如果你想解决这个问题，你会得到以下代码：

#!/usr/bin/env perl

use strict;
use warnings;

my @vowels = qw( a e i o u y A E I O U Y );
my %vowel;

foreach my $v (@vowels) {
   $vowel{$v} = undef;
}

my @letter_array;
foreach my $word (@ARGV) {
    @letter_array = split //, $word;
}

foreach my $letter (@letter_array) {
    print($letter) if !exists($vowel{$letter})
}

print "\n"

但是这段代码仍然不实用。

1. 如果您在输入中获得超过 1 个单词，您将只显示最后一个单词，因为 @ letter_array 每次都会覆盖。
2. 您可以使用map更轻松地获得 hash 的元音，而无需使用额外的变量。
3. 如果您在阅读每个单词后立即处理它，则可以使用更少的循环。
4. 你也可以使用unless如果你想检查if not使它更漂亮和更 perl 风格。
5. 不要在 undef 上使用 split。 最好使用split //, $word
6. 您可以使用for而不是foreach因为它相同但更短:)

所以你可以获得优化的解决方案。

#!/usr/bin/env perl

use 5.012;
use warnings;


my %vowels = map { $_ => undef } qw( a e i o u y A E I O U Y );

for my $word (@ARGV) {
    my @letters = split //, $word;
    for my $letter (@letters) {
        print $letter unless exists $vowels{$letter};
    }
    print ' ';
}
print "\n"

结果：

$ perl delete_vowels.pl hello world
hll wrld

Answer 2

实现相同目的的另一种更紧凑的方法是使用替换运算符“ s ”和匹配元音的正则表达式。

这是一个例子

use strict;
use warnings;

for my $word (@ARGV)
{
    print $word =~ s/[aeiou]//gri;
}

或更简洁地像这样

use strict;
use warnings;

for (@ARGV)
{
    print s/[aeiou]//gri;
}

注意事项

1. 正则表达式使用字符 Class [aeiou]来匹配单个小写元音。
2. 替代操作员已获得三个选项
   • i选项强制进行不区分大小写的匹配。 这意味着字符 Class [aeiou]将匹配大写和小写元音。
   • g选项使替换匹配正则表达式的所有实例——在这种情况下它将匹配字符串中的所有元音。
   • r选项（这是对 Perl 的新增功能）让替换运算符返回替换后的字符串。

运行这给了这个

$ perl try.pl hello world
hllwrld