如何在 Windows 批处理文件中运行 PowerShell 脚本

Question

如何将 PowerShell 脚本嵌入到与 Windows 批处理脚本相同的文件中？

我知道这种事情在其他情况下是可能的：

• 使用sqlcmd将 SQL 嵌入到批处理脚本中，并巧妙地安排文件开头的 goto 和注释
• 在 *nix 环境中，您希望运行脚本的程序名称在脚本的第一行被注释掉，例如#!/usr/local/bin/python 。

可能没有办法做到这一点——在这种情况下，我将不得不从启动脚本中调用单独的 PowerShell 脚本。

我考虑过的一种可能的解决方案是回显 PowerShell 脚本，然后运行它。 不这样做的一个很好的理由是，尝试这样做的部分原因是为了利用 PowerShell 环境的优势，而没有诸如转义字符之类的痛苦

我有一些不寻常的约束，想找到一个优雅的解决方案。 我怀疑这个问题可能会引来各种各样的回答：“你为什么不尝试解决这个不同的问题呢。” 我只想说这些是我的限制，对此感到抱歉。

有任何想法吗？ 是否有巧妙的注释和转义字符的合适组合可以使我实现这一目标？

关于如何实现这一目标的一些想法：

• 一行末尾的克拉^是延续 - 就像 Visual Basic 中的下划线
• 符号&通常用于分隔命令echo Hello & echo World在不同的行上产生两个回声
• %0 将为您提供当前正在运行的脚本

所以像这样的东西（如果我能让它工作的话）会很好：

# & call powershell -psconsolefile %0
# & goto :EOF
/* From here on in we're running nice juicy powershell code */
Write-Output "Hello World"

除了...

• 它不起作用...因为
• 文件的扩展名不符合 PowerShell 的喜好： Windows PowerShell console file "insideout.bat" extension is not psc1. Windows PowerShell console file extension must be psc1. Windows PowerShell console file "insideout.bat" extension is not psc1. Windows PowerShell console file extension must be psc1.
• CMD 对这种情况也不是很满意 - 尽管它确实遇到了'#', it is not recognized as an internal or external command, operable program or batch file.

Answer 1

这一行只将正确的行传递给 PowerShell：

dosps2.cmd ：

@findstr/v "^@f.*&" "%~f0"|powershell -&goto:eof
Write-Output "Hello World" 
Write-Output "Hello some@com & again" 

正则表达式排除以@f开头并包含& ，并将其他所有内容传递给 PowerShell。

C:\tmp>dosps2
Hello World
Hello some@com & again

Answer 2

听起来您正在寻找有时称为“多语言脚本”的内容。 对于 CMD -> PowerShell，

@@:: This prolog allows a PowerShell script to be embedded in a .CMD file.
@@:: Any non-PowerShell content must be preceeded by "@@"
@@setlocal
@@set POWERSHELL_BAT_ARGS=%*
@@if defined POWERSHELL_BAT_ARGS set POWERSHELL_BAT_ARGS=%POWERSHELL_BAT_ARGS:"=\"%
@@PowerShell -Command Invoke-Expression $('$args=@(^&{$args} %POWERSHELL_BAT_ARGS%);'+[String]::Join([char]10,$((Get-Content '%~f0') -notmatch '^^@@'))) & goto :EOF

如果您不需要支持带引号的参数，您甚至可以将其设为单行：

@PowerShell -Command Invoke-Expression $('$args=@(^&{$args} %*);'+[String]::Join([char]10,(Get-Content '%~f0') -notmatch '^^@PowerShell.*EOF$')) & goto :EOF

取自http://blogs.msdn.com/jaybaz_ms/archive/2007/04/26/powershell-polyglot.aspx 。 那是 PowerShell v1； 在 v2 中可能更简单，但我没有看过。

Answer 3

这里已经讨论了这个话题。 主要目标是避免使用临时文件以减少缓慢的 I/O 操作并在没有冗余输出的情况下运行脚本。

