将最后九行数据定义为范围以复制值并将粘贴转置到另一个工作表中

Question

VBA 定义一个始终为最后九行数据的范围的代码是什么？

我有一个 data.table，每月手动更新 9 个主题。 我想从最近的条目中复制特定的单元格值，并使用这些值填充另一个工作表上的记分卡。

我不知道该怎么做是从最后一行开始定义一个动态范围 9。

我可以使用定义最后一行

Last = Cells(Rows.Count, “B”).End(xlUp).Row

但是我如何定义最后 9 行呢？

Last = Cells(Rows.Count, “B”).End(xlUp).Row

'第一的？？？

For i=Last To ‘first Step -1

'如果是“名称”，则将单元格值复制到记分卡中定义的单元格

Answer 1

Range(Cells(max(1,Last-9),2),Cells(Last,2))

处理少于 9 行数据的情况。

将列设置为您需要最终范围的任何宽度。

Answer 2

转置最后一行

Sub PrintLastRowsAddress()

    Const LAST_ROWS_COUNT As Long = 9
 
    Dim ws As Worksheet: Set ws = ActiveSheet ' improve!
    
    Dim lrg As Range

    With ws.UsedRange
        Set lrg = .Resize(LAST_ROWS_COUNT).Offset(.Rows.Count - LAST_ROWS_COUNT)
    End With
    
    Debug.Print lrg.Address(0, 0)
    
End Sub

Sub TransposeLastRows()

    Const SRC_NAME As String = "Sheet1"
    Const SRC_LAST_ROWS As Long = 9
    Const DST_NAME As String = "Sheet2"
    Const DST_FIRST_CELL As String = "A1"
 
    Dim wb As Workbook: Set wb = ThisWorkbook ' workbook containing this code
    
    Dim sws As Worksheet: Set sws = wb.Sheets(SRC_NAME)
    Dim srg As Range
    With sws.UsedRange
        Set srg = .Resize(SRC_LAST_ROWS).Offset(.Rows.Count - SRC_LAST_ROWS)
    End With
    
    Dim dws As Worksheet: Set dws = wb.Sheets(DST_NAME)
    Dim dfCell As Range: Set dfCell = dws.Range(DST_FIRST_CELL)
    Dim drg As Range: Set drg = dfCell.Resize(srg.Columns.Count, SRC_LAST_ROWS)
    
    drg.Value = Application.Transpose(srg.Value)
    
    MsgBox "Last " & SRC_LAST_ROWS & " rows transposed.", vbInformation
    
End Sub