XSLT 3 | Hash Function

Question

我们一直在寻找从给定文档生成特定文本的 hash，并提出了以下版本的 XSLT：

<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:iway="http://iway.company.com/saxon-extension">
    <xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes" exclude-result-prefixes="iway"/>
    <xsl:strip-space elements="*"/>

    <xsl:template match="*[not(descendant::text()[normalize-space()])]"/>

    <xsl:template match="@*|node()">
        <xsl:copy>
            <xsl:apply-templates select="@*|node()"/>
        </xsl:copy>     
    </xsl:template>
    
    <xsl:template match="row" exclude-result-prefixes="iway">
    <xsl:variable name="jsonForHash" select="JSON_Output/text()"/>
    <xsl:variable name="iflExpression" select="concat('_sha1(''', $jsonForHash, ''')')"/>
        <xsl:copy>
            <xsl:apply-templates select="@*|node()"/>
            <CurrentDataHash type="12" typename="varchar"><xsl:value-of select="iway:ifl($iflExpression)"/></CurrentDataHash>   
            <Duplicity type="12" typename="varchar"><xsl:value-of select="$jsonForHash = LastDataHash/text()"/></Duplicity>     
        </xsl:copy>     
    </xsl:template>

</xsl:stylesheet>

......哪个做的工作。 缺点是，它无法在不进行修改的情况下在本地（在 Altova/Stylus Studio 上）进行测试，我们希望能够做到这一点。 这仅在依赖 Saxon-HE-9* 的运行时有效。 为了解决这个问题，我们尝试了以下版本（灵感来自HERE ）：

<xsl:transform version="3.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:digest="java?path=jar:file:///C:/libs/commons-codec-1.13.jar!/">
    <xsl:output method="xml" indent="yes" omit-xml-declaration="yes"/>

    <xsl:template match="/">
        <Output>
            <xsl:apply-templates mode="hash"/>
        </Output>
    </xsl:template>
    
    <xsl:template match="SKU_SEG" mode="hash">
        <Group>
            <xsl:variable name="val" select="."/>
            <xsl:copy-of select="$val"/>
            <xsl:variable name="hash-val" select="digest:org.apache.commons.codec.digest.DigestUtils.md5Hex($val)"/>
            <HashValue>
                <xsl:value-of select="$hash-val"/>
            </HashValue>
        </Group>
    </xsl:template>
    
</xsl:transform>

...仅在 Altova 上本地工作，但在我们使用 Saxon-HE 时在运行时不起作用，但该功能仅在 Saxon-PE/EE 上受支持。 为了克服这个问题，我们想出了这个版本：

<xsl:transform version="3.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:digest="java?path=jar:file:///C:/libs/commons-codec-1.13.jar!/" xmlns:iway="http://iway.company.com/saxon-extension" exclude-result-prefixes="digest iway">
    <xsl:output method="xml" indent="yes" omit-xml-declaration="yes" exclude-result-prefixes="digest iway"/>
    <xsl:template match="/">
        <Output>
            <xsl:apply-templates mode="hash"/>
        </Output>
    </xsl:template>
    <xsl:template match="SKU_SEG" mode="hash">
        <xsl:variable name="parserInfo" select="system-property('xsl:vendor')"/>
        <Group>
            <xsl:variable name="textForHash" select="."/>
            <xsl:variable name="iflExpression" select="concat('_sha1(''', $textForHash, ''')')"/>
            <xsl:copy-of select="$textForHash"/>
            <xsl:variable name="hashedVal">
                <xsl:choose>
                    <xsl:when test="contains(lower-case($parserInfo), 'saxon')">
                        <xsl:value-of select="iway:ifl($textForHash)"/>
                    </xsl:when>
                    <xsl:otherwise>
                        <xsl:value-of select="digest:org.apache.commons.codec.digest.DigestUtils.md5Hex($textForHash)"/>
                    </xsl:otherwise>
                </xsl:choose>
            </xsl:variable>
            <HashValue>
                <xsl:value-of select="$hashedVal"/>
            </HashValue>
        </Group>
    </xsl:template>