这是我认为的最佳解决方案：

<# :
@echo off
setlocal
set "POWERSHELL_BAT_ARGS=%*"
if defined POWERSHELL_BAT_ARGS set "POWERSHELL_BAT_ARGS=%POWERSHELL_BAT_ARGS:"=\"%"
endlocal & powershell -NoLogo -NoProfile -Command "$input | &{ [ScriptBlock]::Create( ( Get-Content \"%~f0\" ) -join [char]10 ).Invoke( @( &{ $args } %POWERSHELL_BAT_ARGS% ) ) }"
goto :EOF
#>

param(
    [string]$str
);

$VAR = "Hello, world!";

function F1() {
    $str;
    $script:VAR;
}

F1;

一个更好的方法（见这里）：

<# : batch portion (begins PowerShell multi-line comment block)


@echo off & setlocal
set "POWERSHELL_BAT_ARGS=%*"

echo ---- FROM BATCH
powershell -noprofile -NoLogo "iex (${%~f0} | out-string)"
exit /b %errorlevel%

: end batch / begin PowerShell chimera #>

$VAR = "---- FROM POWERSHELL";
$VAR;
$POWERSHELL_BAT_ARGS=$env:POWERSHELL_BAT_ARGS
$POWERSHELL_BAT_ARGS

其中POWERSHELL_BAT_ARGS是命令行参数，首先在批处理部分设置为变量。

诀窍在于批量重定向优先级 - 这一行<# :将被解析为:<# ，因为重定向的优先级高于其他命令。

但是批处理文件中以:开头的行被视为标签 - 即，不执行。 这仍然是一个有效的 PowerShell 注释。

剩下的唯一事情就是找到一个正确的方式让 PowerShell 读取和执行%~f0 ，这是 cmd.exe 执行的脚本的完整路径。

Answer 4

这似乎有效，如果您不介意一开始 PowerShell 中的一个错误：

dosps.cmd ：

@powershell -<%~f0&goto:eof
Write-Output "Hello World" 
Write-Output "Hello World again" 

Answer 5

^{还要考虑这个“多语言”包装脚本，它支持嵌入式 PowerShell 和/或 VBScript/JScript 代码； 它改编自作者本人flabdablet于 2013 年发布的这个巧妙的原作，但由于仅提供链接答案，因此在 2015 年被删除。}

改进了凯尔出色答案的解决方案：

创建一个包含以下内容的批处理文件（例如sample.cmd ）：

<# ::
@echo off & setlocal
copy /y "%~f0" "%TEMP%\%~n0.ps1" >NUL && powershell -NoProfile -ExecutionPolicy Bypass -File "%TEMP%\%~n0.ps1" %*
set ec=%ERRORLEVEL% & del "%TEMP%\%~n0.ps1"
exit /b %ec%
#>

# Paste arbitrary PowerShell code here.
# In this example, all arguments are echoed.
'Args:'
$Args | % { 'arg #{0}: [{1}]' -f ++$i, $_ }

笔记：

• 批处理文件运行时，会在%TEMP%文件夹中创建一个临时的*.ps1文件，随后会进行清理； 这样做可以大大简化（合理地）稳健地传递参数，只需使用%*
• 以上调用Windows PowerShell 。 要调用跨平台的 PowerShell (Core) v7+ 版本，请将上面代码中的powershell替换为pwsh 。

技术说明：

• Line <# ::是一个混合行，PowerShell 将其视为注释块的开始，但cmd.exe忽略，这是从npocmaka 的回答中借用的技术。

• 因此，以@开头的批处理文件命令会被 PowerShell 忽略，但会由cmd.exe执行； 由于最后一个@ -prefixed 行以exit /b结尾，它在那里退出批处理文件， cmd.exe忽略文件的其余部分，因此可以自由包含非批处理文件代码，即 PowerShell 代码。

• #>行结束包含批处理文件代码的 PowerShell 注释块。

