解析器错误：“信号”参数标识符后应为“,”或“)”

Question

播放器脚本给我错误。

extends KinematicBody2D

const FRICTION = 5000
const ACCELERATION = 5000
const MOVE_SPEED = 300

onready var animationPlayer = $AnimationPlayer

var velocity = Vector2.ZERO
var aim_direction: Vector2
var max_recoil: float
var current_recoil: float

# Declare the signal that will be used to add recoil to the player's aim
signal add_recoil(recoil: float)

func _ready():
    aim_direction = Vector2(1, 0)
    max_recoil = 20
    current_recoil = 0
    connect("add_recoil", self, "_on_add_recoil")

# Add recoil to the player's aim
func _on_add_recoil(recoil: float) -> void:
    current_recoil += recoil
    
    # Clamp the current recoil to the maximum recoil
    current_recoil = clamp(current_recoil, 0, max_recoil)


func _physics_process(delta):
    #--Local Variables--
    var lerp_rate = FRICTION

    #--Input Logic--
    var input_vector = Vector2(Input.get_action_strength("ui_right") - Input.get_action_strength("ui_left"),
                       Input.get_action_strength("ui_down") - Input.get_action_strength("ui_up"))
    if input_vector.y != 0: lerp_rate = ACCELERATION

    #--Animation Logic--
    if input_vector.y == -1:
        animationPlayer.play("WalkUp")
    elif input_vector.y == 1:
        animationPlayer.play("WalkDown")
    elif input_vector == Vector2.ZERO:
        animationPlayer.stop()

    #--Movement--
    velocity = velocity.move_toward(MOVE_SPEED*input_vector, lerp_rate*delta) 
    velocity = move_and_slide(velocity)
    
    # Slowly reduce the current recoil over time
    current_recoil = lerp(current_recoil, 0, delta * 5)
    
    # Rotate the aim direction by the current recoil
    aim_direction = aim_direction.rotated(current_recoil)

错误出现在信号 add_recoil(recoil: float)如果 Godot 引擎的任何编码智慧可以解释如何解决这个问题，那就太好了。

它应该从 WeaponBaseClass 脚本接收到玩家瞄准的信号。

有问题的脚本：

extends KinematicBody2D
export (PackedScene) var Bullet

# Declare variables to store the properties of the weapon
export var weapon_name: String
export var recoil: float
export var damage: int
export var shooting_speed: float
export var magazine_capacity: int
export var reload_speed: float
export var attachments: Array

# Get a reference to the player kinematic node in the main scene
onready var player_node = get_node("/root/Main/Player")

# Declare a variable to store the speed of the bullets fired by the weapon
export var bullet_speed: float

onready var end_of_gun = $EndOfGun

# Declare variables to store the current state of the weapon
var current_magazine: int
var is_reloading: bool

# Initialize the weapon
func _ready():
    current_magazine = magazine_capacity
    is_reloading = false

func _process(delta: float) -> void:
    look_at(get_global_mouse_position())

func _unhandled_input(event: InputEvent) -> void:
    if event.is_action_released ("shoot"):
        shoot()
    if event.is_action_released ("reload"):
        reload()

# Shoot the weapon
func shoot():
    # Check if the weapon is reloading or out of ammo
    if is_reloading or current_magazine <= 0:
        return
    
    # Decrement the magazine size
    current_magazine -= 1
    
    # Emit the "add_recoil" signal to tell the player to add recoil to their aim
    EventBus.emit_signal("add_recoil", recoil)
    
    # Send the add_recoil signal to the player
    player_node.add_recoil(recoil)
    
    # Play a shooting sound effect
    #audio_play("shoot.wav")
    
    # Spawn a bullet and apply damage to any enemies it hits
    var bullet = preload("Bullet.tscn").instance()
    
    # Set the bullet speed
    #bullet.set_linear_velocity(Vector2(BULLET_SPEED, 0))
    
    var target = get_global_mouse_position()
    var direction_to_mouse = end_of_gun.global_position.direction_to(target).normalized()
    bullet.rotation = get_global_transform().get_rotation()
    EventBus.emit_signal("fired_bullet", bullet, end_of_gun.global_position, direction_to_mouse)
    bullet.damage = damage
    add_child(bullet)

# Reload the weapon
func reload():
    # Check if the weapon is already reloading
    if is_reloading:
        return
    
    # Set the reloading flag
    is_reloading = true
    
    # Play a reloading sound effect
    #audio_play("reload.wav")
    
    # Call the reload animation
    $AnimationPlayer.play("reload")
    
    # Wait for the reload time to elapse
    yield(get_tree().create_timer(reload_speed), "timeout")
    
    # Reset the reloading flag and refill the magazine
    is_reloading = false
    current_magazine = magazine_capacity

如果有帮助，我还有一个 EventBus 脚本：

extends Node

#Only holds signals
signal fired_bullet(bullet, position, direction)

Answer 1

Godot 3 中的 GDScript 不支持指定信号参数的类型。 它会在 Godot 4 中工作。

所以 Godot 3 不会解析这个：

signal add_recoil(recoil: float)

相反，您必须删除类型：

signal add_recoil(recoil)