如何在处理中获取屏幕坐标

Question

我正在使用处理来做一个项目。
通过使用draw功能，我在草图板上有一个草图（实际上是文本）。
我想获取文本中每个单词的屏幕坐标，以执行其他一些有趣的事情。

我不知道我可以使用什么功能来检索屏幕坐标。

有人可以帮忙吗？ 多谢您的协助。

谢谢

Answer 1

希望我能正确解决您的问题，以下草图说明了如何实现解决方案。 它相当快，基本上依靠手动单词定位。 首先，我将全文分成单个单词； 存储在myWords数组中。
在draw loop中，我使用两个变量– xPos和yPos –表示在屏幕上移动的假想光标。 if子句检查当前单词是否会跳出草图区域（包括填充）：

        float xPosEnd = xPos + textWidth (myWords[i]);

如果是这样，光标将跳到下一行的开头。

        if (xPosEnd > width - PADDING_X) {
            ...

现在，间距取决于鼠标，并且行高是固定的。 但也可以轻松实现动态变化。 您可以使用xPos和yPos变量来处理单词的位置。 此外， xPosEnd指示单词结束位置。 就像我说的那样，这种方法是相当快的，也可以应用于字符级。

手动文本定位脚本

public static final int FONT_SIZE = 20;
public static final float LINE_HEIGHT = FONT_SIZE * 1.3f;
public static final float PADDING_X = 25;
public static final float PADDING_Y = 15;

PFont font;
String myText;
String[] myWords;

float spacing = 5;

void setup () {
    size (480, 320);
    smooth ();

    font = createFont ("Arial", FONT_SIZE);
    textFont (font);

    myText = "Lorem ipsum dolor sit amet, consectetur adipisicing elit, ";
    myText += "sed do eiusmod tempor incididunt ut labore et dolore magna aliqua. ";
    myText += "Ut enim ad minim veniam, quis nostrud exercitation ullamco laboris ";
    myText += "nisi ut aliquip ex ea commodo consequat.";

    myWords = myText.split (" ");
}

void draw () {

    background (0);

    float xPos = PADDING_X;
    float yPos = PADDING_Y + FONT_SIZE;

    // For every word in the text
    for (int i=0; i < myWords.length; i++) {

        // Calculate the expected end position of 
        // the current word in this line
        float xPosEnd = xPos + textWidth (myWords[i]);

        // Check if word is not to long 
        // for current screen bounds. If...
        if (xPosEnd > width - PADDING_X) {
            // Set the cursor to the beginning 
            // of the next line
            xPos = PADDING_X;
            yPos += LINE_HEIGHT;
        }

        // Display word at xPos-yPos
        text (myWords[i], xPos, yPos);

        // Move the cursor to the right for the 
        // next word in list
        xPos += textWidth (myWords[i]) + spacing;
    }
}

void mouseMoved () {
    spacing = map (mouseX, 0, width, 0, 40);
}

Answer 2

我可以使用什么功能来取回屏幕坐标

可能是您正在寻找screen系统变量

说明系统变量，用于存储计算机屏幕的尺寸。 例如，如果当前屏幕分辨率为1024x768，则screen.width为1024， screen.height为768。这些尺寸在导出全屏应用程序时很有用。

---

样例程序

println ("Width:" + screen.width);
println ("Height:" + screen.height);

---

有关更多参考，请始终参考语言API

---

编辑

但是我正在寻找找到在素描板上绘制的任何对象的坐标的方法。 就像说如果我有一些文本，我想知道文本中每个单词的开始和结束坐标

您使用什么方法绘制文本？ 您将使用哪种方法制作文本动画？ 这取决于您用来找到坐标的方法。

如果您使用text方法，则将坐标作为参数提供
例如： text(data, x, y)

如果为文本设置了动画，以向右移动5个坐标，则如果初始x坐标为10，则x坐标现在将为15。