检查树之间是否相等的功能

Question

如何在Scheme中实现一个包含2棵树并检查它们是否具有相同元素和结构的相等函数？

Answer 1

从根递归每棵树
如果根值相似-继续左子树，然后继续右子树
任何区别-休息

Answer 2

我们可以用平等吗？

 (equal? '(a (b (c))) '(a (b (c))))

但是，出于乐趣，在Vassermans提到“中断”之后，这可能是利用Schemes连续控制权的好机会！

如果我们发现树中有任何差异，我们可以使用call / cc发出早期回报。 这样，我们可以跳回到调用者的继续，而不必取消堆栈。

这是一个非常简单的例子。 它假定树木结构良好，并且只包含符号作为叶子，但是希望可以证明这一概念。 您会看到该过程明确接受了继续作为参数。

 (define (same? a b return)
   (cond
     ((and (symbol? a) (symbol? b))      ; Both Symbols. Make sure they are the same.
       (if (not (eq? a b))
         (return #f)))
     ((and (empty? a) (empty? b)))       ; Both are empty, so far so good.
     ((not (eq? (empty? a) (empty? b)))  ; One tree is empty, must be different!
       (return #f))
     (else
       (begin
         (same? (car a) (car b) return)  ; Lets keep on looking.
         (same? (cdr a) (cdr b) return)))))

通过call / cc ，我们可以捕获当前的延续。 这是我所谓的过程：

 (call/cc (lambda (k) (same? '(a (b)) '(a (b)) k)))                      ; --> #t
 (call/cc (lambda (k) (same? '(a (b (c) (d e))) '(a (b (c) (d e))) k)))  ; --> #t
 (call/cc (lambda (k) (same? '(a (b (F) (d e))) '(a (b (c) (d e))) k)))  ; --> #f
 (call/cc (lambda (k) (same? '(a (b)) '(a (b (c) (d))) k)))              ; --> #f

Answer 3

我也得到了一个持续的答案。 但是现在我有两个延续，一个是正确的，另一个是错误的。 如果要分支结果，这将很有用。 我还包括了“相同？”，它隐藏了所有连续内容，因此您不必处理它们。

(define (same? a b)
  (call/cc (λ (k) (cont-same? a b (λ () (k #t)) (λ () (k #f))))))

(define (cont-same? a b return-t return-f)
  (define (atest c d)  
    ;; Are they foo?  If they both are, then true
    ;; If they both aren't false
    ;; if they are different, then we are done
    (if (and c d)
        #t
        (if (or c d)
            (return-f)
            #f)))

  (if (atest (null? a) (null? b))  ;; Are they both null, or both not null.
      (return-t)
      (if (atest (pair? a) (pair? b))
          (cont-same? (car a)
                      (car b) 
                      (λ () (cont-same? (cdr a) (cdr b) ;; If the head are the same, compare the tails
                                        return-t return-f)) ;; and if the tails are the same, then the entire thing is the same
                      return-f)          
          (if (equal? a b) ;; Both are atoms
              (return-t)
              (return-f)))))