如何在列出的xml内容中使用xsl：for-each选择第二个节点？

Question

我在单独的xml文件中有一个图形名称列表和宽度和高度信息，

我需要匹配源xml文件中的图形名称，并需要在源xml文件中插入宽度和高度信息作为属性。

这里是源xml文件..

<graphic name="sample.jpg" align="center"/>

预期输出xml文件

<graphic name="sample.jpg" width="100" depth="200" align="center"/>

数字测量xml

<figure>
<name>sample.jpg</name>
<width>100</width>
<height>200</height>
</figure>

我在'$ names'中存储了源文件名属性值。 我在'$ figname'中存储了图形测量文件名属性值。

我的xsl脚本

<xsl:for-each select="@name">
<xsl:if test="$figname=$name">
<xsl:attribute name="width"><xsl:value-of select="document('figure.xml')/figure/width"/></xsl:attribute>
<xsl:attribute name="depth"><xsl:value-of select="document('figure.xml')/figure/height"/></xsl:attribute>
</xsl:if>
</xsl:for-each>

它仅适用于第一次，而不适用于所有人。 我有近100多张图片。 对于所有图像，我需要宽度和高度值。 我的脚本只有第一个值。 我如何选择所有值？

plase建议我..

最诚挚的问候，安东尼

-------------------------------------------------- -----------------------------------------

对不起，我使用过您的脚本，但我无法获得所需的确切输出。

我已在此提供了所有明确的细节供您考虑。

INPUT XML：

<figure>
<title>Earliest Discoveries</title>
<graphic name="luc26959_0101.eps" align="center"/>
<caption>These lithographs of teeth of Iguanodon are from Mantell original 1825 article.</caption>
</figure>

INPUT图XML：

<?xml version="1.0"?>
<figuregroup>
  <figure><name>luc26959_0101.eps</name><width>500</width><height>347</height></figure>
  <figure><name>luc26959_0102.eps</name><width>500</width><height>352</height></figure>
  <figure><name>luc26959_0103.eps</name><width>500</width><height>348</height></figure>
  <figure><name>luc26959_0104.eps</name><width>445</width><height>263</height></figure>
  <figure><name>luc26959_0105.eps</name><width>217</width><height>250</height></figure>
</figuregroup>

转换XSL代码：

<xsl:template match="graphic">
<xsl:variable name="names">
<xsl:value-of select="substring-before(@name, '.')"/>
</xsl:variable>
<xsl:for-each select="//graphic">
    <imageobject>
        <imagedata>
        <xsl:attribute name="fileref">graphics/<xsl:value-of select="$names"/>.jpg</xsl:attribute>
        <xsl:attribute name="width"><xsl:value-of select="document('../input/fig.xml')/figuregroup/figure[name=$names]/width"/></xsl:attribute>
        <xsl:attribute name="depth"><xsl:value-of select="document('../input/fig.xml')/figuregroup/figure[name=$names]/height"/></xsl:attribute>
        <xsl:apply-templates/>
        </imagedata>
     </imageobject>
</xsl:for-each>
</xsl:template>

当前输出XML：

<figure>
<title>Earliest Discoveries</title>
<mediaobject>
    <imageobject><imagedata fileref="graphics/luc26959_0101.jpg" width="" depth=""/></imageobject>
    <imageobject><imagedata fileref="graphics/luc26959_0101.jpg" width="" depth=""/></imageobject>
    <imageobject><imagedata fileref="graphics/luc26959_0101.jpg" width="" depth=""/></imageobject>
    <imageobject><imagedata fileref="graphics/luc26959_0101.jpg" width="" depth=""/></imageobject>
    <imageobject><imagedata fileref="graphics/luc26959_0101.jpg" width="" depth=""/></imageobject>
    <caption><para>These lithographs of teeth of <emphasis>Iguanodon</emphasis> are from Mantell's original 1825 article.</para><para/></caption>
</mediaobject>
</figure>

需要的输出：

<figure>
<title>Earliest Discoveries</title>
<mediaobject>
    <imageobject><imagedata fileref="graphics/luc26959_0101.jpg" width="500" depth="347"/></imageobject>
    <caption><para>These lithographs of teeth of <emphasis>Iguanodon</emphasis> are from Mantell's original 1825 article.</para><para/></caption>
</mediaobject>
</figure>

希望我已经给出了一个关于我的要求的清晰画面，我也尝试了“for-each”，当我没有'for-each'时，我没有得到任何输出元素重复，只有一次我得到它，仍然宽度和深度属性为空。

