使用XSLT清理数据库输入

Question

我一直在寻找一种方法来去除XML内容中的撇号（'），因为我的DBMS抱怨收到这些内容。

我需要

<name> Jim O'Connor</name>

成为：

<name> Jim O''Connor</name>

通过查看此处描述的示例（应将'替换为'' ，我构建了以下脚本：

    <xsl:stylesheet version="1.0"
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
      <xsl:output omit-xml-declaration="yes" indent="yes" />

      <xsl:template match="node()|@*">
        <xsl:copy>
          <xsl:apply-templates select="node()|@*" />
        </xsl:copy>
      </xsl:template>

      <xsl:template name="sqlApostrophe">
        <xsl:param name="string" />
        <xsl:variable name="apostrophe">'</xsl:variable>
        <xsl:choose>
          <xsl:when test="contains($string,$apostrophe)">
            <xsl:value-of select="concat(substring-before($string,$apostrophe), $apostrophe,$apostrophe)"
            disable-output-escaping="yes" />
            <xsl:call-template name="sqlApostrophe">
              <xsl:with-param name="string"
              select="substring-after($string,$apostrophe)" />
            </xsl:call-template>
          </xsl:when>
          <xsl:otherwise>
            <xsl:value-of select="$string"
            disable-output-escaping="yes" />
          </xsl:otherwise>
        </xsl:choose>
      </xsl:template>

      <xsl:template match="text()">
        <xsl:call-template name="sqlApostrophe">
          <xsl:with-param name="string" select="."/>
        </xsl:call-template>
      </xsl:template>

    </xsl:stylesheet>

更新：它工作正常

谢谢你的帮助

Answer 1

您在语法上有几个问题...

1. 您不能在apply-templates标记上具有name属性。
2. 您的xpath“ node（）| @ *”是不明确的。

您是否通过调试器运行了此程序？ 我建议氧气。

Answer 2

主要问题在于您的最后一个模板。 正如dacracot 指出的那样 ， xsl:apply-templates不具有name属性。 要调用命名模板，可以使用xsl:call-template 。

如果要对所有文本节点应用SQL转义，可以尝试使用以下内容替换最后一个模板：

<xsl:template match="text()">
  <xsl:call-template name="sqlApostrophe">
    <xsl:with-param name="string" select="."/>
  </xsl:call-template>
</xsl:template>

另外，为什么disable-output-escaping ？ 如果文本包含特殊字符（ < ， > ， & ），则会得到格式错误的XML作为输出。

Answer 3

是否有理由调用单独的模板进行替换？ 您正在使用什么处理器？ 您应该能够在match="text()"模板中进行替换。

这适用于我使用Saxon 9-HE：

输入XML：

<?xml version="1.0" encoding="UTF-8"?>
<name> Jim O'Connor</name>

样式表：

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
   <xsl:output indent="yes"/>

   <xsl:template match="element()|@*">
      <xsl:copy>
         <xsl:apply-templates select="node()|@*"/>
      </xsl:copy>
   </xsl:template>

    <xsl:template match="text()">
        <xsl:value-of select="replace(data(.),'''','''''')"/>
    </xsl:template>

</xsl:stylesheet>

输出XML：

<?xml version="1.0" encoding="UTF-8"?>
<name> Jim O''Connor</name>