我如何获得标记化拆分 function 内容顺序而不是 xml 顺序

Question

当我使用 XSLT 2.0 键并标记 function 时，它的退货顺序会根据键值更改。 在我们的 output 中，我们需要保留相同的标记序列顺序。

输入文件

<?xml version="1.0" encoding="UTF-8"?>     <a>     <bd id="a">a</bd>     <bd id="b">b</bd>     <bd id="e">e</bd>     <bd id="d">d</bd>     </a>

XSLT

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="2.0">

     <xsl:key name="idcollect" match="*[@id]" use="@id" />
     <xsl:variable name="name" select="'d,b,e,a'"/>
    
     <xsl:template match="/">
      <xsl:for-each select="key('idcollect',tokenize($name,','))" >
         <xsl:copy-of select="."/>
     </xsl:for-each>
     </xsl:template>
    
</xsl:stylesheet>

当前 Output

<?xml version="1.0" encoding="UTF-8"?><bd id="a">a</bd><bd id="b">b</bd><bd id="e">e</bd><bd id="d">d</bd>

预计 output

<?xml version="1.0" encoding="UTF-8"?><bd id="d">d</bd><bd id="b">b</bd><bd id="e">e</bd><bd id="a">a</bd>

Answer 1

我想你想要例如

  <xsl:variable name="main-doc" select="/"/>
  <xsl:for-each select="for $token in tokenize($name,',') return key('idcollect', $token, $main-doc)">
     <xsl:copy-of select="."/>
 </xsl:for-each>

或在 XSLT 3

  <xsl:variable name="main-doc" select="/"/>
  <xsl:for-each select="tokenize($name,',') ! key('idcollect', ., $main-doc)">
     <xsl:copy-of select="."/>
 </xsl:for-each>

当然，在这两种情况下，都不需要 for-each/copy-of 嵌套，例如

 <xsl:copy-of select="let $main-doc := / return tokenize($name,',') ! key('idcollect', ., $main-doc)"/>

或者

 <xsl:variable name="main-doc" select="/"/>
 <xsl:copy-of select="for $token in tokenize($name,',') return key('idcollect', $token, $main-doc)"/>

就足够了。

Answer 2

尝试：

XSLT 2.0

<xsl:stylesheet version="2.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">

<xsl:key name="idcollect" match="*[@id]" use="@id" />
<xsl:variable name="name" select="'d,b,e,a'"/>

<xsl:template match="/">
    <xsl:variable name="ids" select="tokenize($name,',')"/>
    <xsl:for-each select="key('idcollect', $ids)" >
        <xsl:sort select="index-of($ids, .)"/>
         <xsl:copy-of select="."/>
     </xsl:for-each>
</xsl:template>

</xsl:stylesheet>

或者，如果您愿意：

<xsl:stylesheet version="2.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">

<xsl:key name="idcollect" match="*[@id]" use="@id" />
<xsl:variable name="name" select="'d,b,e,a'"/>

<xsl:template match="/">
    <xsl:variable name="xml" select="/"/>
    <xsl:for-each select="tokenize($name, ',')" >
        <xsl:copy-of select="key('idcollect', ., $xml)"/>
     </xsl:for-each>
</xsl:template>

</xsl:stylesheet>