Flex自定义事件调度

Question

我有一个关于flex中的事件调度的问题。

我的目标是让自定义事件加载一些数据，而不是冒充事件监听器。

我的主应用程序内部有一个AMF服务请求，并调用一个服务类。 当AMF服务请求返回结果或错误并且主应用程序正在侦听该事件时，该类应调度一个事件。

因此，在我的mainapp中，我像这样添加和侦听器：

this.addEventListener("UserInfoEvent", userInfoHandler);

自定义UserInfoEvent.as看起来像这样

package events
{
 import flash.events.Event;

 import logic.Ego;

 public class UserInfoEvent extends Event
 {
  private var ego:Ego;

  public function UserInfoEvent(type:String, ego:Ego)
  {
   super(type);
   this.ego = ego;
  }

  override public function clone():Event 
  { 
   return new UserInfoEvent(type, ego);
  } 
 }
}

最后，AMF Service类中的调度程序如下所示：

private var dispatch:EventDispatcher = new EventDispatcher;  
var userInfoEvent:UserInfoEvent = new UserInfoEvent("UserInfoEvent", ego);
dispatch.dispatchEvent(userInfoEvent);

但是，此事件永远不会到达主应用程序。 用调试器仔细查看它，我发现在分派事件时，它的listeners属性设置为null。

谁能告诉我我在做什么错？

Answer 1

我认为您的活动没有成功，因为它不会冒泡

代替

super(type);

尝试

super(type, true, false);

如果使用一个参数调用Event构造函数，则其他两个参数默认为false，其中之一是气泡。

我认为您的另一个问题是您正在创建一个新的EventDispatcher。 而是使用您的服务类扩展EventDispatcher，然后仅调用dispatch（）。

Answer 2

正如我所看到的，您没有以正确的方式收听事件。

 // you have 
 this.addEventListener("UserInfoEvent", userInfoHandler);

 // but you dispatch the event from    
 dispatch.dispatchEvent(userInfoEvent);  

这是错的

你需要有类似的东西

instance_of_Dispatch.addEventListener();  // because this != dispatch

Answer 3

因此，Flex中的事件由其字符串名称标识。 您的Event类没有“名称”，因此它没有任何标识它并在分发时进行匹配的方法。 此“名称”是传递给构造函数的“ type”参数的内容。 传统上，它是作为静态常量存储和引用的。 由于您将类对象UserInfoEvent与字符串“ UserInfoEvent”进行比较，因此它永远不会匹配并捕获到这是您要处理的事件。

package events
{
    import flash.events.Event;

    import logic.Ego;

    public class UserInfoEvent extends Event
    {

        public static const MY_EVENT:String = "myEvent";
        private var ego:Ego;

        public function UserInfoEvent(type:String, ego:Ego)
        {
            super(type);
            this.ego = ego;
        }

        override public function clone():Event 
        { 
            return new UserInfoEvent(type, ego);
        } 
    }
}

然后，您将使用以下方法监听/调度此事件：

dispatchEvent(new UserInfoEvent(UserInfoEvent.MY_EVENT));

和

addEventListener(UserInfoEvent.MY_EVENT, myEventHandler);

希望这是有道理的，我现在正在与一个讨厌的偏头痛作斗争，这正在扼杀我使用字词的能力：P

Answer 4

我猜您的事件调度程序正在冒泡到systemManager而不是通过主应用程序冒泡，因为您的调度程序未添加为主应用程序的子级。 尝试将您的监听器添加到systemManager而不是主应用程序本身：

this.systemManager.addEventListener("UserInfoEvent", userInfoHandler);

Answer 5

好，看起来每个人都部分正确。

这是整个解决方案：

MainApplication.mxml在这里重要的是，这仅在服务类扩展了Sprite类时才有效，否则您将无法使用addEventListener方法。 看起来另一个解决方案是实现IEventDispatcher

private var service:MyService = new MyService;
this.service.addEventListener(UserInfoEvent.RESULT, userInfoHandler);

UserInfoEvent.as

package events
{
    import flash.events.Event;
    import logic.user.Ego;

    public class UserInfoEvent extends Event
    {
        private var ego:Ego;
        public static var RESULT:String = "resultEvent";

        public function UserInfoEvent(type:String, ego:Ego)
        {
            super(type,  true, false);
            this.ego = ego;
        }

        override public function clone():Event 
        { 
            return new UserInfoEvent(type, ego);
        } 
    }
}

最后，如前所述，精灵扩展了MyService.as

public class MyService extends Sprite
{
...
userInfoEvent = new UserInfoEvent(UserInfoEvent.RESULT, ego);
dispatchEvent(userInfoEvent);

这样对我有用。 感谢您的所有帮助，我将把Adrian的答案标记为正确的，因为它给了我一个方向。