加起来等于目标值 n 的唯一集合

Question

给定的数据库：

age(ann, 20).
age(joe, 44).
age(bob, 40).
age(min, 27).
age(cai, 20).
age(ned, 27).
age(deb, 36).
age(pat, 36).
age(edo, 24).
age(tod, 56).

到目前为止我所拥有的：

hundred(L) :-
    findall(X, age(X,_), L1),
    sum(L1,100,L), 
    length(L,Len),
    Len > 1.

sum(_, 0, []).
sum(L, S, [H|T]) :-
    select(H, L, L1),
    age(H, A),
    S1 is S-A,
    S1 >= 0,
    sum(L1, S1, T).

我想在数据库中获得年龄总和为 100 的唯一一组人（长度 > 1）。我的解决方案产生所有可能的排列，而我想获得如下所示的唯一一组人（清单output 示例中的顺序无关紧要）：

L=[joe,tod];
L=[ann,joe,deb];
L=[ann,joe,pat];
L=[ann, edo, tod];
L=[ann, cai, deb, edo];
L=[ann, cai, edo, pat];
L=[cai, edo, tod];
L=[joe, cai, deb];
L=[joe, cai, pat];
L=[bob, deb, edo];
L=[bob, pat, edo];

为清楚起见：人们可能年龄相同，这很好。 所以数字组合本身可能包括重复项以达到 100，只要这些年龄属于不同的人。 最后，每个解决方案都应该是不同人的组合，而不应该仅仅是对先前解决方案的排列。 我的解决方案总是采用不同人的组合，但将顺序中的每个更改都列为新解决方案。 我试图通过将所有解决方案放在列表列表中然后对其进行排序以删除重复项来摆脱排列，但它没有用。

Answer 1

对于数字，可以使用通用谓词：

sub_list_sum(Sum, Lst, Sub) :-
    compare(C, Sum, 0),
    sub_list_sum_(C, Sum, Lst, Sub).

sub_list_sum_(=, 0, _, []).
sub_list_sum_(>, Sum, Lst, [E|Sub]) :-
    select_forward(E, Lst, Lst0),
    Sum0 is Sum - E,
    compare(C, Sum0, 0),
    sub_list_sum_(C, Sum0, Lst0, Sub).

% A subsequence variant of select/3
select_forward(E, [H|T], F) :-
    select_forward_(T, H, E, F).

select_forward_(T, H, H, T).
select_forward_([H|T], _, E, F) :-
    select_forward_(T, H, E, F).

swi-prolog 中的结果：

?- Dupes = [20, 44, 40, 27, 20, 27, 36, 36, 24, 56],
sort(Dupes, Sorted), sub_list_sum(100, Sorted, S).
S = [20, 24, 56] ;
S = [20, 36, 44] ;
S = [24, 36, 40] ;
S = [44, 56] ;
false.

为年龄定制这个：

age(ann, 20).
age(joe, 44).
age(bob, 40).
age(min, 27).
age(cai, 20).
age(ned, 27).
age(deb, 36).
age(pat, 36).
age(edo, 24).
age(tod, 56).

sub_list_age_sum(Sum, Sub) :-
    % Want at least length 2
    Sub = [_,_|_],
    bagof(age(P, A), age(P, A), Ages),
    compare(C, Sum, 0),
    sub_list_age_sum_(C, Sum, Ages, Sub).

sub_list_age_sum_(=, 0, _, []).
sub_list_age_sum_(>, Sum, Lst, [P|Sub]) :-
    select_forward(age(P, A), Lst, Lst0),
    Sum0 is Sum - A,
    compare(C, Sum0, 0),
    sub_list_age_sum_(C, Sum0, Lst0, Sub).

...并添加上面的select_forward代码 - 结果：

?- sub_list_age_sum(100, L).
L = [ann, joe, deb] ;
L = [ann, joe, pat] ;
L = [ann, cai, deb, edo] ;
L = [ann, cai, pat, edo] ;
L = [ann, edo, tod] ;
L = [joe, cai, deb] ;
L = [joe, cai, pat] ;
L = [joe, tod] ;
L = [bob, deb, edo] ;
L = [bob, pat, edo] ;
L = [cai, edo, tod] ;
false.