检查项目是否在 SAS 列表中

Question

我有一个 SAS 列表。 这个 SAS 列表存储在一个宏变量中。 请假设我没有表格来导出这个 SAS 列表。

SAS 列表包含以逗号分隔的名称。 SAS 列表宏变量示例：

%LET sas_list = name1,name2,name3;

我想检查列表中是否存在宏变量“item”。

就像是：

%IF &item. IN &sas_list. %THEN %DO;
Whatever;
%END;

出于某种原因，我收到错误：

“A character operand was found in the %EVAL function or %IF condition where a numeric operand is required. The condition was: name1 IN name1,name2,name3”

感谢帮助。

Answer 1

添加minoperator和mindelimiter系统选项。 它们代表 Macro IN Operator 和 Macro IN Delimiter。

options minoperator mindelimiter=',';

%LET sas_list = name1,name2,name3;
%LET item = name1;

%IF &item. IN &sas_list. %THEN %DO;
    %put &item is in &sas_list;
%END;

Output：

name1 is in name1,name2,name3

如果要查找不在列表中的值，请将其传递给%eval 。

options minoperator mindelimiter=',';

%LET sas_list = name1 name2 name3;
%LET item = name4;

%IF %eval(&item. IN &sas_list.) = 0 %THEN %DO;
    %put &item NOT in &sas_list;
%END;

Output：

name4 is NOT in name1,name2,name3

请注意，如果您只想in选择地工作，也可以直接在宏中提供这些选项。 例如：

%macro foo / minoperator mindelimiter=',';
    ...
%mend;

Answer 2

您需要在此处使用两个选项：

1. MINOPERATOR ，这将允许使用 IN 运算符
2. MINDELIMITER ，这将允许您设置分隔符

%let sas_list = name1,name2,name3;
options minoperator mindelimiter=',';
%Macro want(item);
    %if &item. in &sas_list. %then %put i = 1;
    %else %put i = 0;
%mend;
%want(name1);

i = 1

Answer 3

您还可以使用FINDW函数来确定列表中是否存在某个项目。

%if %sysfunc(FINDW(%upcase(%superq(saslist)), %upcase(&item), %str(,))) %then %do;
...
%end;

Answer 4

配套

 %LET sas_list = name1,name2,name3;

您可以通过这种方式查找name2是否在列表中。

data test;
    it = findw("&sas_list", 'name2',',');
run;

但我假设您想在不使用data步骤的情况下找到它，所以

%let het = %sysfunc(findw(%quote(&sas_list),name2,%quote(,)));
%put NOTE: het is &het;

完成工作。 笔记

• 你发现不是宏 function，所以你需要%sysfunc()在宏语句中调用它
• 你必须用%quote()掩盖逗号。 否则它们将被视为参数分隔符。