如何使Perl正则表达式选项成为条件

Question

不要问为什么，但是...

我有一个正则表达式，如果在Windows上运行，则需要不区分大小写，但在* nix上运行时，区分大小写。

这是我目前正在做的事情的示例片段。

sub relative_path 
{
    my ($root, $path) = @_;

    if ($os eq "windows")
    {
        # case insensitive with regex option 'i'
        if ($path !~ /^\Q$root\E[\\\/](.*)$/i)
        {
            print "\tFAIL:$root not in $path\n";
        }
        else
        {
            return $1;
        }
    }
    else
    {
        # case sensitive
        if ($path !~ /^\Q$root\E[\\\/](.*)$/)
        {
            print "\tFAIL:$root not in $path\n";
        }
        else
        {
            return $1;
        }
    }
    return "";
}

啊！ 重复会伤害我的强迫症，但我的表现却很弱。 我想以某种方式使不区分大小写的条件使用正则表达式选项“ i”，但我现在不怎么做？

Answer 1

您可以使用扩展构造来指定选项。 例如：

#!/usr/bin/env perl

use warnings; use strict;

my $s = 'S';

print check($s, 'i'), "\n";
print check($s, '-i'), "\n";

sub check {
    my ($s, $opt) = @_;
    return "Matched" if $s =~ /(?$opt)^s\z/;
    return "Did not match";
}

请参见perldoc perlre 。

Answer 2

您可以使用qr运算符创建模式并将其存储在标量中：

sub relative_path 
{
    my ($root, $path) = @_;

    my $pattern = ($os eq "windows") ? qr/^\Q$root\E[\\\/](.*)$/i : qr/^\Q$root\E[\\\/](.*)$/;

    if ($path !~ $pattern)
    {
        print "\tFAIL:$root not in $path\n";
    }
    else
    {
        return $1;
    }
}

这可能不是100％完美，但希望您能明白。

确保检查出perlop中的“报价和类似报价的运算符”部分 。

---

编辑：好的，这是一种DRY解决方案，因为人们对此表示抱怨。

sub relative_path 
{
    my ($root, $path) = @_;

    my $base_pattern = qr/^\Q$root\E[\\\/](.*)$/;
    my $pattern = ($os eq "windows") ? qr/$base_pattern/i : $base_pattern;

    if ($path !~ $pattern)
    {
        print "\tFAIL:$root not in $path\n";
    }
    else
    {
        return $1;
    }
}

Answer 3

除了实现既定目标外，它还可以正确处理卷，这与以前发布的正则表达式模式不同。

use Path::Class qw( dir );

sub relative_path {
   my ($root, $path) = @_;

   if ($^O =~ /Win32/) {
      require Win32;
      $root = Win32::GetLongPathName($root);
      $path = Win32::GetLongPathName($path);
   }

   $root = dir($root);
   $path = dir($path);

   if ($root->subsumes($path)) {
      return $path->relative($root);
   } else {
      print "\tFAIL:$root not in $path\n";
      return "";
   }
}

顺便说一下，在那儿处理错误不是很合适。 该函数应返回错误信号（返回undef，引发异常等），并且调用方应按其认为合适的方式对其进行处理。 关注点分离。

Answer 4

您也可以使用本地修饰符（perl扩展正则表达式选项）来执行此操作：

sub relative_path 
{
    my ($root, $path) = @_;

    my $pattern = "^\Q$root\E[\\\/](.*)$";
    $pattern = "(?i)$pattern" if ($os eq "windows");
    if ($path =~ /$pattern/)
    {
        return $1;
    }
    else
    {
        print "\tFAIL:$root not in $path\n";
    }
}

（输入答案后，我看到思南也提出了建议，但我决定也发布答案，因为它为问题提供了更具体的答案）