sort_by function 是如何工作的？

Question

根据这篇文章，我试图了解sort_by在JSON::PP中的工作原理。

当我运行这段代码

#!/usr/bin/perl
use strict;
use warnings;
use JSON::PP;
use Data::Dumper qw(Dumper);

my $h = {
    22 => { title => "c", name => "d" },
    1  => { title => "1", name => "a" },
    10 => { title => "a", name => "c" },
    5  => { title => "b", name => "b" },
};

my $sorter = sub {
    # See what's going on.
    print "$JSON::PP::a cmp $JSON::PP::b\n";
    print Dumper(\@_, $_);
    <STDIN>; # press return to continue

    $JSON::PP::a cmp $JSON::PP::b
};

my $js = JSON::PP->new;
my $output = $js->sort_by($sorter)->encode($h);
print $output . "\n";

它首先对内部键进行排序，然后对外部键进行排序，这决定了 JSON 字符串中的最终顺序。

现在它输出

{"1":{"name":"a","title":"1"},"10":{"name":"c","title":"a"},"22":{"name":"d","title":"c"},"5":{"name":"b","title":"b"}}

我想结束的是它按title排序。

{"1":{"name":"a","title":"1"},"5":{"name":"b","title":"b"}"10",{"name":"c","title":"a"},"22":{"name":"d","title":"c"}}

我想第一个问题是禁用最后一个外键排序？

那么我如何获得title的值呢？ 当算法运行时， $JSON::PP::a和$JSON::PP::b包含来自同一 hash 的值name和title 。

这个我想不通。 谁能解释一下，和/或帮我写这个算法？

Answer 1

你不能，或者至少不容易。 您提供给sort_by的 function 只能访问正在排序的键。 为了做你想做的事，你需要访问与这些键关联的值（或者，更有可能是键所属的 hashref，所以你可以自己查找值）。 这似乎是一个有用的增强； 您可以提交功能请求。

如果您的数据结构足够简单（您的示例似乎很简单），您可以自己保留对 hash 的引用。 为了做到这一点，您必须能够区分内部散列中的键和外部散列中的键（这样您就知道正在对哪个 hash 进行排序，从而知道要进行哪种比较）。

my $sorter = sub {
    if ($JSON::PP::a =~ /^\d+$/) {
      return $h->{$JSON::PP::a}{title} cmp $h->{$JSON::PP::b}{title};
    }
    return $JSON::PP::a cmp $JSON::PP::b
};

Answer 2

尝试类似：

my $sorter = sub {
    my $h = $_[0];

    # simple check for if we are too deep
    # just sort by keys in that case
    return $JSON::PP::a cmp $JSON::PP::b
        if ref($h->{$JSON::PP::a}) ne 'HASH';

    # sort by titles value
    return $h->{$JSON::PP::a}{title} cmp $h->{$JSON::PP::b}{title};
};

$_[0]是当前正在排序的 hash，尽管这似乎没有记录（因此可能不可靠）。

它适用于这种情况，但更复杂的结构会出现问题，因为深度检查非常简单。 如果您确定没有该类型的更深的键，则检查像 cjm 这样的键类型会更好。 或组合，如：

my $sorter = sub {
    my $h = $_[0];

    # just sort by the keys
    return $JSON::PP::a cmp $JSON::PP::b
        unless $JSON::PP::a =~ /^\d+\z/
            && $JSON::PP::b =~ /^\d+\z/
            && ref($h->{$JSON::PP::a}) eq 'HASH'
            && ref($h->{$JSON::PP::b}) eq 'HASH';

    # sort by titles
    return $h->{$JSON::PP::a}{title} cmp $h->{$JSON::PP::b}{title};
};