如何在 if OBJECT_ID 中使用 T-SQL 变量来检查表是否存在？

Question

我试图用下面的代码做的是让它获取所有数据库名称，然后遍历这些数据库检查表tblAdminLogin存在，以及它是否更新了用户名“foo”的密码

我一直在使用 select 语句而不是更新，直到它正常工作。

declare @databases table
(
    PK      int IDENTITY(1,1), 
    dbid    int,
    name    varchar(50)
)

insert into @databases(dbid, name) select dbid, name from master.dbo.sysdatabases

Declare @maxPK int; select @maxPK = MAX(PK) from @databases
Declare @pk int; Set @pk = 1
Declare @name varchar(50)

While @pk <= @maxPK
Begin
    Select @name = name from @databases where PK=@pk
    if OBJECT_ID(''+@name+'.dbo.tblAdminLogin') IS NOT NULL
    Begin
        Select password from @name.dbo.tblAdminLogin where username = 'foo'
        --Update @name.dbo.tblAdminLogin Set password='bar' where username = 'foo' 
    End
    Set @pk = @pk + 1
End

有问题的主要代码是

    Select @name = name from @databases where PK=@pk
    if OBJECT_ID(''+@name+'.dbo.tblAdminLogin') IS NOT NULL
    Begin
        Select password from @name.dbo.tblAdminLogin where username = 'foo'
        --Update @name.dbo.tblAdminLogin Set password='bar' where username = 'foo' 
    End

编辑：在标题中添加了 T-SQL，因为我使用的是 SQL 服务器

编辑：修复了 Typo.dbl。 到正确的.dbo。

Answer 1

动态 SQL。

未经测试

declare @SQL varchar(max) -- varchar(8000) if on SQL Server 2000 or earlier
While @pk <= @maxPK  
Begin      
    Select @name = name from @databases where PK=@pk
    if OBJECT_ID(''+@name+'.dbo.tblAdminLogin') IS NOT NULL      
    Begin          
        set @SQL = 'update ' + quotename(@name) + '.dbo.tblAdminLogin Set     password=''bar'' where username = ''foo'''
        exec (@SQL)
    End
    set @PK = @PK + 1
End

参考：

• 报价名称
• 执行

编辑：关于类型的一般说明，OP 未要求：

数据库名称是 SYSNAME 类型，我上次检查过，它等同于 NVARCHAR(128)。 将该值存储在 VARCHAR 类型中可能会丢失信息。 由于他们会选择名称，因此在某些站点上的机会很小，但机会仍然很小。

declare @databases table
(
    PK      int IDENTITY(1,1), 
    dbid    int,
    name    sysname
)

insert into @databases(dbid, name) select dbid, name from master.dbo.sysdatabases

Declare @maxPK int; select @maxPK = MAX(PK) from @databases
Declare @pk int; Set @pk = 1
Declare @name sysname -- so that 

declare @SQL nvarchar(4000) 
While @pk <= @maxPK  

Begin      
    Select @name = name from @databases where PK=@pk
    if OBJECT_ID(@name+N'.dbo.tblAdminLogin') IS NOT NULL      
    Begin          
        set @SQL = N'update ' + quotename(@name) + N'.dbo.tblAdminLogin Set     password=''bar'' where username = ''foo'''
        exec (@SQL)
    End
    set @PK = @PK + 1
End

Answer 2

选择：

EXEC sp_MSForEachDB 
  'Use [?]; if object_id(''tblAdminLogin'') is not null Select password from tblAdminLogin where username = ''foo'''

Answer 3

我可能会做这样的事情：

exec sp_msforeachdb '
if (object_id(''[?].[dbo].[tblAdminLogin]'', ''U'')) is not null
begin
  update table [?].[dbo].[tblAdminLogin] Set password=''bar'' where username = ''foo''
  select ''?'', username, password from [?].[dbo].[tblAdminLogin] where username = ''foo''
end
'