• 因为整个文件是一个有效的 PowerShell 文件，所以不需要findstr技巧来提取 PowerShell 代码； 但是，由于 PowerShell 仅执行文件扩展.ps1脚本，因此必须创建批处理文件的（临时）副本； %TEMP%\\%~n0.ps1在以批处理文件 ( %~n0 ) 命名的%TEMP%文件夹中创建临时副本，但扩展.ps1 ； 临时文件在完成时自动删除。

• 请注意，需要 3行单独的cmd.exe语句来传递 PowerShell 命令的退出代码。
  （使用setlocal enabledelayedexpansion假设允许做它作为一个单一的线，但可能导致不必要的解释!在参数字符。）

---

为了证明参数传递的稳健性：

假设上面的代码已经保存为sample.cmd ，调用它：

sample.cmd "val. w/ spaces & special chars. (\|<>'), on %OS%" 666 "Lisa \"Left Eye\" Lopez"

产生如下内容：

Args:
arg #1: [val. w/ spaces & special chars. (\|<>'), on Windows_NT]
arg #2: [666]
arg #3: [Lisa "Left Eye" Lopez]

请注意嵌入的" chars. 是如何作为\\"传递的。
但是，存在与嵌入的"字符"相关的边缘情况。 ：

:: # BREAKS, due to the `&` inside \"...\"
sample.cmd "A \"rock & roll\" life style"

:: # Doesn't break, but DOESN'T PRESERVE ARGUMENT BOUNDARIES.
sample.cmd "A \""rock & roll\"" life style"

这些困难是由于cmd.exe有缺陷的参数解析，最终试图隐藏这些缺陷是没有意义的，正如flabdablet 在他的优秀回答中指出的那样。

正如他所解释的，在\\"...\\"序列中使用^^^ (sic) 转义以下cmd.exe元字符可以解决问题：

& | < >

使用上面的例子：

:: # OK: cmd.exe metachars. inside \"...\" are ^^^-escaped.
sample.cmd "A \"rock ^^^& roll\" life style"

Answer 6

这支持与 Carlos 发布的解决方案不同的参数，并且不会像 Jay 发布的解决方案那样破坏多行命令或param的使用。 唯一的缺点是此解决方案会创建一个临时文件。 对于我的用例，这是可以接受的。

@@echo off
@@findstr/v "^@@.*" "%~f0" > "%~f0.ps1" & powershell -ExecutionPolicy ByPass "%~f0.ps1" %* & del "%~f0.ps1" & goto:eof

Answer 7

在没有完全理解你的问题的情况下，我的建议是这样的：

@echo off
set MYSCRIPT="some cool powershell code"
powershell -c %MYSCRIPT%

或者更好

@echo off
set MYSCRIPTPATH=c:\work\bin\powershellscript.ps1
powershell %MYSCRIPTPATH%

Answer 8

我目前对这项任务的偏好是多语言标题，其工作方式与mklement0 的第一个解决方案大致相同：

<#  :cmd header for PowerShell script
@   set dir=%~dp0
@   set ps1="%TMP%\%~n0-%RANDOM%-%RANDOM%-%RANDOM%-%RANDOM%.ps1"
@   copy /b /y "%~f0" %ps1% >nul
@   powershell -NoProfile -ExecutionPolicy Bypass -File %ps1% %*
@   del /f %ps1%
@   goto :eof
#>

# Paste arbitrary PowerShell code here.
# In this example, all arguments are echoed.
$Args | % { 'arg #{0}: [{1}]' -f ++$i, $_ }

出于多种原因，我更喜欢将 cmd 标头放置为多行，每行一个命令。 首先，我认为更容易看到发生了什么：命令行足够短，不会跑出我的编辑窗口的右侧，左侧的标点列在视觉上将其标记为标题块，上面的标签被严重滥用第一行说是。 其次， del和goto命令在它们自己的行上，因此即使某些非常时髦的东西作为脚本参数传递，它们仍然会运行。

