如何在不直接包含我的查询的 function 中为 SQL 命令添加标量变量？

Question

我会尽量保持简短。

我有一个名为 GetData(ByVal query As String) 的 function，其唯一目的是根据特定条件多次填充 data.table。 如您所见，function 接受 SQL 语句所在的字符串变量。 我想要做的是添加一个标量变量，在我的例子中是“@date”，无论我在哪里尝试添加这个变量，它都会抛出一个错误，指出“必须声明标量变量@date。

编辑：我应该提到它在 sda.Fill(dt) 行上抛出“必须声明变量”错误。

获取数据 Function

    Private Shared Function GetData(ByVal query As String) As DataTable
        Dim constr As String = ConfigurationManager.ConnectionStrings("WarrantyConnectionString").ConnectionString
        Using con As SqlConnection = New SqlConnection(constr)
            Using cmd As SqlCommand = New SqlCommand(query)
                Dim dt As DataTable = New DataTable()
                cmd.Parameters.Add("@date", SqlDbType.Date).Value = Date.Today
                Using sda As SqlDataAdapter = New SqlDataAdapter(query, con)
                    cmd.Parameters.AddWithValue("@date", Date.Today)
                    sda.Fill(dt)
                End Using

                Return dt
            End Using
        End Using
    End Function

我在一个具有查询并处理我需要的所有条件的过程中调用 function。

程序

Dim queryStart As String = "SELECT ( SELECT SUM(DealerNet) FROM Agreement WHERE VoidDate IS NULL "
        Dim queryAlias As String = "AS Actual, "
        Dim queryStart2 As String = "(SELECT SUM(Amount) FROM AccountingUS.dbo.ProjectedSales "
        Dim queryAlias2 As String = "AS Projected "

        If chart = "pmtd" Then
            Dim queryCondition As String = "AND IssueDate BETWEEN (SELECT DATEADD(MONTH, DATEDIFF(MONTH, 0, @date)-1, 0)) AND @date) "
            Dim queryCondition2 As String = "WHERE [Month] = MONTH(@date) AND [Year] = YEAR(@date)) "
            Dim query As String = queryStart + queryCondition + queryAlias + queryStart2 + queryCondition2 + queryAlias2
            Dim xMember1 As String = "Actual"
            Dim xMember2 As String = "Projected"

            Dim dt As DataTable = GetData(query)
            pmtdChart.DataSource = dt

有问题的变量是“If”语句中字符串中的@date 变量，它保存的唯一值是今天的日期。 目前，我尝试在 GetData function 中使用“cmd.Parameters.Add("@date", SqlDbType.Date).Value = Date.Today，但是，我仍然收到相同的“必须声明标量变量”错误。我也尝试用简单的“”+ Date.Today +“”或保存今天日期的变量替换@date变量，但在这样做时我收到一个关于“操作数冲突：日期与Int不兼容”的操作数错误

非常感谢有关此问题的任何帮助，我对编程还比较陌生，如果有任何关于最佳实践的提示或批评，我将不胜感激。 如果您需要有关此问题的任何其他信息或说明，我很乐意提供我所能提供的。 先感谢您。

Answer 1

如果仔细观察，您会设置一个 cmd 命令，但实际上您从未将它传递给 DataTable。 所以它对你的参数一无所知。 这个怎么样（从Trying to pass SqlCommand in SqlDataAdapter as parameters复制未经测试）：

DataTable dt = new DataTable();
using (SqlConnection con = new SqlConnection(ConfigurationManager.ConnectionStrings("WarrantyConnectionString").ConnectionString))
            {
                con.Open();
                using (SqlCommand cmd = con.CreateCommand())
                {
                    cmd.CommandText = query;
                    cmd.CommandType = CommandType.Text;
                    cmd.Parameters.Add("@date", SqlDbType.Date)
                    cmd.Parameters.AddWithValue("@date", Date.Today)
                    using (SqlDataAdapter adp = new SqlDataAdapter(cmd))
                    {
                        adp.Fill(dt);
                        return dt;
                    }
                }
            }

Answer 2

    Dim dt as new DataTable()
    using db as new SqlConnection(ConfigurationManager.ConnectionStrings("WarrantyConnectionString").ConnectionString)
        db.Open();
        using cmd as New SqlCommand(query, con)
            cmd.Parameters.Add("@date", SqlDbType.Date).value = Date.Today
            //cmd.Parameters.AddWithValue("@date", Date.Today)
            using adp as new SqlDataAdapter(cmd)
                adp.Fill(dt)
                return dt
            End using
        End using
    End using

Answer 3

好的，有几件事：

我实际上会将命令 object 传递给该获取数据例程。

你的问题是你将查询提供给“适配器”，但没有向那个“sda”提供@date参数

这：

   Using sda As SqlDataAdapter = New SqlDataAdapter(query, con)
      cmd.Parameters.AddWithValue("@date", Date.Today)
      sda.Fill(dt)
   End Using

换句话说，你甚至没有使用 cmd 对象！！！

因此，您需要将参数添加到 sda 对象！！

例如这个：

