VBA For循环中的乘法

Question

有问题，我需要创建一个范围从 11 到 20 的乘法表，但它在 B2 中需要是 output 而不是它的通用值，所以当我使用 for 循环编写我的代码时，我无法得到 output 结果工作表中的其他任何地方，我需要它 output 结果表到 B2。

output 从 K11 到 T20，但我需要这些结果到 output 从 B1 到 K10。 任何帮助都感激不尽！

这是我到目前为止所得到的：

Private Sub CommandButton1_Click()
Dim i As Integer, x As Integer
For i = 11 To 20
For x = 11 To 20
cells(i, x) = i * x
Next
Next
End Sub

Answer 1

尝试这个

Private Sub CommandButton1_Click()
Dim i As Integer, x As Integer
For i = 1 To 10
For x = 2 To 11
Cells(i , x) = (i + 10) * (x + 9)
Next
Next
End Sub

Answer 2

一个很好的选择是预先设置一些变量然后使用偏移量：

Sub Main()
        
    Dim ST_RG As Range  'Start range, this is where your values will begin being output
    Dim Y As Long       'Y axis count
    Dim X As Long       'X axis count
    Dim lFrom As Long   'Count From
    Dim lTo As Long     'Count To
    
    ' Set all your parameters here:
    Set ST_RG = Sheet4.Range("A1")
    lFrom = 11
    lTo = 20
    
    For Y = lFrom To lTo
        For X = lFrom To lTo
            ST_RG.Offset(Y - lFrom, X - lFrom).Value = Y * X
        Next
    Next

End Sub

例子：

Answer 3

创建乘法口诀表

• WriteMultiplicationTable过程的最佳位置是在标准模块中，例如Module1 ，因此您可以轻松地从任何其他模块调用它。
• 请小心调整正确的单元格，因为您首先提到单元格B2 ，然后是范围B1:K10 。

Option Explicit

Private Sub CommandButton1_Click()
    
    Dim wb As Workbook: Set wb = ThisWorkbook ' workbook containing this code
    Dim ws As Worksheet: Set ws = wb.Sheets("Sheet1")
    Dim fCell As Range: Set fCell = ws.Range("B1")
    WriteMultiplicationTable fCell, 11, 20
    
    ' Alternatively, if the command button is in the worksheet where
    ' you want to create the table, instead of the previous, you could use
    ' the following one-liner:
    'WriteMultiplicationTable Me.Range("B1"), 11, 20

End Sub

Sub WriteMultiplicationTable( _
        ByVal FirstCell As Range, _
        ByVal StartNumber As Long, _
        ByVal EndNumber As Long)
    
    Dim Data() As Long
    ReDim Data(StartNumber To EndNumber, StartNumber To EndNumber)
    
    Dim r As Long, c As Long
    
    For r = StartNumber To EndNumber
        For c = StartNumber To EndNumber
            Data(r, c) = r * c
        Next c
    Next r
    
    Dim nCount As Long: nCount = EndNumber - StartNumber + 1
    
    FirstCell.Cells(1).Resize(nCount, nCount).Value = Data
    
End Sub