我更喜欢制作临时.ps1文件的解决方案，而不是那些依赖Invoke-Expression解决方案，纯粹是因为 PowerShell 难以理解的错误消息将至少包含有意义的行号。

制作临时文件所需的时间通常完全被 PowerShell 本身所需的时间淹没，临时文件名称中嵌入的 128 位%RANDOM%几乎可以保证多个并发脚本永远不会践踏彼此的临时文件。 临时文件方法的唯一真正缺点是可能丢失有关调用原始 cmd 脚本的目录的信息，这是在第二行创建dir环境变量的基本原理。

显然，对于 PowerShell 来说，不要对它在脚本文件上接受的文件扩展名如此挑剔会少得多，但是你会与你拥有的 shell 打架，而不是你希望拥有的 shell。

说到这一点：正如 mklement0 所观察到的，

# BREAKS, due to the `&` inside \"...\"
sample.cmd "A \"rock & roll\" life style"

这确实中断了，因为cmd.exe的参数解析完全没有价值。 我通常发现，我尝试隐藏cmd 的许多限制所做的工作越少，我给自己造成的意外错误就越少（我确信我可以提出包含括号的参数，这些参数会破坏 mklement0 否则无可挑剔的＆符号转义逻辑， 例如）。 在我看来，不那么痛苦，只是硬着头皮使用类似的东西

sample.cmd "A \"rock ^^^& roll\" life style"

当最初解析该命令行时，第一个和第三个^转义会被吃掉； 第二个幸存下来，以逃避传递给powershell.exe的命令行中嵌入的& 。 是的，这很丑陋。 是的，它确实让人更难假装cmd.exe不是脚本的第一个破解。 别担心。 如果重要，请记录下来。

在大多数实际应用中， &问题无论如何都没有实际意义。 大多数将作为参数传递给这样的脚本的内容将是通过拖放到达的路径名。 Windows 将引用这些内容，这足以保护空格和与符号，实际上除了引号之外的任何内容，无论如何都不允许在 Windows 路径名中使用。

甚至不要让我开始使用Vinyl LP's, 12"出现在 CSV 文件中。

Answer 9

另一个示例批处理 + PowerShell 脚本......它比其他建议的解决方案更简单，并且具有它们都无法匹配的特性：

• 不创建临时文件 => 更好的性能，并且没有覆盖任何内容的风险。
• 批次代码没有特殊前缀。 这只是普通批次。 PowerShell 代码也是如此。
• 将所有批处理参数正确传递给 PowerShell，甚至是带有棘手字符的引号字符串，例如 ! % < > ' $
• 双引号可以通过加倍传递。
• 标准输入可在 PowerShell 中使用。 （与将批处理本身通过​​管道传输到 PowerShell 的所有版本相反。）

此示例显示语言转换，PowerShell 端显示它从批处理端收到的参数列表。

<# :# PowerShell comment protecting the Batch section
@echo off
:# Disabling argument expansion avoids issues with ! in arguments.
setlocal EnableExtensions DisableDelayedExpansion

:# Prepare the batch arguments, so that PowerShell parses them correctly
set ARGS=%*
if defined ARGS set ARGS=%ARGS:"=\"%
if defined ARGS set ARGS=%ARGS:'=''%

:# The ^ before the first " ensures that the Batch parser does not enter quoted mode
:# there, but that it enters and exits quoted mode for every subsequent pair of ".
:# This in turn protects the possible special chars & | < > within quoted arguments.
:# Then the \ before each pair of " ensures that PowerShell's C command line parser 
:# considers these pairs as part of the first and only argument following -c.
:# Cherry on the cake, it's possible to pass a " to PS by entering two "" in the bat args.
echo In Batch
PowerShell -c ^"Invoke-Expression ('^& {' + [io.file]::ReadAllText(\"%~f0\") + '} %ARGS%')"
echo Back in Batch. PowerShell exit code = %ERRORLEVEL%
exit /b