Public Function GetData(ByVal query As String) As DataTable

    Dim dt As DataTable = New DataTable()

    Dim constr As String =
        ConfigurationManager.ConnectionStrings("WarrantyConnectionString").ConnectionString

    Using con As SqlConnection = New SqlConnection(constr)
        Using sda As SqlDataAdapter = New SqlDataAdapter(query, con)
            sda.SelectCommand.Parameters.Add("@date", SqlDbType.Date).Value = Date.Today()
            sda.Fill(dt)
        End Using
    End Using

    Return dt

End Function

所以，是的，您将收到有关未声明“@date”的错误，因为您没有使用 cmd object 来填充表，而是使用数据适配器。

那么，作为未来的建议？

选择一种方式，或另一种方式。

多年来，我已经决定我将使用/拥有/采用和 cookie cut over SqlCommand object。

我发现 Sql cmd object 更好，因为：

it has the parameters.
it has a connection object (if you want to use)
it has a data reader built in

那么，这意味着什么？

我建议使用此代码获取数据：

Private Shared Function GetData(ByVal query As String) As DataTable
    Dim constr As String =
        ConfigurationManager.ConnectionStrings("WarrantyConnectionString").ConnectionString
    Dim dt As DataTable = New DataTable()

    Using con As SqlConnection = New SqlConnection(constr)
        Using cmd As SqlCommand = New SqlCommand(query, con))
            con.Open()
            cmd.Parameters.Add("@date", SqlDbType.Date).Value = Date.Today
            dt.Load(cmd.ExecuteReader)
        End Using
    End Using

    Return dt

End Function

所以，我们不需要数据适配器。 事实上，如果您要更新结果表，您只需要一个适配器（考虑一个“自适应”表来记住这一点）。 您不会更新数据，所以实际上，这里根本不需要使用“适配器”。 （可悲的是，太多的例子无论如何都使用“适配器”。它们是为了允许更新 data.table，而你不这样做！

所以，使用命令 object。请注意，您必须始终打开糖果，但由于我们有“使用”块，它总是会为您关闭。

并注意我们如何不创建“使用”来自适配器的“阅读器”，也不创建填充命令。 （所以，我们消除了整个令人困惑的 object。！）。

因此，在您的示例中，您创建了一个 SQL 命令 object，正确地将参数添加到命令 object，但随后不使用它，然后决定创建一个数据适配器，并使用它！！！

因此，您可以/可以保留您的代码，就像我在上面发布的 sda“参数”修复程序中所做的那样。

但是，但我认为您最好使用 sql 命令 object。

说明还好吗？

将命令 object 传递给 GetData 例程。

我有一个名为 MyRstP() 的全局“通用”目的例程，我将命令 object 传递给它，即使只是简单的简 sql。

但是，如果您决定添加参数，您可以！

请注意，可以 100% 独立于 SQL 字符串添加参数，并且可以在设置 sql 字符串之前或之后添加它们。

并且您可以在没有有效工作连接的情况下添加参数（或者已经创建了一个）。 所以，“参数”只是一个集合——它不关心 SQL（好吧，至少现在还不是。！）。

所以，这是我的 RstP，我将它转储到 VB 拥有的普通简“module1”中（这意味着您不必创建 static class，然后它就像 VB6 或 VBA 一样工作。

所以这：

Public Function MyRstP(cmdSQL As SqlCommand, ByVal Optional strCon As String = "") As DataTable

    If strCon = "" Then
        strCon = My.Settings.TEST4
    End If

    Dim rstData As New DataTable
    Using conn As New SqlConnection(strCon)
        Using (cmdSQL)
            cmdSQL.Connection = conn
            conn.Open()
            rstData.Load(cmdSQL.ExecuteReader)
        End Using
    End Using

    Return rstData

End Function

所以，现在说填充网格视图，我使用这个：

    Dim strSQL As String =
        "SELECT id, HotelName, City FROM tblHotelsA"

    Dim cmdSQL As New SqlCommand(strSQL)

    GridView1.DataSource = MyRstP(cmdSQL)
    GridView1.DataBind()

或者说一些这样的给定日期：从年初开始的所有酒店访问日期如何。

所以这：

    Dim strSQL As String =
        "SELECT id, HotelName, City FROM tblHotelsA
        WHERE VisitDate >= @dtStart"

    Dim dtStart As DateTime
    dtStart = DateSerial(DateTime.Today.Year, 1, 1)

    Dim cmdSQL As New SqlCommand(strSQL)
    cmdSQL.Parameters.Add("@dtStart", SqlDbType.DateTime).Value = dtStart

    GridView1.DataSource = MyRstP(cmdSQL)
    GridView1.DataBind()

请注意我是如何拥有 MyRstP（就像您的获取数据）的，但是我可以传递任何我想要的东西，包括来自“调用”代码的参数，而不是在那个通用例程中。

无论如何，上述使用并将参数添加到“适配器”将解决此问题，但我会改用仅使用命令 object 和连接 - 适配器确实不需要，并且如前所述，它们确实将在 WHEN您实际上想更新 data.table，然后一次性将其发送回数据库。