xpath谓词限制xml节点显示

Question

回到那个相当古老的（现在）问题，关于在某个时候限制 xml 个节点显示。 xml文件是这样的：

<persns>
<prsn> 
  <fname>Smith</fname> 
  <lname>Milton</lname> 
  <age>44</age> 
  <addrss>5th summer st, mntb</addrss>
  <city>Portland</city>
 </prsn>
 <prsn> 
  <fname>Ken</fname> 
  <lname>Jackson</lname> 
  <age>37</age> 
  <addrss>19th Penfield ave, brtcl</addrss>
  <city>Kelowna</city>
 </prsn>
 <prsn> 
  <fname>Susan</fname> 
  <lname>Arkland</lname> 
  <age>48</age> 
  <addrss>34th Mansfield st, sgtp</addrss>
  <city>Raleigh</city>
 </prsn>
 <prsn> 
  <fname>George</fname> 
  <lname>Bond</lname> 
  <age>35</age> 
  <addrss>5th drive, mntb</addrss>
  <city>Albany</city>
 </prsn>
 <prsn> 
  <fname>Ron</fname> 
  <lname>Davis</lname> 
  <age>37</age> 
  <addrss>12th Greenfield ave, brtcl</addrss>
  <city>Pheonix</city>
 </prsn>
</persns>

通过一些 xslt 转换，我想这样显示：

<table border="1">
<tr><th>fname</th><td>Smith</td><td>Ken</td><td>Susan</td></tr>
<tr><th>lname</th><td>Milton</td><td>Jackson</td><td>Arkland</td></tr>
<tr><th>age</th><td>44</td><td>37</td><td>48</td></tr>
<tr><th>addrss</th><td>5th summer st, mntb</td><td>19th Penfield ave, brtcl</td><td>34th Mansfield st, sgtp</td></tr>
 <tr><th>city</th><td>Portland</td><td>Kelowna</td><td>Raleigh</td></tr>
</table>
       Fig.1 Required Display

我以某种方式设法几乎显示它但不完全......所以我相关的 xsl 样式表如下：

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:xs="http://www.w3.org/2001/XMLSchema" version="2.0">
<xsl:output method="html" indent="yes" html-version="5"/>
<!-- page count starts from 1 -->
<xsl:param name="pag" select="1"/>
<!-- frme=frame - three records per page -->
<xsl:param name="frme" as="xs:integer" select="3"/>

<xsl:template match="persns">
 <xsl:for-each select="prsn[position()&gt;=($pag*$frme)+1 and position()&lt;=($frme + ($pag*$frme))]">
 <xsl:variable name="rec" select="."/>

<table border="1">
<xsl:for-each select="*/name()">
<xsl:variable name="i" select="position()"/>
<tr><th><xsl:value-of select="."/></th>
<xsl:for-each select="$rec">
 <td><xsl:value-of select="*[$i]"/></td>
</xsl:for-each>
</tr>
</xsl:for-each>
</table>
</xsl:template>
</xsl:stylesheet>

所以通过上面的样式表，转换显示了一些东西。 喜欢：

<table border="1">
<tr><th>fname</th><td>Smith</td></tr>
<tr><th>lname</th><td>Milton</td></tr>
<tr><th>age</th><td>44</td></tr>
<tr><th>addrss</th><td>5th summer st, mntb</td></tr>
<tr><th>city</th><td>Portland</td></tr>
<tr><th>fname</th><td>Ken</td></tr>
<tr><th>lname</th><td>Jackson</td></tr>
<tr><th>age</th><td>37</td></tr>
<tr><th>addrss</th><td>19th Penfield ave, brtcl</td></tr>
<tr><th>city</th><td>Kelowna</td></tr>
<tr><th>fname</th><td>Susan</td></tr>
<tr><th>lname</th><td>Arkland</td></tr>
<tr><th>age</th><td>48</td></tr>
<tr><th>addrss</th><td>34th Mansfield st, sgtp</td>
</tr>
<tr><th>city</th><td>Raleigh</td></tr>
</table>
   Fig.2 Actual Displaying
          (not wanted) 

所以请大家帮我显示上面的 xml，如图 1 所示。 我真的很抱歉问了同一个问题三次，但我非常需要这个来按照我的要求工作。 非常感谢提前

Answer 1

这个问题并不完全清楚。 我想你想做这样的事情：

XSLT 2.0

<xsl:stylesheet version="2.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="html"/>

<xsl:param name="pag" select="1"/>
<xsl:param name="frme" select="3"/>

<xsl:template match="/persns">
    <xsl:variable name="start" select="($pag - 1) * $frme + 1" />
    <xsl:variable name="rec" select="prsn[position() ge $start and position() lt $start + $frme]"/>
    <table border="1">
        <xsl:for-each select="$rec[1]/*">
            <xsl:variable name="i" select="position()"/>
            <tr>
                <th>
                    <xsl:value-of select="name()"/>
                </th>   
                <xsl:for-each select="$rec">
                    <td>
                        <xsl:value-of select="*[$i]"/>
                    </td>
                </xsl:for-each>
            </tr>
        </xsl:for-each>
    </table>
</xsl:template>

</xsl:stylesheet>