###############################################################################
End of the PS comment around the Batch section; Begin the PowerShell section #>

echo "In PowerShell"
$Args | % { "PowerShell Args[{0}] = '$_'" -f $i++ }
exit 0

请注意，我使用 :# 进行批注释，而不是像大多数其他人那样使用 ::，因为这实际上使它们看起来像 PowerShell 注释。 （或者实际上就像大多数其他脚本语言注释一样。）

Answer 10

我非常喜欢Jean-François Larvoire 的解决方案，尤其是他处理参数并将它们直接传递给 powershell 脚本（+1 添加）。

但它有一个缺陷。 由于我确实 npt 有评论的声誉，因此我将更正作为新的解决方案发布。

当脚本名称包含$字符时，作为双引号中 Invoke-Expression 参数的脚本名称将不起作用，因为这将在加载文件内容之前进行评估。 最简单的补救方法是替换双引号：

PowerShell -c ^"Invoke-Expression ('^& {' + [io.file]::ReadAllText('%~f0') + '} %ARGS%')"

就我个人而言，我更喜欢将get-content与-raw选项一起使用，对我而言，这更强大：

PowerShell -c ^"Invoke-Expression ('^& {' + (get-content -raw '%~f0') + '} %ARGS%')"

但这当然只是我个人的意见。 ReadAllText works得非常完美。

为完整起见，更正后的脚本：

<# :# PowerShell comment protecting the Batch section
@echo off
:# Disabling argument expansion avoids issues with ! in arguments.
setlocal EnableExtensions DisableDelayedExpansion

:# Prepare the batch arguments, so that PowerShell parses them correctly
set ARGS=%*
if defined ARGS set ARGS=%ARGS:"=\"%
if defined ARGS set ARGS=%ARGS:'=''%

:# The ^ before the first " ensures that the Batch parser does not enter quoted mode
:# there, but that it enters and exits quoted mode for every subsequent pair of ".
:# This in turn protects the possible special chars & | < > within quoted arguments.
:# Then the \ before each pair of " ensures that PowerShell's C command line parser 
:# considers these pairs as part of the first and only argument following -c.
:# Cherry on the cake, it's possible to pass a " to PS by entering two "" in the bat args.
echo In Batch
PowerShell -c ^"Invoke-Expression ('^& {' + (get-content -raw '%~f0') + '} %ARGS%')"
echo Back in Batch. PowerShell exit code = %ERRORLEVEL%
exit /b

###############################################################################
End of the PS comment around the Batch section; Begin the PowerShell section #>

echo "In PowerShell"
$Args | % { "PowerShell Args[{0}] = '$_'" -f $i++ }
exit 0

Answer 11

使用Invoke-Command （简称icm ），我们可以将以下 4 行 header 添加到 ps1 文件中，使其成为有效的 cmd 批处理：

<# : batch portion
@powershell -noprofile "& {icm -ScriptBlock ([Scriptblock]::Create((cat -Raw '%~f0'))) -NoNewScope -ArgumentList $args}" %*
@exit /b %errorlevel%
: end batch / begin powershell #>

"Result:"
$args | %{ "`$args[{0}]: $_" -f $i++ }

如果要使 args[0] 指向脚本路径，请将%*更改为"'%~f0'" %*

Answer 12

您可以在 Powershell 脚本之前添加三行，仅使用块注释，然后将其保存为批处理文件。 然后，您可以有一个批处理文件来运行 Powershell 脚本。 例子：

psscript.bat

@echo off
@powershell -command "(Get-Content -Encoding UTF8 '%0' | select-string -pattern '^[^@]')" | @powershell -NoProfile -ExecutionPolicy ByPass
@goto:eof
<# Must use block comment; Powershell script starts below #>
while($True) {
    Write-Host "wait for 3s"
    Start-Sleep -Seconds 3
}

Answer 13

汇集一些想法

<# :
@powershell -<%~f0&goto:eof
#>

Write-Output "Hello World" 
Write-Output "Hello World again"