06533. 00000 - “无法计数的下标”

Question

我有这个 plsql 块，它用其他两个表的信息填充一个表，我必须使用一个变量数组：

DECLARE nombre_grupo VARCHAR2(15);
    direccion_tipo direccion;
    persona_tipo persona;
    personas_array personas := personas();
    CURSOR departamento IS
    SELECT * FROM departamentos;
    CURSOR empleado IS
    SELECT * FROM empleados, departamentos
    WHERE empleados.dept_no = departamentos.dept_no;
    i INTEGER;
BEGIN
    FOR departamento IN (SELECT * FROM departamentos) LOOP
    nombre_grupo := departamento.dnombre;
    i := 1;
    personas_array := personas();
    FOR empleado IN (SELECT * FROM empleados WHERE dept_no = departamento.dept_no) LOOP
        direccion_tipo := DIRECCION(departamento.loc, 'NULL', empleado.dir);
        personas_array(i) := PERSONA(empleado.emp_no, empleado.apellido,
        direccion_tipo, empleado.fecha_alt);
        i := i + 1;
    END LOOP;
    INSERT INTO grupos VALUES (nombre_grupo, personas_array);
    END LOOP;
END;

这是类型角色：

CREATE OR REPLACE TYPE personas AS VARRAY(5) OF PERSONA

因此，当我执行该块并且它到达personas_array(i)位时，无论 i 的值是多少，它都会以“下标超出计数”错误退出执行。 我错过了什么？

我已经删除并再次创建了类型角色，我也试过在过程中创建类型，但它不能插入到表中

Answer 1

给 SQL 初学者的一些提示：

不要学习 30 岁 Oracle 连接语法。 使用现代 ANSI 连接语法，即

SELECT * 
FROM empleados 
   JOIN departamentos ON empleados.dept_no = departamentos.dept_no;

你的游标是多余的。 要么使用

DECLARE 
    CURSOR cur_departamento IS
    SELECT * 
    FROM departamentos;   
BEGIN
    FOR departamento IN cur_departamento LOOP
       ...
    END LOOP;
END;

或者

DECLARE 
BEGIN
    FOR departamento IN (SELECT * FROM departamentos) LOOP
       ...
    END LOOP;
END;

你也可以使用这个：

DECLARE 
    CURSOR cur_empleados(d IN EMPLEADOS.DEPT_NO%TYPE) IS
    SELECT * 
    FROM EMPLEADOS
    WHERE dept_no = d;

   /*
   -- Do not use this!
    CURSOR cur_empleados(dept_no IN EMPLEADOS.DEPT_NO%TYPE) IS
    SELECT * 
    FROM EMPLEADOS
    WHERE EMPLEADOS.dept_no = dept_no;  -> will return all rows
    */    

BEGIN
   FOR departamento IN (SELECT * FROM departamentos) LOOP
      FOR empleado  IN cur_empleados(departamento.dept_no) LOOP
         ...
      END LOOP;
   END LOOP;
END;

根据我的感觉，VARRAY 通常是学生资料的一部分，但在现实生活中几乎没有用到。

使用字符串'NULL'很可能不是您想要的。 使用文字NULL ，即

DIRECCION(departamento.loc, NULL, empleado.dir)

类型VARRAY(5) OF PERSONA定义了一个最大大小为 5 个元素的 varray。 当你用personas_array:= personas();初始化它时则实际大小为 0。您需要扩展 varray。

您的代码可能如下所示：

DECLARE 

    nombre_grupo VARCHAR2(15); 
    direccion_tipo direccion;
    persona_tipo persona;
    personas_array personas;

    i INTEGER;
    
BEGIN
    FOR departamento IN (SELECT * FROM departamentos) LOOP
        nombre_grupo := departamento.dnombre;
        i := 1;
        personas_array := personas();
        FOR empleado IN (SELECT * FROM empleados WHERE dept_no = departamento.dept_no AND ROWNUM <= 5) LOOP
            direccion_tipo := DIRECCION(departamento.loc, NULL, empleado.dir);
            personas_array.extend();
            personas_array(i) := PERSONA(empleado.emp_no, empleado.apellido, direccion_tipo, empleado.fecha_alt);
            i := i + 1;
        END LOOP;
        INSERT INTO grupos VALUES (nombre_grupo, personas_array);
    END LOOP;
END;

请注意，这样的程序性能会很低。 这样做的专业方法是嵌套表，然后使用单个命令插入数据：

CREATE OR REPLACE TYPE personas_NT AS TABLE OF PERSONA;

INSERT INTO grupos VALUES (nombre_grupo, personas_array)
SELECT dnombre, 
    CAST(MULTISET(
        SELECT 
            emp_no, 
            apellido, 
            DIRECCION(dept.loc, NULL, dir), 
            fecha_alt
        FROM EMPLEADOS
        WHERE dept_no = dept.dept_no
    ) AS personas_NT) AS personas_array
FROM DEPARTAMENTOS dept;

但也许，那将是“高级”SQL 课程中的一章。