在使用你的代码之后，我不知道如何以正确的方式填充该属性。

请帮我..

谢谢和问候，安东尼

Answer 1

你的方法有很多问题。

首先，变量只能被赋值一次，而不能再被赋值。 我怀疑你没有向我们展示的代码是在假设它们被分配不止一次的情况下分配变量。

其次， <for-each select="@name">只会选择一件事： name属性（如果存在）在当前上下文中。 您可能想要更像<for-each select="//graphic"> 。

然后是使用document函数访问figure.xml方法。 无论图像的名称如何，您的示例都只会获得第一个高度和宽度。 您需要使用以下内容过滤结果：

<xsl:attribute name="width">
  <xsl:value-of select="document('figure.xml')//figure[name=$name]/width"/>
</xsl:attribute>

假设你已正确设置$name ，我在第一点就已经介绍过了。

你没有给出整个麻烦的XSLT片段，所以我不能给你一个完整的修正。 不过，从你给我的东西来看，我认为你需要废弃你拥有的东西并重新评估你的方法。 你正在做的事情并不复杂，但你显然是XSLT的新手，也可能是函数编程。 这是一个让你入门的例子：

<xsl:template match="/">
  <xsl:for-each select="//graphic">
    <xsl:variable name="name" select="@name"/>
    <xsl:copy>
      <!-- stuff to copy the attributes/children you want, left to the OP -->
      <xsl:attribute name="width">
        <xsl:value-of 
          select="document('figure.xml')//figure[name=$name]/width"/>
      </xsl:attribute>
      <xsl:attribute name="height">
        <xsl:value-of 
          select="document('figure.xml')//figure[name=$name]/height"/>
      </xsl:attribute>
    </xsl:copy>
  </xsl:for-each>
</xsl:template>

---

编辑

有一点我可以肯定地说，你真的需要了解你的XSLT基础知识 。 您遇到的问题相对简单，而且似乎主要源于XSLT比实际更聪明的信念。 也就是说，这是一个我相信将涵盖您需要的脚本：

<xsl:template match="graphic">
  <!-- Get the name of the file in the right dir, with a .jpg extension -->
  <xsl:variable
    name="filename" 
    select="concat('graphics/',substring-before(@name, '.'),'.jpg')"
  />

  <!-- Set a variable to preserve the name of the file we're looking up -->
  <xsl:variable name="lookupname" select="@name"/>

  <!-- Look up this particular figure by name for easy access -->
  <xsl:variable
    name="lookup"
    select="document('../input/fig.xml')/figuregroup/figure[name=$lookupname]"
  />

  <imageobject>
    <imagedata>
    <xsl:attribute name="fileref">
      <xsl:value-of select="$filename"/>
    </xsl:attribute>

    <!-- Set the width and depth according to the lookup variable's children -->
    <xsl:attribute name="width">
      <xsl:value-of select="$lookup/width"/>
    </xsl:attribute>
    <xsl:attribute name="depth">
      <xsl:value-of select="$lookup/height"/>
    </xsl:attribute>

    <!-- Apply any more templates as necessary -->
    <xsl:apply-templates/>
    </imagedata>
  </imageobject>
</xsl:template>

Answer 2

据我所知，你有一个包含许多不同元素的XML文件，并希望为所有<graphic...>元素添加宽度和高度，而不需要触及XML的其余部分。 我对么？ 然后尝试这个：

<?xml version="1.0" encoding="utf-8"?>
<xsl:stylesheet
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    version="1.0">    
<xsl:output method="xml" indent="yes"/>

<xsl:template match="graphic">
  <xsl:variable name="name" select="@name"/>
  <xsl:copy><xsl:copy-of select="@*"/><xsl:attribute name="width">
    <xsl:value-of select="document('figure.xml')//figure[name=$name]/width"/>
  </xsl:attribute><xsl:attribute name="height">
    <xsl:value-of select="document('figure.xml')//figure[name=$name]/height"/>
  </xsl:attribute></xsl:copy>
</xsl:template>

<xsl:template match="*">
  <xsl:copy><xsl:copy-of select="@*"/>
    <xsl:apply-templates/>
  </xsl:copy>
</xsl:template>

<xsl:template match="text()"><xsl:copy/></xsl:template>

</xsl:stylesheet>

我使用了Welbog建议的属性查找代码，所以请确保你支持他。

它按原样复制所有元素和属性（除非我犯了一个错误），但特别是通过在figure.xml文件中添加宽度和高度来处理<graphic...>元素。 如果要特殊处理其他元素，请添加更多模板，或省略它们。