印刷和图形[]

Question

我想画一个打印在纸上的矩形（或更多），以厘米为单位显示矩形。 所以

Graphics[{Rectangle[{0, 0}, {19, 28}], Orange, Rectangle[{0, 0}, {1, 1}]}]

将打印出两个矩形，可以精确测量为 1cm x 1cm（橙色一个），黑色一个为 19x28 cm。

似乎有些变量很重要： ImageSize ，当然还有AspectRatio 。

我使用了AspectRatio->19/28和ImageSize的各种设置，如ImageSize->{19*27,28*27}但它一直不是很准确。

我将图形导出到 TIFF，然后使用 windows 照片库打印到整页照片。 这个事情谁有经验？ 必须有一个公式，而不是反复试验。

更新：我尝试了@Szabolcs 的建议，并使用了以下代码：

   g = Graphics[{White, EdgeForm[Directive[Thick, Black]], 
   Rectangle[{0, 0}, {18, 28}], Orange, Rectangle[{0, 0}, {10, 10}]}]

   final = Show[g, AspectRatio -> Automatic, 
   PlotRange -> {{-0.5, 18.5}, {-0.5, 28.5}}]

   cm = 72/2.54

   Export["final.pdf", Show[final, ImageSize -> {19 cm, 29 cm}]]

这很好用。 10x10cm 的橙色矩形是精确测量的 10x10cm

cm 72/2.54 值不是我所期望的，因为我虽然 Windows 使用 96dpi 和 Mac 72dpi（从 www 读取）。 但是 72 是有效的值。 我也一直在玩框架，但它变得很难看。 尽管使用了所有可能的设置，但还没有找到获得正确结果的方法。 应该做的是在选定的边界内自己创建框架/刻度等，但这不是我想要追求的路径..

Answer 1

g = Graphics[{Rectangle[{0, 0}, {19, 28}], Orange, Rectangle[{0, 0}, {1, 1}]}]

好的，您需要做的第一件事是将x和y方向设置为使用相同的单位，这意味着

Show[g, AspectRatio -> Automatic]

但这已经是默认设置了。

您需要做的第二件事是为您的 plot 区域选择尺寸和范围。 让我们将矩形居中设置为 21 x 30：

plotArea = {{0, 21}, {0, 30}} - {1, 1}
Show[g, AspectRatio -> Automatic, PlotRange -> plotArea]

您需要做的第三件事是关闭添加任何使图形的实际大小大于 plot 范围的填充/边距：

final = Show[g, AspectRatio -> Automatic, PlotRange -> plotArea, PlotRangePadding -> 0, ImagePadding -> 0]

我相信ImageMargins没有什么不同，但如果有，也将其设置为 0。

您需要做的最后一件事是将其导出为保留图像尺寸的可打印格式，并设置图像的大小，使 plot 上的 1 厘米为 1 个单位。 Mathematica 接受以打印机点为单位的图像尺寸，所以让我们定义：

cm = 72/2.54
Export["final.pdf", Show[final, ImageSize -> 21 cm]]

我们希望 plot 宽 21 厘米，因为它有 21 个单位宽。 使用 PDF 作为导出格式，而不是 TIFF。 需要在Show中使用ImageSize来解决Export ...

现在在 Adobe Reader 中打开 PDF，打开打印对话框，确保页面缩放设置为无。 我不知道如何在其他读者中做到这一点......还要确保你的身材适合纸张（21 x 30 厘米对于 A4 来说太大了......）

我不打算做测试打印，所以让我知道这是否适合你:-) 以这种方式生成的 PDF 的大小正好是 21 x 30 厘米，所以如果出现问题，它一定是在打印时发生的阶段。

Answer 2

我相信您需要添加PlotRangePadding -> None并适当地设置图像尺寸。

在这种情况下，“边界框”的大小与您的较大矩形相同： {19, 28}

执行此操作的可靠方法是将ImageSize设置为实际所需的尺寸，并使用ImageResolution ，它将将此值嵌入到 TIFF 文件中以进行正确打印：

cm = 72 / 2.54;

g = Graphics[{Rectangle[{0, 0}, {19, 28}], Orange, 
      Rectangle[{0, 0}, {1, 1}]}, PlotRangePadding -> None, 
      ImageSize -> {19, 28}*cm];

Export["print.tif", g, ImageResolution -> 300]

这假设您要从光栅格式 (TIFF) 打印，但您也可以使用相同的方法导出为其他格式，例如 PDF。