生成代码的qmake规则

Question

我意识到我之前的问题对规则和依赖关系有点困惑。 以下.pro文件生成一个makefile，如果在qmake运行时存在“generated”目录中的源文件，该makefile可以正常工作。

idl.target   = generated/qmtest.h
idl.commands = code_generator 
idl.config   = no_link
idl.depends  = $$SOURCES $$HEADERS $$FORMS

TEMPLATE       = app
INCLUDEPATH    += generated
SOURCES        += generated/*.cpp
PRE_TARGETDEPS += generated/qmtest.h
QMAKE_EXTRA_UNIX_TARGETS += idl

但是当qmake运行时，它只生成一个makefile，而PRE_TARGETDEPS和QMAKE_EXTRA_UNIX_TARGETS对我没有帮助。 如何让qmake生成一个makefile，它将生成的内容添加到SOURCES？

Answer 1

您可能需要两次通过。

在qmake文件中，添加以下行：

include( generated/generated.pri )

然后，在code_generator脚本的末尾，将源添加到generated.pri文件中（使用bash作为示例，但几乎所有语言的想法都相同）：

rm generated/generated.pri
for file in $( ls generated/*.cpp ); do
    echo "SOURCES += ${file}" >> generated/generated.pri
done

第一次运行qmake文件时，生成/ generated.pri可能是空的。 运行make时，它将填充generated.pri文件。 第二次，它将重新创建make文件（更改源.pri文件），然后再次编译。 您可能可以使用其他可以为您完成第二阶段的命令。

Answer 2

我刚才遇到了同样的问题，但只是一个生成文件的简单用法。 为此，我找到了一种更简单的方法来实现这一点，使用GENERATED_SOURCES而不是SOURCES：

dummyfile.target = dummy.cpp
dummyfile.commands = touch $$dummyfile.target
QMAKE_EXTRA_TARGETS += dummyfile
GENERATED_SOURCES += $$dummyfile.target

可能有人可以将其推入qmake循环并为多个文件生成适当的目标。

Answer 3

我想出了一个我认为健壮且通用的解决方案，它依赖于生成GNU Makefile的qmake 。

假设我们在名为Makefile.pri的文件中获得了所有额外的SOURCES和HEADERS分配，该文件通过执行脚本generate_Makefile.pri.sh ，该脚本还生成Makefile.pri提到的源和/或头。

我们希望构建系统本身自动且可靠地生成此文件，因此要包含在.pro文件中，以便qmake可以考虑其内容并生成具有适当依赖关系的Makefile。

这就是我们必须放在.pro文件中的内容。

Makefile_pri.target   = Makefile.pri
Makefile_pri.commands = generate_Makefile.pri.sh
Makefile_pri.depends  = FORCE

Makefile.target  = $$MAKEFILE
Makefile.depends = Makefile_pri

include($$Makefile_pri.target)

QMAKE_EXTRA_TARGETS = Makefile Makefile_pri

这条路：

1. 如果没有Makefile.pri ，那么它就会被创建;
2. 如果Makefile.pri被创建或更新，则qmake再次运行并考虑其内容，重新Makefile

如上所述，这确实依赖于生成GNU Makefile的qmake ，但我认为可以采用相同的方法来适应其他目标构建系统。