VBA中使用AutoFilter后如何复制特定范围的单元格？

Question

我在弄清楚 AutoFilter function 在 VBA 中的工作原理时遇到了一些麻烦。这行代码： Worksheets("my sheet").Range("A1").AutoFilter Field:=14, Criteria1:="my criteria" filters第 14 列中的工作表就像我想要的那样很好，但是当我 go 使用这段代码复制第一个列时：

Dim LR As Long
LR = Cells(Rows.Count, 1).End(xlUp).Row
Worksheets("my sheet").Range("A2:A" & LR).Copy

然后我将第一个 col (A1) 的第一个 header 复制到我创建的工作表中，这不是我想要的。 我想复制过滤的所有内容，但 header（A2 和过滤列的末尾）。

我试图分离创建我正在将 col 复制到的工作表的函数，以防创建工作表时出现问题，但这并没有解决问题。 我确实从 inte.net 上截取了这段代码：

Dim LR As Long
LR = Cells(Rows.Count, 1).End(xlUp).Row

但据我所知，这不应该是问题，因为如果我再次运行宏（两次），一旦创建了新工作表并对其进行了格式化（只是单元格 A1 和 B1 中的一些文本和这些单元格的一些格式）。 任何见解将不胜感激！

Answer 1

设置过滤数据的范围

Set Rng = Range("A1:A" & Cells(Rows.Count, "A").End(xlUp).Row).SpecialCells(xlCellTypeVisible)

Answer 2

复制筛选范围的第一列

• 在立即 window Ctrl+G中，查看范围的相关地址。

Option Explicit

Sub CopyFirstColumnOfFilteredRange()

    Dim wb As Workbook: Set wb = ThisWorkbook ' workbook containing this code
    
    Dim sws As Worksheet: Set sws = wb.Sheets("Sheet1")
    If sws.AutoFilterMode Then sws.AutoFilterMode = False ' turn off AutoFilter
    
    Dim srg As Range: Set srg = sws.Range("A1").CurrentRegion ' table range
    Dim sdrg As Range: ' data range (no headers): first column ', 1'
    Set sdrg = srg.Resize(srg.Rows.Count - 1, 1).Offset(1)
    
    Debug.Print srg.Address
    Debug.Print sdrg.Address
    
    srg.AutoFilter 14, "My Criteria"
    
    Dim sdvrg As Range ' visible data range (no headers)
    On Error Resume Next ' to prevent error if no cells
        Set sdvrg = sdrg.SpecialCells(xlCellTypeVisible)
    On Error GoTo 0
    
    sws.AutoFilterMode = False ' turn off AutoFilter
    
    If sdvrg Is Nothing Then
        MsgBox "No filtered rows.", vbExclamation
        Exit Sub
    End If
    
    Debug.Print sdvrg.Address

    Dim dws As Worksheet: Set dws = wb.Sheets("Sheet2")
    Dim dfCell As Range: Set dfCell = dws.Range("A2")
    
    sdvrg.Copy dfCell

    MsgBox "Filtered column copied.", vbInformation

End Sub