</xsl:transform>

...它在 Altova XMLSpy 上本地工作，但在运行时不工作，因为 Saxon 抱怨以下内容：

net.sf.saxon.trans.XPathException: 
Cannot find a 1-argument function named 
Q{java?path=jar:file:///C:/libs/commons-codec-1.13.jar!/}
org.apache.commons.codec.digest.DigestUtils.md5Hex(). 
Reflexive calls to Java methods are not available under Saxon-HE

现在的问题是：是否有可能完全达到要求？ 提前致谢。

Setup Info: 
Runtime: Java Application relying on Saxon-HE
XSLT Versions Supported: 1/2/3
Standalone Tool for local tests: Altova XMLSpy

PS：下面的版本（灵感来自HERE ）似乎在本地和远程工作，如果要散列的文本不是太长，但这里散列的文本太长，比 HTTP URL 允许的更长，因此不是一种选择：

<xsl:transform version="3.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output method="xml" indent="yes" omit-xml-declaration="yes"/>
    
    <xsl:template match="/">
        <Output>
            <arg0>
                <xsl:text disable-output-escaping="yes">&lt;![CDATA[</xsl:text>
                <xsl:copy>
                    <xsl:apply-templates/>
                </xsl:copy>
                <xsl:text disable-output-escaping="yes">]]&gt;</xsl:text>
            </arg0>
            <arg1>
                <xsl:apply-templates mode="hash"/>
            </arg1>
        </Output>
    </xsl:template>
    
    <xsl:template match="SKU_SEG">
        <xsl:copy-of select="."/>
    </xsl:template>
    
    <xsl:template match="SKU_SEG" mode="hash">
        <xsl:variable name="val" select="."/>
        <!-- delegate to an external REST service to calculate the MD5 hash of the value -->
        <xsl:variable name="hash-val" select="unparsed-text(concat('http://localhost/md5?text=', encode-for-uri($val)))"/>
        <!-- the response from this service is wrapped in quotes, so need to trim those off -->
        <xsl:value-of select="substring($hash-val, 2, string-length($hash-val) - 2)"/>
    </xsl:template>
    
</xsl:transform>

作为参考，这里是撒克逊分机号 function：

 private void registeriWayXsltExtensions_iFLEval(final XDDocument docIn) {
    log(".init() Registering iWay XSLT extensions...", "info");
    this.iway_xslt_extension_ifl = new ExtensionFunction() {
        public QName getName() {
          return new QName("http://iway.company.com/saxon-extension", "ifl");
        }
        
        public SequenceType getResultType() {
          return SequenceType.makeSequenceType(ItemType.STRING, OccurrenceIndicator.ONE);
        }
        
        public SequenceType[] getArgumentTypes() {
          return 
            new SequenceType[] { SequenceType.makeSequenceType(ItemType.STRING, OccurrenceIndicator.ONE) };
        }
        
        public XdmValue call(XdmValue[] arguments) throws SaxonApiException {
          String iflExpression = ((XdmAtomicValue)arguments[0].itemAt(0)).getStringValue();
          SaxonXsltAgent.this.log(".execute()  Received iFL Expression: " + iflExpression, "info");
          String iflResult = null;
          if (iflExpression != null && !iflExpression.equals(""))
            iflResult = XDUtil.evaluate(iflExpression, docIn, SaxonXsltAgent.this.getSRM()); 
          return (XdmValue)new XdmAtomicValue(iflResult);
        }
      };
    this.xsltProcessor.registerExtensionFunction(this.iway_xslt_extension_ifl);
    log(".execute() \"ifl\" registered.", "info");
  }

Answer 1

我会尝试例如

<xsl:value-of 
  select="iway:ifl($textForHash)" 
  use-when="exists(function-lookup(QName('http://iway.company.com/saxon-extension', 'ifl'), 1))"/>

和

<xsl:value-of select="disest:org.apache.commons.codec.digest.DigestUtils.md5Hex($textForHash)" 
  use-when="exists(function-lookup(QName('java?path=jar:file:///C:/libs/commons-codec-1.13.jar!/', 'org.apache.commons.codec.digest.DigestUtils.md5Hex'), 1))"/>`.

这是该方法的一个完整示例（应该只适用于 Saxon HE 10 或更高版本，诚然，因为早期的 HE 版本不支持高阶函数）：

package org.example;

import net.sf.saxon.s9api.*;

import javax.xml.transform.stream.StreamSource;

public class Main {
    public static void main(String[] args) throws SaxonApiException {
        Processor processor = new Processor(true);

        ExtensionFunction sqrt = new ExtensionFunction() {
            public QName getName() {
                return new QName("http://example.org/mf", "sqrt");
            }

            public SequenceType getResultType() {
                return SequenceType.makeSequenceType(
                        ItemType.DOUBLE, OccurrenceIndicator.ONE
                );
            }

            public SequenceType[] getArgumentTypes() {
                return new SequenceType[]{
                        SequenceType.makeSequenceType(
                                ItemType.DOUBLE, OccurrenceIndicator.ONE)};
            }

            public XdmValue call(XdmValue[] arguments) throws SaxonApiException {
                double arg = ((XdmAtomicValue)arguments[0].itemAt(0)).getDoubleValue();
                double result = Math.sqrt(arg);
                return new XdmAtomicValue(result);
            }
        };

        processor.registerExtensionFunction(sqrt);

        XsltCompiler xsltCompiler = processor.newXsltCompiler();

        Xslt30Transformer xslt30Transformer = xsltCompiler.compile(new StreamSource("sheet1.xsl")).load30();

        xslt30Transformer.callTemplate(null, xslt30Transformer.newSerializer(System.out));
    }
}

XSLT

<?xml version="1.0" encoding="utf-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
                version="3.0"
                xmlns:xs="http://www.w3.org/2001/XMLSchema"
                xmlns:mf="http://example.org/mf"
                xmlns:java-math="java:java.lang.Math"
                exclude-result-prefixes="#all"
                expand-text="yes">

    <xsl:mode on-no-match="shallow-copy"/>

    <xsl:output indent="yes"/>

    <xsl:template match="/" name="xsl:initial-template">
        <test>
            <integrated-extension-function>
                <xsl:value-of select="mf:sqrt(4)" use-when="exists(function-lookup(QName('http://example.org/mf', 'sqrt'), 1))"/>
            </integrated-extension-function>
            <reflexive-extension-function>
                <xsl:value-of select="java-math:sqrt(4)" use-when="exists(function-lookup(QName('java:java.lang.Math', 'sqrt'), 1))"/>
            </reflexive-extension-function>
        </test>
        <xsl:comment>Run with {system-property('xsl:product-name')} {system-property('xsl:product-version')} {system-property('Q{http://saxon.sf.net/}platform')}</xsl:comment>
    </xsl:template>

</xsl:stylesheet>

当使用上面的 Java 代码在 Saxon HE 11 中注册 function 时，结果是例如

<?xml version="1.0" encoding="UTF-8"?>
<test>
   <integrated-extension-function>2</integrated-extension-function>
   <reflexive-extension-function/>
</test>
<!--Run with SAXON HE 11.4 -->

当通过 Saxon EE 运行 XSLT 而未注册集成扩展 function 时，output 是

<?xml version="1.0" encoding="UTF-8"?>
<test>
   <integrated-extension-function/>
   <reflexive-extension-function>2</reflexive-extension-function>
</test>
<!--Run with SAXON EE 11.4 -->

因此，使用(xsl):use-when="exists(function-lookup(..))"您可以有条件地仅在某个 function 可用时注入代码。

Github 上的示例项目： https://github.com/martin-honnen/SaxonHEIntegratedExtFnSample2

Answer 2

如果你想在 SaxonJ-HE 中调用 Java 那么你需要实现一个“集成扩展功能”并将其注册到 Saxon 配置中，而不是依赖于动态加载和自反调用。

不难：看https://www.saxonica.com/documentation12/index.html#!extensibility/extension-functions-J/ext-simple-J