反转terraform中yaml节点的关联

Question

假设以下yaml输入文件

admins:
  members:
    - john@gmail.com
    - peter@gmail.com
viewers:
  members:
    - maria@gmail.com
    - john@gmail.com

通过yamldecode传递给var.memberships ，是否可以生成一个对象列表，该列表将member作为key并将其所属的组作为值，即类似于

{
  "maria@gmail.com" = {
    groups = ["viewers"]
  },
  "john@gmail.com" = {
    groups = ["admins", "viewers"]
  },
  "peter@gmail.com" = {
    groups = ["admins"]
  }
}

Answer 1

在 Terraform 语言中，将一种数据结构投影到另一种数据结构的一般答案是for 。

在这种特殊情况下， 分组结果机制将成为解决方案的一部分，因为您希望通过按特定键（email 地址）分组，将 map 中可能的许多元素从输入到 output 中的单个元素。

我想我首先要展平这个数据结构，这样它就只是一组成员+组对，因此每个元素都单独描述一个成员和一个组之间的关系。

locals {
  memberships = setunion([
    for group_name, group in var.memberships : toset([
      for member_email in group.members : {
        member_email = member_email
        group_name   = group_name
      }
    ])
  ]...)
}

通过此声明和您的示例输入，我希望中间结果为：

memberships = toset([
  { member_email = "john@gmail.com", group_name = "admins" },
  { member_email = "peter@gmail.com", group_name = "admins" },
  { member_email = "maria@gmail.com", group_name = "viewers" },
  { member_email = "john@gmail.com", group_name = "viewers" },
])

然后我们可以第二次投影它，将其转换为 map，从 email 地址到 collections 组：

locals {
  member_groups = tomap({
    for membership in local.memberships :
    membership.member_email => membership.group_name...
  })
}

member_groups = tomap({
  "john@gmail.com" = ["admins", "viewers"]
  "maria@gmail.com" = ["viewers"]
  "peter@gmail.com" = ["admins"]
})

这现在具有与您想要的数据结构相同的信息，但形状不太正确，因此再进行一次转换就可以准确地实现您在问题中描述的对象的 map：

locals {
  users = tomap({
    for email, groups in local.member_groups : email => {
      groups = toset(groups)
    }
  })
}

users = tomap({
  "john@gmail.com" = {
    groups = toset(["admins", "viewers"])
  }
  "maria@gmail.com" = {
    groups = toset(["viewers"])
  }
  "peter@gmail.com" = {
    groups = toset(["admins"])
  }
})